Add new version for Gnome 2.30

(Portage version: 2.1.8.3/cvs/Linux x86_64)

2 files changed, 58 insertions, 1 deletions

diff --git a/gnome-base/gnome-desktop/ChangeLog b/gnome-base/gnome-desktop/ChangeLog
index 98cdfef021fc..0e20506a9ae2 100644
--- a/gnome-base/gnome-desktop/ChangeLog
+++ b/gnome-base/gnome-desktop/ChangeLog
@@ -1,6 +1,11 @@
 # ChangeLog for gnome-base/gnome-desktop
 # Copyright 1999-2010 Gentoo Foundation; Distributed under the GPL v2
-# $Header: /var/cvsroot/gentoo-x86/gnome-base/gnome-desktop/ChangeLog,v 1.271 2010/06/04 20:04:22 maekke Exp $
+# $Header: /var/cvsroot/gentoo-x86/gnome-base/gnome-desktop/ChangeLog,v 1.272 2010/06/13 17:38:21 pacho Exp $
+
+*gnome-desktop-2.30.0 (13 Jun 2010)
+
+  13 Jun 2010; Pacho Ramos <pacho@gentoo.org> +gnome-desktop-2.30.0.ebuild:
+  Add new version for Gnome 2.30.
 
   04 Jun 2010; Markus Meier <maekke@gentoo.org>
   gnome-desktop-2.28.2-r1.ebuild:
diff --git a/gnome-base/gnome-desktop/gnome-desktop-2.30.0.ebuild b/gnome-base/gnome-desktop/gnome-desktop-2.30.0.ebuild
new file mode 100644
index 000000000000..7abd7bee6aa6
--- /dev/null
+++ b/gnome-base/gnome-desktop/gnome-desktop-2.30.0.ebuild
@@ -0,0 +1,52 @@
+# Copyright 1999-2010 Gentoo Foundation
+# Distributed under the terms of the GNU General Public License v2
+# $Header: /var/cvsroot/gentoo-x86/gnome-base/gnome-desktop/gnome-desktop-2.30.0.ebuild,v 1.1 2010/06/13 17:38:21 pacho Exp $
+
+EAPI="2"
+
+inherit gnome2 eutils
+
+DESCRIPTION="Libraries for the gnome desktop that are not part of the UI"
+HOMEPAGE="http://www.gnome.org/"
+
+LICENSE="GPL-2 FDL-1.1 LGPL-2"
+SLOT="0"
+KEYWORDS="~alpha ~amd64 ~arm ~hppa ~ia64 ~ppc ~ppc64 ~sh ~sparc ~x86 ~x86-fbsd ~x86-interix ~amd64-linux ~x86-linux ~x86-solaris"
+IUSE="doc"
+
+RDEPEND=">=x11-libs/gtk+-2.18.0
+	>=dev-libs/glib-2.19.1
+	>=x11-libs/libXrandr-1.2
+	>=gnome-base/gconf-2
+	>=x11-libs/startup-notification-0.5"
+DEPEND="${RDEPEND}
+	>=dev-util/intltool-0.40
+	>=dev-util/pkgconfig-0.9
+	>=app-text/gnome-doc-utils-0.3.2
+	doc? ( >=dev-util/gtk-doc-1.4 )
+	~app-text/docbook-xml-dtd-4.1.2
+	x11-proto/xproto
+	>=x11-proto/randrproto-1.2"
+PDEPEND=">=dev-python/pygtk-2.8
+	>=dev-python/pygobject-2.14"
+
+# Includes X11/Xatom.h in libgnome-desktop/gnome-bg.c which comes from xproto
+# Includes X11/extensions/Xrandr.h that includes randr.h from randrproto (and
+# eventually libXrandr shouldn't RDEPEND on randrproto)
+
+DOCS="AUTHORS ChangeLog HACKING NEWS README"
+
+pkg_setup() {
+	G2CONF="${G2CONF}
+		--with-gnome-distributor=Gentoo
+		--disable-scrollkeeper
+		--disable-static"
+}
+
+src_prepare() {
+	gnome2_src_prepare
+
+	# Fix intltoolize broken file, see upstream #577133
+	sed "s:'\^\$\$lang\$\$':\^\$\$lang\$\$:g" -i po/Makefile.in.in \
+		|| die "sed failed"
+}