Bump to 0.10.31. Bunch of fixes, new APIs for date/time and faster, unchecked bitreader/bytewriter.

(Portage version: 2.2.0_alpha10/cvs/Linux x86_64)

2 files changed, 65 insertions, 1 deletions

diff --git a/media-libs/gstreamer/ChangeLog b/media-libs/gstreamer/ChangeLog
index b11a5f16541f..27aac047cf16 100644
--- a/media-libs/gstreamer/ChangeLog
+++ b/media-libs/gstreamer/ChangeLog
@@ -1,6 +1,13 @@
 # ChangeLog for media-libs/gstreamer
 # Copyright 1999-2010 Gentoo Foundation; Distributed under the GPL v2
-# $Header: /var/cvsroot/gentoo-x86/media-libs/gstreamer/ChangeLog,v 1.275 2010/09/29 01:10:06 flameeyes Exp $
+# $Header: /var/cvsroot/gentoo-x86/media-libs/gstreamer/ChangeLog,v 1.276 2010/12/24 09:04:05 ford_prefect Exp $
+
+*gstreamer-0.10.31 (24 Dec 2010)
+
+  24 Dec 2010; Arun Raghavan <ford_prefect@gentoo.org>
+  +gstreamer-0.10.31.ebuild:
+  Bump to 0.10.31. Bunch of fixes, new APIs for date/time and faster, unchecked
+  bitreader/bytewriter.
 
   29 Sep 2010; Diego E. Pettenò <flameeyes@gentoo.org>
   gstreamer-0.10.30.ebuild:
diff --git a/media-libs/gstreamer/gstreamer-0.10.31.ebuild b/media-libs/gstreamer/gstreamer-0.10.31.ebuild
new file mode 100644
index 000000000000..30c2e3328868
--- /dev/null
+++ b/media-libs/gstreamer/gstreamer-0.10.31.ebuild
@@ -0,0 +1,57 @@
+# Copyright 1999-2010 Gentoo Foundation
+# Distributed under the terms of the GNU General Public License v2
+# $Header: /var/cvsroot/gentoo-x86/media-libs/gstreamer/gstreamer-0.10.31.ebuild,v 1.1 2010/12/24 09:04:05 ford_prefect Exp $
+
+EAPI=2
+
+inherit eutils multilib versionator
+
+# Create a major/minor combo for our SLOT and executables suffix
+PV_MAJ_MIN=$(get_version_component_range '1-2')
+
+DESCRIPTION="Streaming media framework"
+HOMEPAGE="http://gstreamer.sourceforge.net"
+SRC_URI="http://${PN}.freedesktop.org/src/${PN}/${P}.tar.bz2"
+
+LICENSE="LGPL-2"
+SLOT=${PV_MAJ_MIN}
+KEYWORDS="~alpha ~amd64 ~arm ~hppa ~ia64 ~ppc ~ppc64 ~sh ~sparc ~x86 ~x86-fbsd"
+IUSE="+introspection nls test"
+
+RDEPEND=">=dev-libs/glib-2.20:2
+	dev-libs/libxml2
+	introspection? ( >=dev-libs/gobject-introspection-0.6.3 )
+	!<media-libs/gst-plugins-base-0.10.26"
+	# ^^ queue2 move, mustn't have both libgstcoreleements.so and libgstqueue2.so at runtime providing the element at once
+DEPEND="${RDEPEND}
+	dev-util/pkgconfig
+	dev-util/gtk-doc-am
+	nls? ( sys-devel/gettext )"
+
+src_configure() {
+	# Disable static archives, dependency tracking and examples
+	# to speed up build time
+	econf \
+		--disable-static \
+		--disable-dependency-tracking \
+		$(use_enable nls) \
+		--disable-valgrind \
+		--disable-examples \
+		--enable-check \
+		$(use_enable introspection) \
+		$(use_enable test tests) \
+		--with-package-name="GStreamer ebuild for Gentoo" \
+		--with-package-origin="http://packages.gentoo.org/package/media-libs/gstreamer"
+}
+
+src_install() {
+	emake DESTDIR="${D}" install || die "emake install failed."
+	dodoc AUTHORS ChangeLog NEWS MAINTAINERS README RELEASE
+
+	# Remove unversioned binaries to allow SLOT installations in future
+	cd "${D}"/usr/bin
+	local gst_bins
+	for gst_bins in $(ls *-${PV_MAJ_MIN}); do
+		rm -f ${gst_bins/-${PV_MAJ_MIN}/}
+	done
+}