Take over maintenance, version bump 3.1.3: static-libs, la files removal, install manual pages in private location (bug 312043), install headers in own subdir (bug 297644)

(Portage version: 2.2_rc67/cvs/Linux x86_64)

5 files changed, 113 insertions, 77 deletions

diff --git a/media-libs/coin/ChangeLog b/media-libs/coin/ChangeLog
index d974cab3bd60..15d017db0aec 100644
--- a/media-libs/coin/ChangeLog
+++ b/media-libs/coin/ChangeLog
@@ -1,6 +1,14 @@
 # ChangeLog for media-libs/coin
 # Copyright 1999-2010 Gentoo Foundation; Distributed under the GPL v2
-# $Header: /var/cvsroot/gentoo-x86/media-libs/coin/ChangeLog,v 1.30 2010/06/25 12:15:47 jlec Exp $
+# $Header: /var/cvsroot/gentoo-x86/media-libs/coin/ChangeLog,v 1.31 2010/06/25 20:26:39 reavertm Exp $
+
+*coin-3.1.3 (25 Jun 2010)
+
+  25 Jun 2010; Maciej Mrozowski <reavertm@gentoo.org> -coin-3.1.2.ebuild,
+  +coin-3.1.3.ebuild, metadata.xml:
+  Take over maintenance, version bump 3.1.3: static-libs, la files removal,
+  install manual pages in private location (bug 312043), install headers
+  in own subdir (bug 297644)
 
   25 Jun 2010; Justin Lecher <jlec@gentoo.org> coin-3.1.0.ebuild,
   coin-3.1.2.ebuild:
@@ -111,11 +119,11 @@
   update to later snapshot (bug 20541)
 
   06 Dec 2002; Rodney Rees <manson@gentoo.org> : changed sparc ~sparc keywords
- 
+
 *coin-20010601-r1 (1 Feb 2002)
 
   1 Feb 2002; G.Bevin <gbevin@gentoo.org> ChangeLog :
-  
+
   Added initial ChangeLog which should be updated whenever the package is
   updated in any way. This changelog is targetted to users. This means that the
   comments should well explained and written in clean English. The details about
diff --git a/media-libs/coin/coin-3.1.0.ebuild b/media-libs/coin/coin-3.1.0.ebuild
index c09c29237f47..a0c905c12ccd 100644
--- a/media-libs/coin/coin-3.1.0.ebuild
+++ b/media-libs/coin/coin-3.1.0.ebuild
@@ -1,6 +1,6 @@
 # Copyright 1999-2010 Gentoo Foundation
 # Distributed under the terms of the GNU General Public License v2
-# $Header: /var/cvsroot/gentoo-x86/media-libs/coin/coin-3.1.0.ebuild,v 1.4 2010/06/25 12:15:47 jlec Exp $
+# $Header: /var/cvsroot/gentoo-x86/media-libs/coin/coin-3.1.0.ebuild,v 1.5 2010/06/25 20:26:39 reavertm Exp $
 
 EAPI=2
 
@@ -16,7 +16,7 @@ SRC_URI="ftp://ftp.coin3d.org/pub/coin/src/all/${MY_P}.tar.gz"
 LICENSE="|| ( GPL-2 PEL )"
 SLOT="0"
 KEYWORDS="~amd64 ~ppc x86"
-IUSE="debug doc java javascript openal"
+IUSE="debug doc javascript openal"
 
 RDEPEND="
 	!x11-libs/qwt[doc]
@@ -29,7 +29,6 @@ RDEPEND="
 	x11-libs/libX11
 	x11-libs/libXt
 	x11-libs/libXext
-	java? ( virtual/jdk )
 	javascript? ( dev-lang/spidermonkey )
 	openal? ( media-libs/openal )"
 
