revbumps; 0.7.2-r1; add 1 missing test dep, tidy up, both; Add py3.2 support, upgrade test phase with upstream bug added for fails under py3, remove only old 0.7.2 for now

(Portage version: 2.2.0/cvs/Linux x86_64, signed Manifest commit with key 0xB8072B0D)

4 files changed, 118 insertions, 37 deletions

diff --git a/dev-python/hacking/ChangeLog b/dev-python/hacking/ChangeLog
index 849a6dc354c3..9f8f0a3e5409 100644
--- a/dev-python/hacking/ChangeLog
+++ b/dev-python/hacking/ChangeLog
@@ -1,6 +1,15 @@
 # ChangeLog for dev-python/hacking
 # Copyright 1999-2014 Gentoo Foundation; Distributed under the GPL v2
-# $Header: /var/cvsroot/gentoo-x86/dev-python/hacking/ChangeLog,v 1.4 2014/01/02 03:07:25 idella4 Exp $
+# $Header: /var/cvsroot/gentoo-x86/dev-python/hacking/ChangeLog,v 1.5 2014/01/02 15:06:38 idella4 Exp $
+
+*hacking-0.7.2-r1 (02 Jan 2014)
+*hacking-0.8.0-r1 (02 Jan 2014)
+
+  02 Jan 2014; Ian Delaney <idella4@gentoo.org> +hacking-0.7.2-r1.ebuild,
+  +hacking-0.8.0-r1.ebuild, -hacking-0.7.2.ebuild:
+  revbumps; 0.7.2-r1; add 1 missing test dep, tidy up, both; Add py3.2 support,
+  upgrade test phase with upstream bug added for fails under py3, remove only
+  old 0.7.2 for now
 
   02 Jan 2014; Ian Delaney <idella4@gentoo.org> hacking-0.8.0.ebuild:
   correct 1 char white space
