add multilib support wrt #497774, patch by Michael Mair-Keimberger

(Portage version: 2.2.10/cvs/Linux x86_64, signed Manifest commit with key BDEED020)

2 files changed, 74 insertions, 2 deletions

diff --git a/media-libs/aalib/ChangeLog b/media-libs/aalib/ChangeLog
index e19a3fd0287a..ed0f89443f3d 100644
--- a/media-libs/aalib/ChangeLog
+++ b/media-libs/aalib/ChangeLog
@@ -1,6 +1,11 @@
 # ChangeLog for media-libs/aalib
-# Copyright 1999-2013 Gentoo Foundation; Distributed under the GPL v2
-# $Header: /var/cvsroot/gentoo-x86/media-libs/aalib/ChangeLog,v 1.49 2013/05/08 09:49:06 blueness Exp $
+# Copyright 1999-2014 Gentoo Foundation; Distributed under the GPL v2
+# $Header: /var/cvsroot/gentoo-x86/media-libs/aalib/ChangeLog,v 1.50 2014/04/18 13:46:37 hasufell Exp $
+
+*aalib-1.4_rc5-r6 (18 Apr 2014)
+
+  18 Apr 2014; Julian Ospald <hasufell@gentoo.org> +aalib-1.4_rc5-r6.ebuild:
+  add multilib support wrt #497774, patch by Michael Mair-Keimberger
 
   08 May 2013; Anthony G. Basile <blueness@gentoo.org> aalib-1.4_rc5.ebuild:
   Fix missing eautoreconf, bug #467988, comment #4
diff --git a/media-libs/aalib/aalib-1.4_rc5-r6.ebuild b/media-libs/aalib/aalib-1.4_rc5-r6.ebuild
new file mode 100644
index 000000000000..f02cd2f00f4b
--- /dev/null
+++ b/media-libs/aalib/aalib-1.4_rc5-r6.ebuild
@@ -0,0 +1,67 @@
+# Copyright 1999-2014 Gentoo Foundation
+# Distributed under the terms of the GNU General Public License v2
+# $Header: /var/cvsroot/gentoo-x86/media-libs/aalib/aalib-1.4_rc5-r6.ebuild,v 1.1 2014/04/18 13:46:37 hasufell Exp $
+
+EAPI=5
+
+inherit autotools-multilib eutils toolchain-funcs
+
+MY_P="${P/_/}"
+S="${WORKDIR}/${PN}-1.4.0"
+
+DESCRIPTION="A ASCII-Graphics Library"
+HOMEPAGE="http://aa-project.sourceforge.net/aalib/"
+SRC_URI="mirror://sourceforge/aa-project/${MY_P}.tar.gz"
+
+LICENSE="GPL-2"
+SLOT="0"
+KEYWORDS="~alpha ~amd64 ~arm ~hppa ~ia64 ~mips ~ppc ~ppc64 ~s390 ~sh ~sparc ~x86 ~amd64-fbsd ~x86-fbsd"
+IUSE="X slang gpm static-libs"
+
+RDEPEND="X? ( x11-libs/libX11[${MULTILIB_USEDEP}] )
+	gpm? ( sys-libs/gpm[${MULTILIB_USEDEP}] )
+	slang? ( >=sys-libs/slang-1.4.2[${MULTILIB_USEDEP}] )
+	>=sys-libs/ncurses-5.1[${MULTILIB_USEDEP}]
+"
+DEPEND="${RDEPEND}
+	virtual/pkgconfig
+	X? ( x11-proto/xproto )
+"
+
+DOCS="ANNOUNCE AUTHORS ChangeLog NEWS README*"
+
+src_prepare() {
+	epatch "${FILESDIR}"/${PN}-1.4_rc4-gentoo.patch
+	epatch "${FILESDIR}"/${PN}-1.4_rc4-m4.patch
+	epatch "${FILESDIR}"/${PN}-1.4_rc5-fix-protos.patch #224267
+	epatch "${FILESDIR}"/${PN}-1.4_rc5-fix-aarender.patch #214142
+	epatch "${FILESDIR}"/${PN}-1.4_rc5-tinfo.patch #468566
+
+	sed -i -e 's:#include <malloc.h>:#include <stdlib.h>:g' "${S}"/src/*.c
+
+	# Fix bug #165617.
+	use gpm || sed -i \
+		's/gpm_mousedriver_test=yes/gpm_mousedriver_test=no/' "${S}/configure.in"
+
+	#467988 automake-1.13
+	mv configure.{in,ac} || die
+	sed -i 's/AM_CONFIG_HEADER/AC_CONFIG_HEADERS/g' configure.ac || die
+
+	eautoreconf
+}
+
+src_configure() {
+	local myeconfargs=(
+		$(use_with slang slang-driver)
+		$(use_with X x11-driver)
+		$(use_enable static-libs static)
+	)
+
+	PKG_CONFIG=$(tc-getPKG_CONFIG) \
+	autotools-multilib_src_configure
+}
+
+src_install() {
+	autotools-multilib_src_install
+	use static-libs || prune_libtool_files --all
+}