Add static-libs support (bug #378307 by Agostino Sarubbo and Nikoli).

(Portage version: 2.2.0_alpha58/cvs/Linux x86_64)

3 files changed, 97 insertions, 11 deletions

diff --git a/media-libs/libvpx/ChangeLog b/media-libs/libvpx/ChangeLog
index 2ccf8a556f80..6d54627d7030 100644
--- a/media-libs/libvpx/ChangeLog
+++ b/media-libs/libvpx/ChangeLog
@@ -1,6 +1,12 @@
 # ChangeLog for media-libs/libvpx
 # Copyright 1999-2011 Gentoo Foundation; Distributed under the GPL v2
-# $Header: /var/cvsroot/gentoo-x86/media-libs/libvpx/ChangeLog,v 1.31 2011/08/08 10:43:05 lu_zero Exp $
+# $Header: /var/cvsroot/gentoo-x86/media-libs/libvpx/ChangeLog,v 1.32 2011/09/21 20:35:58 radhermit Exp $
+
+*libvpx-0.9.7-r1 (21 Sep 2011)
+
+  21 Sep 2011; Tim Harder <radhermit@gentoo.org> +libvpx-0.9.7-r1.ebuild,
+  libvpx-9999.ebuild:
+  Add static-libs support (bug #378307 by Agostino Sarubbo and Nikoli).
 
 *libvpx-0.9.7 (08 Aug 2011)
 
diff --git a/media-libs/libvpx/libvpx-0.9.7-r1.ebuild b/media-libs/libvpx/libvpx-0.9.7-r1.ebuild
new file mode 100644
index 000000000000..0a759bb491df
--- /dev/null
+++ b/media-libs/libvpx/libvpx-0.9.7-r1.ebuild
@@ -0,0 +1,80 @@
+# Copyright 1999-2011 Gentoo Foundation
+# Distributed under the terms of the GNU General Public License v2
+# $Header: /var/cvsroot/gentoo-x86/media-libs/libvpx/libvpx-0.9.7-r1.ebuild,v 1.1 2011/09/21 20:35:58 radhermit Exp $
+
+EAPI=4
+inherit eutils multilib toolchain-funcs
+
+if [[ ${PV} == *9999* ]]; then
+	inherit git-2
+	EGIT_REPO_URI="git://review.webmproject.org/${PN}.git"
+	KEYWORDS=""
+elif [[ ${PV} == *pre* ]]; then
+	SRC_URI="mirror://gentoo/${P}.tar.bz2"
+	KEYWORDS="~alpha ~amd64 ~arm ~ppc ~ppc64 ~x86 ~x86-fbsd ~amd64-linux ~x86-linux"
+else
+	MY_P="${PN}-v${PV}"
+	SRC_URI="http://webm.googlecode.com/files/${MY_P}.tar.bz2"
+	KEYWORDS="~alpha ~amd64 ~arm ~ppc ~ppc64 ~x86 ~x86-fbsd ~amd64-linux ~x86-linux"
+	S="${WORKDIR}/${MY_P}"
+fi
+
+DESCRIPTION="WebM VP8 Codec SDK"
+HOMEPAGE="http://www.webmproject.org"
+
+LICENSE="BSD"
+SLOT="0"
+IUSE="altivec debug doc mmx postproc sse sse2 sse3 ssse3 static-libs +threads"
+
+RDEPEND=""
+DEPEND="amd64? ( dev-lang/yasm )
+	x86? ( dev-lang/yasm )
+	x86-fbsd? ( dev-lang/yasm )
+	doc? (
+		app-doc/doxygen
+		dev-lang/php
+	)
+"
+
+REQUIRED_USE="
+	sse2? ( mmx )
+	"
+
+src_prepare() {
+	epatch "${FILESDIR}"/${PN}-0.9.5-enable-shared.patch
+}
+
+src_configure() {
+	tc-export CC
+	local archparams=""
+	[ "$ABI" = "x86" ] && archparams=" --target=x86-linux-gcc"
+	[ "$ABI" = "amd64" ] && archparams=" --target=x86_64-linux-gcc"
+	( use x86 || use amd64 ) && archparams+=" --as=yasm"
+	./configure \
+		--prefix="${EPREFIX}"/usr \
+		--libdir="${EPREFIX}"/usr/$(get_libdir) \
+		--enable-pic \
+		--enable-vp8 \
+		--enable-shared \
+		$(use_enable altivec) \
+		$(use_enable debug debug-libs) \
+		$(use_enable debug) \
+		$(use_enable doc install-docs) \
+		$(use_enable mmx) \
+		$(use_enable postproc) \
+		$(use_enable sse) \
+		$(use_enable sse2) \
+		$(use_enable sse3) \
+		$(use_enable ssse3) \
+		$(use_enable static-libs static) \
+		$(use_enable threads multithread) \
+		$archparams \
+		|| die
+}
+
+src_install() {
+	# http://bugs.gentoo.org/show_bug.cgi?id=323805
+	emake -j1 DESTDIR="${D}" install
+
+	dodoc AUTHORS CHANGELOG README
+}
diff --git a/media-libs/libvpx/libvpx-9999.ebuild b/media-libs/libvpx/libvpx-9999.ebuild
index 004575f825b8..15640373f95d 100644
--- a/media-libs/libvpx/libvpx-9999.ebuild
+++ b/media-libs/libvpx/libvpx-9999.ebuild
@@ -1,6 +1,6 @@
 # Copyright 1999-2011 Gentoo Foundation
 # Distributed under the terms of the GNU General Public License v2
-# $Header: /var/cvsroot/gentoo-x86/media-libs/libvpx/libvpx-9999.ebuild,v 1.15 2011/07/29 02:11:44 zmedico Exp $
+# $Header: /var/cvsroot/gentoo-x86/media-libs/libvpx/libvpx-9999.ebuild,v 1.16 2011/09/21 20:35:58 radhermit Exp $
 
 EAPI=4
 inherit multilib toolchain-funcs
@@ -22,7 +22,7 @@ HOMEPAGE="http://www.webmproject.org"
 
 LICENSE="BSD"
 SLOT="0"
-IUSE="altivec debug doc mmx postproc sse sse2 sse3 ssse3 sse4_1 +threads"
+IUSE="altivec debug doc mmx postproc sse sse2 sse3 ssse3 sse4_1 static-libs +threads"
 
 RDEPEND=""
 DEPEND="amd64? ( dev-lang/yasm )
@@ -47,22 +47,22 @@ src_configure() {
 		--enable-vp8 \
 		--enable-shared \
 		$(use_enable altivec) \
+		$(use_enable debug debug-libs) \
+		$(use_enable debug) \
+		$(use_enable doc install-docs) \
 		$(use_enable mmx) \
+		$(use_enable postproc) \
 		$(use_enable sse) \
 		$(use_enable sse2) \
 		$(use_enable sse3) \
-		$(use_enable ssse3) \
 		$(use_enable sse4_1) \
-		$(use_enable debug) \
-		$(use_enable debug debug-libs) \
-		$(use_enable doc install-docs) \
-		$(use_enable postproc) \
+		$(use_enable ssse3) \
+		$(use_enable static-libs static ) \
 		$(use_enable threads multithread) \
 		|| die
 }
 
 src_install() {
-	emake DESTDIR="${D}" install || die
-
-	dodoc AUTHORS CHANGELOG README || die
+	emake DESTDIR="${D}" install
+	dodoc AUTHORS CHANGELOG README
 }