media-gfx/optipng: No longer calls gcc, ar, ranlib directly (bug #435780)

(Portage version: 2.1.10.65/cvs/Linux x86_64)

2 files changed, 62 insertions, 1 deletions

diff --git a/media-gfx/optipng/ChangeLog b/media-gfx/optipng/ChangeLog
index 9b8062cae228..393aaec9bd37 100644
--- a/media-gfx/optipng/ChangeLog
+++ b/media-gfx/optipng/ChangeLog
@@ -1,6 +1,11 @@
 # ChangeLog for media-gfx/optipng
 # Copyright 1999-2012 Gentoo Foundation; Distributed under the GPL v2
-# $Header: /var/cvsroot/gentoo-x86/media-gfx/optipng/ChangeLog,v 1.87 2012/09/22 15:51:53 ago Exp $
+# $Header: /var/cvsroot/gentoo-x86/media-gfx/optipng/ChangeLog,v 1.88 2012/09/22 20:42:18 sping Exp $
+
+*optipng-0.7.3-r1 (22 Sep 2012)
+
+  22 Sep 2012; Sebastian Pipping <sping@gentoo.org> +optipng-0.7.3-r1.ebuild:
+  No longer calls gcc, ar, ranlib directly (bug #435780), patch by Agostino
 
   22 Sep 2012; Agostino Sarubbo <ago@gentoo.org> -optipng-0.7.1.ebuild,
   -optipng-0.7.2.ebuild, -optipng-0.7.ebuild:
diff --git a/media-gfx/optipng/optipng-0.7.3-r1.ebuild b/media-gfx/optipng/optipng-0.7.3-r1.ebuild
new file mode 100644
index 000000000000..1c2d953915e3
--- /dev/null
+++ b/media-gfx/optipng/optipng-0.7.3-r1.ebuild
@@ -0,0 +1,56 @@
+# Copyright 1999-2012 Gentoo Foundation
+# Distributed under the terms of the GNU General Public License v2
+# $Header: /var/cvsroot/gentoo-x86/media-gfx/optipng/optipng-0.7.3-r1.ebuild,v 1.1 2012/09/22 20:42:18 sping Exp $
+
+EAPI=4
+
+inherit eutils toolchain-funcs
+
+DESCRIPTION="Compress PNG files without affecting image quality"
+HOMEPAGE="http://optipng.sourceforge.net/"
+SRC_URI="mirror://sourceforge/${PN}/${P}.tar.gz"
+
+LICENSE="ZLIB"
+SLOT="0"
+KEYWORDS="~alpha ~amd64 ~ppc ~ppc64 ~x86 ~amd64-linux ~x86-linux ~ppc-macos ~x86-macos ~x86-solaris"
+IUSE=""
+
+RDEPEND="sys-libs/zlib
+	media-libs/libpng:0"
+DEPEND="${RDEPEND}
+	sys-apps/findutils"
+
+src_prepare() {
+	rm -R src/{libpng,zlib} || die
+	find . -type d -name build -exec rm -R {} + || die
+
+	# next release is almost a complete rewrite, so plug this compilation
+	# problem in anticipation of the much (c)leaner(?) rewrite
+	sed -i \
+		-e 's/^#ifdef AT_FDCWD/#if defined(AT_FDCWD) \&\& !(defined (__SVR4) \&\& defined (__sun))/' \
+		src/optipng/osys.c || die
+
+	tc-export CC AR RANLIB
+}
+
+src_configure() {
+	./configure \
+		-with-system-libpng \
+		-with-system-zlib \
+		|| die "configure failed"
+}
+
+src_compile() {
+	emake \
+		-C src/optipng \
+		GENTOO_CFLAGS="${CFLAGS}" \
+		GENTOO_LDFLAGS="${LDFLAGS}"
+}
+
+src_install() {
+	dodoc README.txt doc/*.txt
+	dohtml doc/*.html
+	doman src/${PN}/man/${PN}.1
+
+	dobin src/${PN}/${PN}
+}