Version bump KDE SC 4.12.4

(Portage version: 2.2.10/cvs/Linux x86_64, signed Manifest commit with key F3CFD2BD)

2 files changed, 64 insertions, 1 deletions

diff --git a/kde-base/cantor/ChangeLog b/kde-base/cantor/ChangeLog
index b3794e646837..f54f568bd390 100644
--- a/kde-base/cantor/ChangeLog
+++ b/kde-base/cantor/ChangeLog
@@ -1,6 +1,11 @@
 # ChangeLog for kde-base/cantor
 # Copyright 1999-2014 Gentoo Foundation; Distributed under the GPL v2
-# $Header: /var/cvsroot/gentoo-x86/kde-base/cantor/ChangeLog,v 1.163 2014/03/11 13:06:27 johu Exp $
+# $Header: /var/cvsroot/gentoo-x86/kde-base/cantor/ChangeLog,v 1.164 2014/04/01 18:09:26 johu Exp $
+
+*cantor-4.12.4 (01 Apr 2014)
+
+  01 Apr 2014; Johannes Huber <johu@gentoo.org> +cantor-4.12.4.ebuild:
+  Version bump KDE SC 4.12.4
 
   11 Mar 2014; Johannes Huber <johu@gentoo.org> -cantor-4.12.2.ebuild:
   Remove KDE SC 4.12.2
diff --git a/kde-base/cantor/cantor-4.12.4.ebuild b/kde-base/cantor/cantor-4.12.4.ebuild
new file mode 100644
index 000000000000..86b03ab4202c
--- /dev/null
+++ b/kde-base/cantor/cantor-4.12.4.ebuild
@@ -0,0 +1,58 @@
+# Copyright 1999-2014 Gentoo Foundation
+# Distributed under the terms of the GNU General Public License v2
+# $Header: /var/cvsroot/gentoo-x86/kde-base/cantor/cantor-4.12.4.ebuild,v 1.1 2014/04/01 18:09:26 johu Exp $
+
+EAPI=5
+
+KDE_HANDBOOK="optional"
+PYTHON_COMPAT=( python2_7 )
+inherit kde4-base python-single-r1
+
+DESCRIPTION="KDE4 interface for doing mathematics and scientific computing"
+HOMEPAGE="http://www.kde.org/applications/education/cantor http://edu.kde.org/cantor"
+KEYWORDS=" ~amd64 ~arm ~ppc ~ppc64 ~x86 ~amd64-linux ~x86-linux"
+IUSE="analitza debug postscript python qalculate +R"
+
+REQUIRED_USE="python? ( ${PYTHON_REQUIRED_USE} )"
+
+# TODO Add Sage Mathematics Software backend (http://www.sagemath.org)
+RDEPEND="
+	analitza? ( $(add_kdebase_dep analitza) )
+	qalculate? (
+		sci-libs/cln
+		sci-libs/libqalculate
+	)
+	postscript? ( app-text/libspectre )
+	python? ( ${PYTHON_DEPS} )
+	R? ( dev-lang/R )
+	dev-qt/qtxmlpatterns:4
+"
+DEPEND="${RDEPEND}
+	>=dev-cpp/eigen-2.0.3:2
+"
+
+RESTRICT="test"
+
+src_configure() {
+	mycmakeargs=(
+		$(cmake-utils_use_with analitza)
+		$(cmake-utils_use_with postscript LibSpectre)
+		$(cmake-utils_use_with python PythonLibs)
+		$(cmake-utils_use_with qalculate)
+		$(cmake-utils_use_with R)
+	)
+	kde4-base_src_configure
+}
+
+pkg_postinst() {
+	kde4-base_pkg_postinst
+
+	if ! use analitza && ! use python && ! use qalculate && ! use R; then
+		echo
+		ewarn "You have decided to build ${PN} with no backend."
+		ewarn "To have this application functional, please do one of below:"
+		ewarn "    # emerge -va1 '='${CATEGORY}/${P} with 'analitza', 'python', 'qalculate' or 'R' USE flag enabled"
+		ewarn "    # emerge -vaDu sci-mathematics/maxima"
+		echo
+	fi
+}