Version bump to KDE 4.0.2.

(Portage version: 2.1.4.4)

2 files changed, 57 insertions, 1 deletions

diff --git a/kde-base/okular/ChangeLog b/kde-base/okular/ChangeLog
index ef67b6a6e9c9..5ae9b0e4ccad 100644
--- a/kde-base/okular/ChangeLog
+++ b/kde-base/okular/ChangeLog
@@ -1,6 +1,11 @@
 # ChangeLog for kde-base/okular
 # Copyright 1999-2008 Gentoo Foundation; Distributed under the GPL v2
-# $Header: /var/cvsroot/gentoo-x86/kde-base/okular/ChangeLog,v 1.4 2008/02/23 17:45:58 ingmar Exp $
+# $Header: /var/cvsroot/gentoo-x86/kde-base/okular/ChangeLog,v 1.5 2008/03/11 00:03:07 philantrop Exp $
+
+*okular-4.0.2 (10 Mar 2008)
+
+  10 Mar 2008; Wulf C. Krueger <philantrop@gentoo.org> +okular-4.0.2.ebuild:
+  Version bump to KDE 4.0.2
 
   23 Feb 2008; Ingmar Vanhassel <ingmar@gentoo.org> okular-4.0.1.ebuild:
   Remove traces of monolithic KDE 4.
diff --git a/kde-base/okular/okular-4.0.2.ebuild b/kde-base/okular/okular-4.0.2.ebuild
new file mode 100644
index 000000000000..4787c5f81540
--- /dev/null
+++ b/kde-base/okular/okular-4.0.2.ebuild
@@ -0,0 +1,51 @@
+# Copyright 1999-2008 Gentoo Foundation
+# Distributed under the terms of the GNU General Public License v2
+# $Header: /var/cvsroot/gentoo-x86/kde-base/okular/okular-4.0.2.ebuild,v 1.1 2008/03/11 00:03:07 philantrop Exp $
+
+EAPI="1"
+
+KMNAME=kdegraphics
+inherit kde4-meta
+
+DESCRIPTION="Okular is an universal document viewer based on KPDF for KDE 4."
+KEYWORDS="~amd64 ~x86"
+IUSE="chm debug djvu htmlhandbook jpeg pdf tiff"
+
+RDEPEND="
+	>=app-text/libspectre-0.2
+	media-libs/freetype
+	kde-base/qimageblitz
+	chm? ( app-doc/chmlib )
+	djvu? ( >=app-text/djvu-3.5.17 )
+	jpeg? ( media-libs/jpeg )
+	pdf? ( >=app-text/poppler-0.5.4
+		>=app-text/poppler-bindings-0.5.4 )
+	tiff? ( media-libs/tiff )"
+DEPEND="${RDEPEND}
+	dev-util/pkgconfig"
+
+PATCHES="${FILESDIR}/${KMNAME}-4.0.1-system-libspectre.patch"
+
+pkg_setup() {
+	if use pdf; then
+		KDE4_BUILT_WITH_USE_CHECK="${KDE4_BUILT_WITH_USE_CHECK}
+			app-text/poppler-bindings qt4"
+	fi
+	kde4-meta_pkg_setup
+}
+
+src_compile() {
+	# remove internal copy of libspectre
+	rm -r "${S}"/okular/generators/spectre/libspectre || \
+		die "Failed to remove internal copy of libspectre."
+
+	mycmakeargs="${mycmakeargs}
+		$(cmake-utils_use_with chm CHM)
+		$(cmake-utils_use_with djvu DjVuLibre)
+		$(cmake-utils_use_with jpeg JPEG)
+		$(cmake-utils_use_with pdf PopplerQt4)
+		$(cmake-utils_use_with pdf Poppler)
+		$(cmake-utils_use_with tiff TIFF)"
+
+	kde4-meta_src_compile
+}