Migrate to distutils-r1.

(Portage version: 2.2.0_alpha161/cvs/Linux x86_64, signed Manifest commit with key 42B9401D)

2 files changed, 60 insertions, 2 deletions

diff --git a/dev-util/scons/ChangeLog b/dev-util/scons/ChangeLog
index ed876dffec19..93a63a9b179d 100644
--- a/dev-util/scons/ChangeLog
+++ b/dev-util/scons/ChangeLog
@@ -1,6 +1,11 @@
 # ChangeLog for dev-util/scons
-# Copyright 1999-2012 Gentoo Foundation; Distributed under the GPL v2
-# $Header: /var/cvsroot/gentoo-x86/dev-util/scons/ChangeLog,v 1.126 2012/10/07 14:40:20 grobian Exp $
+# Copyright 1999-2013 Gentoo Foundation; Distributed under the GPL v2
+# $Header: /var/cvsroot/gentoo-x86/dev-util/scons/ChangeLog,v 1.127 2013/02/06 12:22:06 mgorny Exp $
+
+*scons-2.2.0-r1 (06 Feb 2013)
+
+  06 Feb 2013; Michał Górny <mgorny@gentoo.org> +scons-2.2.0-r1.ebuild:
+  Migrate to distutils-r1.
 
   07 Oct 2012; Fabian Groffen <grobian@gentoo.org> scons-2.2.0.ebuild:
   Setup a valid path, EPREFIX does NOT end in /
diff --git a/dev-util/scons/scons-2.2.0-r1.ebuild b/dev-util/scons/scons-2.2.0-r1.ebuild
new file mode 100644
index 000000000000..63e5b416ee6e
--- /dev/null
+++ b/dev-util/scons/scons-2.2.0-r1.ebuild
@@ -0,0 +1,53 @@
+# Copyright 1999-2013 Gentoo Foundation
+# Distributed under the terms of the GNU General Public License v2
+# $Header: /var/cvsroot/gentoo-x86/dev-util/scons/scons-2.2.0-r1.ebuild,v 1.1 2013/02/06 12:22:06 mgorny Exp $
+
+EAPI=5
+
+PYTHON_COMPAT=( python{2_5,2_6,2_7} )
+PYTHON_REQ_USE="threads(+)"
+
+inherit distutils-r1
+
+DESCRIPTION="Extensible Python-based build utility"
+HOMEPAGE="http://www.scons.org/"
+SRC_URI="mirror://sourceforge/${PN}/${P}.tar.gz
+	doc? ( http://www.scons.org/doc/${PV}/PDF/${PN}-user.pdf -> ${P}-user.pdf
+	       http://www.scons.org/doc/${PV}/HTML/${PN}-user.html -> ${P}-user.html )"
+
+LICENSE="MIT"
+SLOT="0"
+KEYWORDS="~alpha ~amd64 ~arm ~hppa ~ia64 ~mips ~ppc ~ppc64 ~sparc ~x86 ~x86-fbsd ~amd64-linux ~x86-linux ~ppc-macos ~x64-macos ~x86-macos ~sparc-solaris ~x86-solaris"
+IUSE="doc"
+
+python_prepare_all() {
+	local PATCHES=(
+		"${FILESDIR}/scons-1.2.0-popen.patch"
+		"${FILESDIR}/${PN}-2.1.0-jython.patch"
+	)
+
+	# https://bugs.gentoo.org/show_bug.cgi?id=361061
+	sed -i -e "s|/usr/local/bin:/opt/bin:/bin:/usr/bin|${EPREFIX}/usr/local/bin:${EPREFIX}/opt/bin:${EPREFIX}/bin:${EPREFIX}/usr/bin:/usr/local/bin:/opt/bin:/bin:/usr/bin|g" engine/SCons/Platform/posix.py || die
+	# and make sure the build system doesn't "force" /usr/local/ :(
+	sed -i -e "s/'darwin'/'NOWAYdarwinWAYNO'/" setup.py || die
+
+	distutils-r1_python_prepare_all
+}
+
+python_install() {
+	distutils-r1_python_install \
+		--standard-lib \
+		--no-version-script \
+		--install-data "${EPREFIX}"/usr/share
+
+	# Build system does not use build_scripts properly.
+	# http://scons.tigris.org/issues/show_bug.cgi?id=2891
+	python_doscript "${ED}"usr/bin/scons{,ign,-time}
+}
+
+python_install_all() {
+	local DOCS=( {CHANGES,README,RELEASE}.txt )
+	distutils-r1_python_install_all
+
+	use doc && dodoc "${DISTDIR}"/${P}-user.{pdf,html}
+}