@@ -44,6 +43,7 @@ src_prepare() {
 src_configure() {
 	econf \
 		htmldir=/usr/share/doc/${PF}/html				\
+		--disable-java-wrapper							\
 		--enable-3ds-import								\
 		--enable-threadsafe								\
 		--with-fontconfig								\
@@ -52,7 +52,6 @@ src_configure() {
 		$(use_enable debug symbols)						\
 		$(use_enable doc html)							\
 		$(use_enable doc man)							\
-		$(use_enable java java-wrapper)					\
 		$(use_enable javascript javascript-api)			\
 		$(use_enable openal sound)						\
 		$(use_with javascript spidermonkey)				\
diff --git a/media-libs/coin/coin-3.1.2.ebuild b/media-libs/coin/coin-3.1.2.ebuild
deleted file mode 100644
index ac6cb21e1377..000000000000
--- a/media-libs/coin/coin-3.1.2.ebuild
+++ /dev/null
@@ -1,69 +0,0 @@
-# Copyright 1999-2010 Gentoo Foundation
-# Distributed under the terms of the GNU General Public License v2
-# $Header: /var/cvsroot/gentoo-x86/media-libs/coin/coin-3.1.2.ebuild,v 1.2 2010/06/25 12:15:47 jlec Exp $
-
-EAPI=2
-
-inherit eutils
-
-MY_P=${P/c/C}
-S="${WORKDIR}/${MY_P}"
-
-DESCRIPTION="a high-level 3D graphics toolkit, fully compatible with SGI Open Inventor 2.1."
-HOMEPAGE="http://www.coin3d.org/"
-SRC_URI="ftp://ftp.coin3d.org/pub/coin/src/all/${MY_P}.tar.gz"
-
-LICENSE="|| ( GPL-2 PEL )"
-SLOT="0"
-KEYWORDS="~amd64 ~ppc ~x86"
-IUSE="debug doc java javascript openal"
-
-RDEPEND="
-	!x11-libs/qwt[doc]
-	media-libs/fontconfig
-	media-libs/freetype
-	virtual/opengl
-	virtual/glu
-	x11-libs/libICE
-	x11-libs/libSM
-	x11-libs/libX11
-	x11-libs/libXt
-	x11-libs/libXext
-	java? ( virtual/jdk )
-	javascript? ( dev-lang/spidermonkey )
-	openal? ( media-libs/openal )"
-
-DEPEND="${RDEPEND}
-	doc? ( app-doc/doxygen )
-	dev-util/pkgconfig"
-
-src_prepare() {
-	epatch "${FILESDIR}"/${PN}-3.1.0-javascript.patch
-}
-
-src_configure() {
-	econf \
-		htmldir=/usr/share/doc/${PF}/html				\
-		--enable-3ds-import								\
-		--enable-threadsafe								\
-		--with-fontconfig								\
-		--with-freetype									\
-		$(use_enable debug)								\
-		$(use_enable debug symbols)						\
-		$(use_enable doc html)							\
-		$(use_enable doc man)							\
-		$(use_enable java java-wrapper)					\
-		$(use_enable javascript javascript-api)			\
-		$(use_enable openal sound)						\
-		$(use_with javascript spidermonkey)				\
-		$(use_with openal)
-}
-
-src_compile() {
-	emake || die "emake failed"
-}
-
-src_install() {
-	emake DESTDIR="${D}" install || die "emake install failed"
-	dodoc AUTHORS FAQ FAQ.legal NEWS README RELNOTES THANKS	docs/ChangeLog.v${PV}
-}
diff --git a/media-libs/coin/coin-3.1.3.ebuild b/media-libs/coin/coin-3.1.3.ebuild
new file mode 100644
index 000000000000..3e92da186c36
--- /dev/null
+++ b/media-libs/coin/coin-3.1.3.ebuild
@@ -0,0 +1,98 @@
+# Copyright 1999-2010 Gentoo Foundation
+# Distributed under the terms of the GNU General Public License v2
+# $Header: /var/cvsroot/gentoo-x86/media-libs/coin/coin-3.1.3.ebuild,v 1.1 2010/06/25 20:26:39 reavertm Exp $
+
+EAPI=2
+
+inherit eutils base flag-o-matic
+
+MY_P=${P/c/C}
+S="${WORKDIR}/${MY_P}"
+
+DESCRIPTION="A high-level 3D graphics toolkit, fully compatible with SGI Open Inventor 2.1."
+HOMEPAGE="http://www.coin3d.org/"
+SRC_URI="ftp://ftp.coin3d.org/pub/coin/src/all/${MY_P}.tar.gz"
+
+LICENSE="|| ( GPL-2 PEL )"
+KEYWORDS="~amd64 ~ppc ~x86"
+SLOT="0"
+IUSE="debug doc javascript openal static-libs threads"
+
+RDEPEND="
+	app-arch/bzip2
+	dev-libs/expat
+	media-libs/fontconfig
+	media-libs/freetype:2
+	sys-libs/zlib
+	virtual/opengl
+	virtual/glu
+	x11-libs/libICE
+	x11-libs/libSM
+	x11-libs/libX11
+	x11-libs/libXext
+	javascript? ( dev-lang/spidermonkey )
+	openal? ( media-libs/openal )
+"
+DEPEND="${RDEPEND}
+	dev-util/pkgconfig
+	x11-proto/xextproto
+	doc? ( app-doc/doxygen )
+"
+
+DOCS=(
+	AUTHORS FAQ FAQ.legal NEWS README RELNOTES THANKS
+	docs/{ChangeLog.v${PV},HACKING,oiki-launch.txt}
+)
+
+PATCHES=(
+	"${FILESDIR}/${PN}-3.1.0-javascript.patch"
+)
+
+src_configure() {
+	MANDIR=/usr/share/Coin/man
+	append-cppflags -I/usr/include/freetype2
+	# Prefer link-time linking over dlopen
+	econf \
+		htmldir="/usr/share/doc/${PF}/html" \
+		--disable-dl-fontconfig \
+		--disable-dl-freetype \
+		--disable-dl-libbzip2 \
+		--disable-dl-openal \
+		--disable-dl-zlib \
+		--disable-dyld \
+		--disable-loadlibrary \
+		--disable-java-wrapper \
+		--enable-3ds-import \
+		--enable-compact \
+		--enable-dl-glu \
+		--enable-dl-spidermonkey \
+		--enable-system-expat \
+		--includedir="/usr/include/${PN}" \
+		--mandir="${MANDIR}" \
+		--with-fontconfig \
+		--with-freetype \
+		$(use_enable debug) \
+		$(use_enable debug symbols) \
+		$(use_enable doc html) \
+		$(use_enable doc man) \
+		$(use_enable javascript javascript-api) \
+		$(use_enable openal sound) \
+		$(use_enable static-libs static) \
+		$(use_enable threads threadsafe) \
+		$(use_with javascript spidermonkey) \
+		$(use_with openal)
+}
+
+src_install() {
+	base_src_install
+
+	if use doc; then
+		cat >"${T}/50coin" <<-__EOF__
+MANPATH=${MANDIR}
+__EOF__
+		doenvd "${T}/50coin"
+	fi
+
+	# Remove libtool files when not needed.
+	use static-libs || rm -f "${D}"/usr/lib*/*.la
+}
diff --git a/media-libs/coin/metadata.xml b/media-libs/coin/metadata.xml
index 73420b6cf0f0..b95a6037b551 100644
--- a/media-libs/coin/metadata.xml
+++ b/media-libs/coin/metadata.xml
@@ -3,6 +3,6 @@
 <pkgmetadata>
 <herd>no-herd</herd>
 <maintainer>
-  <email>maintainer-needed@gentoo.org</email>
+  <email>reavertm@gentoo.org</email>
 </maintainer>
 </pkgmetadata>