add multilib support

(Portage version: 2.2.10/cvs/Linux x86_64, signed Manifest commit with key BDEED020)

2 files changed, 57 insertions, 2 deletions

diff --git a/media-libs/smpeg2/ChangeLog b/media-libs/smpeg2/ChangeLog
index 98d340030dd8..a93f2c66e0ea 100644
--- a/media-libs/smpeg2/ChangeLog
+++ b/media-libs/smpeg2/ChangeLog
@@ -1,6 +1,11 @@
 # ChangeLog for media-libs/smpeg2
-# Copyright 1999-2013 Gentoo Foundation; Distributed under the GPL v2
-# $Header: /var/cvsroot/gentoo-x86/media-libs/smpeg2/ChangeLog,v 1.2 2013/10/07 15:36:12 hasufell Exp $
+# Copyright 1999-2014 Gentoo Foundation; Distributed under the GPL v2
+# $Header: /var/cvsroot/gentoo-x86/media-libs/smpeg2/ChangeLog,v 1.3 2014/04/18 21:22:11 hasufell Exp $
+
+*smpeg2-2.0.0-r2 (18 Apr 2014)
+
+  18 Apr 2014; Julian Ospald <hasufell@gentoo.org> +smpeg2-2.0.0-r2.ebuild:
+  add multilib support
 
 *smpeg2-2.0.0-r1 (07 Oct 2013)
 
diff --git a/media-libs/smpeg2/smpeg2-2.0.0-r2.ebuild b/media-libs/smpeg2/smpeg2-2.0.0-r2.ebuild
new file mode 100644
index 000000000000..9cc912946677
--- /dev/null
+++ b/media-libs/smpeg2/smpeg2-2.0.0-r2.ebuild
@@ -0,0 +1,50 @@
+# Copyright 1999-2014 Gentoo Foundation
+# Distributed under the terms of the GNU General Public License v2
+# $Header: /var/cvsroot/gentoo-x86/media-libs/smpeg2/smpeg2-2.0.0-r2.ebuild,v 1.1 2014/04/18 21:22:11 hasufell Exp $
+
+EAPI=5
+inherit eutils toolchain-funcs autotools multilib-minimal
+
+MY_P=smpeg-${PV}
+DESCRIPTION="SDL MPEG Player Library"
+HOMEPAGE="http://icculus.org/smpeg/"
+SRC_URI="http://dev.gentoo.org/~hasufell/distfiles/${MY_P}.tar.bz2"
+
+LICENSE="LGPL-2"
+SLOT="0"
+KEYWORDS="~amd64 ~x86"
+IUSE="debug mmx static-libs"
+
+DEPEND="media-libs/libsdl2[${MULTILIB_USEDEP}]"
+RDEPEND="${DEPEND}"
+
+DOCS=( CHANGES README README.SDL_mixer TODO )
+
+S=${WORKDIR}/${MY_P}
+
+src_prepare() {
+	epatch "${FILESDIR}"/${P}-smpeg2-config.patch
+
+	# avoid file collision with media-libs/smpeg
+	sed -i \
+		-e '/plaympeg/d' \
+		Makefile.am || die
+
+	AT_M4DIR="/usr/share/aclocal acinclude" eautoreconf
+}
+
+multilib_src_configure() {
+	# the debug option is bogus ... all it does is add extra
+	# optimizations if you pass --disable-debug
+	ECONF_SOURCE="${S}" econf \
+		$(use_enable static-libs static) \
+		--disable-rpath \
+		--enable-debug \
+		--disable-sdltest \
+		$(use_enable mmx) \
+		$(use_enable debug assertions)
+}
+
+multilib_src_install_all() {
+	use static-libs || prune_libtool_files
+}