[kde-base] Add KDE SC 4.7.1

(Portage version: 2.2.0_alpha54/cvs/Linux x86_64)

2 files changed, 82 insertions, 1 deletions

diff --git a/kde-base/qtruby/ChangeLog b/kde-base/qtruby/ChangeLog
index 69cf9f848289..4f8626f4917c 100644
--- a/kde-base/qtruby/ChangeLog
+++ b/kde-base/qtruby/ChangeLog
@@ -1,6 +1,11 @@
 # ChangeLog for kde-base/qtruby
 # Copyright 1999-2011 Gentoo Foundation; Distributed under the GPL v2
-# $Header: /var/cvsroot/gentoo-x86/kde-base/qtruby/ChangeLog,v 1.86 2011/07/27 14:04:31 alexxy Exp $
+# $Header: /var/cvsroot/gentoo-x86/kde-base/qtruby/ChangeLog,v 1.87 2011/09/07 20:13:52 alexxy Exp $
+
+*qtruby-4.7.1 (07 Sep 2011)
+
+  07 Sep 2011; Alexey Shvetsov <alexxy@gentoo.org> +qtruby-4.7.1.ebuild:
+  Version bump KDE SC 4.7.1
 
 *qtruby-4.7.0 (27 Jul 2011)
 
diff --git a/kde-base/qtruby/qtruby-4.7.1.ebuild b/kde-base/qtruby/qtruby-4.7.1.ebuild
new file mode 100644
index 000000000000..f618816c97e3
--- /dev/null
+++ b/kde-base/qtruby/qtruby-4.7.1.ebuild
@@ -0,0 +1,76 @@
+# Copyright 1999-2011 Gentoo Foundation
+# Distributed under the terms of the GNU General Public License v2
+# $Header: /var/cvsroot/gentoo-x86/kde-base/qtruby/qtruby-4.7.1.ebuild,v 1.1 2011/09/07 20:13:52 alexxy Exp $
+
+EAPI=4
+
+OPENGL_REQUIRED="always"
+DECLARATIVE_REQUIRED="optional"
+KDE_REQUIRED="never"
+KDE_SCM="git"
+USE_RUBY="ruby18"
+# No ruby19 for three reasons:
+# 1) it does not build (yet) - will likely be solved soon
+# 2) cmake bails when configuring twice or more - solved with CMAKE_IN_SOURCE_BUILD=1
+# 3) the ebuild can only be installed for one ruby variant, otherwise the compiled
+#    files with identical path+name will overwrite each other - difficult :(
+
+inherit kde4-base ruby-ng
+
+DESCRIPTION="Qt Ruby bindings"
+KEYWORDS="~amd64 ~x86"
+IUSE="debug phonon qscintilla qwt webkit"
+
+DEPEND="
+	$(add_kdebase_dep smokeqt 'declarative?,opengl,phonon?,qscintilla?,qwt?,webkit?')
+"
+
+RDEPEND="${DEPEND}
+	!dev-ruby/qt4-qtruby
+"
+
+# Split from kdebindings-ruby in 4.7
+add_blocker kdebindings-ruby
+
+pkg_setup() {
+	ruby-ng_pkg_setup
+	kde4-base_pkg_setup
+}
+
+src_unpack() {
+	local S="${WORKDIR}/${P}"
+	kde4-base_src_unpack
+
+	cd "${WORKDIR}"
+	mkdir all
+	mv ${P} all/ || die "Could not move sources"
+}
+
+all_ruby_prepare() {
+	kde4-base_src_prepare
+}
+
+each_ruby_configure() {
+	local CMAKE_USE_DIR=${S}
+	mycmakeargs=(
+		-DRUBY_LIBRARY=$(ruby_get_libruby)
+		-DRUBY_INCLUDE_PATH=$(ruby_get_hdrdir)
+		-DRUBY_EXECUTABLE=${RUBY}
+		$(cmake-utils_use_disable declarative QtDeclarative)
+		$(cmake-utils_use_with phonon)
+		$(cmake-utils_use_with qscintilla QScintilla)
+		$(cmake-utils_use_with qwt Qwt5)
+		$(cmake-utils_use_disable webkit QtWebKit)
+	)
+	kde4-base_src_configure
+}
+
+each_ruby_compile() {
+	local CMAKE_USE_DIR=${S}
+	kde4-base_src_compile
+}
+
+each_ruby_install() {
+	local CMAKE_USE_DIR=${S}
+	kde4-base_src_install
+}