diff --git a/dev-python/hacking/hacking-0.7.2-r1.ebuild b/dev-python/hacking/hacking-0.7.2-r1.ebuild
new file mode 100644
index 000000000000..48f831633365
--- /dev/null
+++ b/dev-python/hacking/hacking-0.7.2-r1.ebuild
@@ -0,0 +1,49 @@
+# Copyright 1999-2014 Gentoo Foundation
+# Distributed under the terms of the GNU General Public License v2
+# $Header: /var/cvsroot/gentoo-x86/dev-python/hacking/hacking-0.7.2-r1.ebuild,v 1.1 2014/01/02 15:06:38 idella4 Exp $
+
+EAPI=5
+PYTHON_COMPAT=( python{2_7,3_2} )
+
+inherit distutils-r1
+
+DESCRIPTION="A client for the OpenStack Nova API"
+HOMEPAGE="https://github.com/openstack-dev/hacking"
+SRC_URI="mirror://pypi/${PN:0:1}/${PN}/${P}.tar.gz"
+
+LICENSE="Apache-2.0"
+SLOT="0"
+KEYWORDS="~amd64 ~x86"
+IUSE="test"
+
+DEPEND="dev-python/setuptools[${PYTHON_USEDEP}]
+		>=dev-python/pbr-0.5.21[${PYTHON_USEDEP}]
+		<dev-python/pbr-1.0[${PYTHON_USEDEP}]
+		test? ( >=dev-python/coverage-3.6[${PYTHON_USEDEP}]
+			>=dev-python/fixtures-0.3.14[${PYTHON_USEDEP}]
+			dev-python/subunit[${PYTHON_USEDEP}]
+			>=dev-python/sphinx-1.1.2[${PYTHON_USEDEP}]
+			>=dev-python/testrepository-0.0.17-r2[${PYTHON_USEDEP}]
+			>=dev-python/testscenarios-0.4[${PYTHON_USEDEP}]
+			>=dev-python/testtools-0.9.32[${PYTHON_USEDEP}]
+			${RDEPEND} )"
+RDEPEND="~dev-python/pep8-1.4.5[${PYTHON_USEDEP}]
+		>=dev-python/pyflakes-0.7.2[${PYTHON_USEDEP}]
+		<dev-python/pyflakes-0.7.4[${PYTHON_USEDEP}]
+		~dev-python/flake8-2.0[${PYTHON_USEDEP}]
+		dev-python/six[${PYTHON_USEDEP}]"
+DISTUTILS_IN_SOURCE_BUILD=1
+
+python_test() {
+	# https://bugs.launchpad.net/hacking/+bug/1265520
+	if [ "${EPYTHON}" == 'python3.2' ]; then
+		sed -e 's:test_pep8:_&:' -i hacking/tests/test_doctest.py || die
+		sed -e 's:test_with_physical_line_argument:_&:' \
+			-e 's:test_without_physical_line_argument:_&:' \
+			-i hacking/tests/test_noqa_decorator.py || die
+	fi
+	testr init || die "testr init died"
+	testr run || die "testsuite failed under ${EPYTHON}"
+
+	flake8 "${PN}"/tests || die "flake8 drew error on a run over ${PN}/tests folder"
+}
diff --git a/dev-python/hacking/hacking-0.7.2.ebuild b/dev-python/hacking/hacking-0.7.2.ebuild
deleted file mode 100644
index f8e67d614608..000000000000
--- a/dev-python/hacking/hacking-0.7.2.ebuild
+++ /dev/null
@@ -1,36 +0,0 @@
-# Copyright 1999-2013 Gentoo Foundation
-# Distributed under the terms of the GNU General Public License v2
-# $Header: /var/cvsroot/gentoo-x86/dev-python/hacking/hacking-0.7.2.ebuild,v 1.1 2013/10/25 06:46:23 prometheanfire Exp $
-
-EAPI=5
-PYTHON_COMPAT=( python2_7 )
-
-inherit distutils-r1
-
-DESCRIPTION="A client for the OpenStack Nova API"
-HOMEPAGE="https://github.com/openstack-dev/hacking"
-SRC_URI="mirror://pypi/${PN:0:1}/${PN}/${P}.tar.gz"
-
-LICENSE="Apache-2.0"
-SLOT="0"
-KEYWORDS="~amd64 ~x86"
-IUSE="test"
-
-DEPEND="dev-python/setuptools[${PYTHON_USEDEP}]
-		>=dev-python/pbr-0.5.21[${PYTHON_USEDEP}]
-		<dev-python/pbr-1[${PYTHON_USEDEP}]
-		test? ( >=dev-python/coverage-3.6[${PYTHON_USEDEP}]
-				>=dev-python/fixtures-0.3.14[${PYTHON_USEDEP}]
-				dev-python/subunit[${PYTHON_USEDEP}]
-				>=dev-python/sphinx-1.1.2[${PYTHON_USEDEP}]
-				>=dev-python/testrepository-0.0.17[${PYTHON_USEDEP}]
-				>=dev-python/testtools-0.9.32[${PYTHON_USEDEP}] )"
-RDEPEND="~dev-python/pep8-1.4.5[${PYTHON_USEDEP}]
-		>=dev-python/pyflakes-0.7.2[${PYTHON_USEDEP}]
-		<dev-python/pyflakes-0.7.4[${PYTHON_USEDEP}]
-		~dev-python/flake8-2.0[${PYTHON_USEDEP}]
-		dev-python/six[${PYTHON_USEDEP}]"
-
-python_test() {
-	"${PYTHON}" -m subunit.run discover -t ./ . || die
-}
diff --git a/dev-python/hacking/hacking-0.8.0-r1.ebuild b/dev-python/hacking/hacking-0.8.0-r1.ebuild
new file mode 100644
index 000000000000..43916c10cc26
--- /dev/null
+++ b/dev-python/hacking/hacking-0.8.0-r1.ebuild
@@ -0,0 +1,59 @@
+# Copyright 1999-2014 Gentoo Foundation
+# Distributed under the terms of the GNU General Public License v2
+# $Header: /var/cvsroot/gentoo-x86/dev-python/hacking/hacking-0.8.0-r1.ebuild,v 1.1 2014/01/02 15:06:38 idella4 Exp $
+
+EAPI=5
+PYTHON_COMPAT=( python{2_7,3_2} )
+
+inherit distutils-r1
+
+DESCRIPTION="A client for the OpenStack Nova API"
+HOMEPAGE="https://github.com/openstack-dev/hacking"
+SRC_URI="mirror://pypi/${PN:0:1}/${PN}/${P}.tar.gz"
+
+LICENSE="Apache-2.0"
+SLOT="0"
+KEYWORDS="~amd64 ~x86"
+IUSE="doc test"
+
+DEPEND="dev-python/setuptools[${PYTHON_USEDEP}]
+		>=dev-python/pbr-0.5.21[${PYTHON_USEDEP}]
+		<dev-python/pbr-1.0[${PYTHON_USEDEP}]
+		test? ( >=dev-python/coverage-3.6[${PYTHON_USEDEP}]
+			>=dev-python/fixtures-0.3.14[${PYTHON_USEDEP}]
+			dev-python/subunit[${PYTHON_USEDEP}]
+			>=dev-python/sphinx-1.1.2[${PYTHON_USEDEP}]
+			>=dev-python/testrepository-0.0.17-r2[${PYTHON_USEDEP}]
+			>=dev-python/testscenarios-0.4[${PYTHON_USEDEP}]
+			>=dev-python/testtools-0.9.32[${PYTHON_USEDEP}]
+			${RDEPEND} )"
+RDEPEND="~dev-python/pep8-1.4.5[${PYTHON_USEDEP}]
+		>=dev-python/pyflakes-0.7.2[${PYTHON_USEDEP}]
+		<dev-python/pyflakes-0.7.4[${PYTHON_USEDEP}]
+		~dev-python/flake8-2.0[${PYTHON_USEDEP}]
+		>=dev-python/six-1.4.1[${PYTHON_USEDEP}]"
+DISTUTILS_IN_SOURCE_BUILD=1
+
+python_prepare_all() {
+	sed -e 's:intersphinx_mapping:#&:' -i doc/source/conf.py || die
+	distutils-r1_python_prepare_all
+}
+
+python_compile_all() {
+	use doc && sphinx-build -b html -c doc/source/ doc/source/ doc/source/html
+}
+
+python_test() {
+	# https://bugs.launchpad.net/hacking/+bug/1265520
+	if [ "${EPYTHON}" == 'python3.2' ]; then
+		sed -e 's:test_pep8:_&:'  -i hacking/tests/test_doctest.py || die
+	fi
+	testr init || die "testr init died"
+	testr run || die "testsuite failed under ${EPYTHON}"
+	flake8 "${PN}"/tests || die "flake8 drew error on a run over ${PN}/tests folder"
+}
+
+python_install_all() {
+	use doc && local HTML_DOCS=( doc/source/html/. )
+	distutils-r1_python_install_all
+}