Version bump wrt bug #480536.

(Portage version: 2.2.0/cvs/Linux x86_64, signed Manifest commit with key 675D0D2C)

3 files changed, 73 insertions, 1 deletions

diff --git a/media-sound/kwave/ChangeLog b/media-sound/kwave/ChangeLog
index 8df764050f65..13ba83fc785b 100644
--- a/media-sound/kwave/ChangeLog
+++ b/media-sound/kwave/ChangeLog
@@ -1,6 +1,12 @@
 # ChangeLog for media-sound/kwave
 # Copyright 1999-2013 Gentoo Foundation; Distributed under the GPL v2
-# $Header: /var/cvsroot/gentoo-x86/media-sound/kwave/ChangeLog,v 1.30 2013/06/11 20:22:19 johu Exp $
+# $Header: /var/cvsroot/gentoo-x86/media-sound/kwave/ChangeLog,v 1.31 2013/08/14 12:18:16 kensington Exp $
+
+*kwave-0.8.10 (14 Aug 2013)
+
+  14 Aug 2013; Michael Palimaka <kensington@gentoo.org> +kwave-0.8.10.ebuild,
+  metadata.xml:
+  Version bump wrt bug #480536.
 
   11 Jun 2013; Johannes Huber <johu@gentoo.org> -kwave-0.8.8-r1.ebuild:
   Remove old.
diff --git a/media-sound/kwave/kwave-0.8.10.ebuild b/media-sound/kwave/kwave-0.8.10.ebuild
new file mode 100644
index 000000000000..9112db81fccb
--- /dev/null
+++ b/media-sound/kwave/kwave-0.8.10.ebuild
@@ -0,0 +1,65 @@
+# Copyright 1999-2013 Gentoo Foundation
+# Distributed under the terms of the GNU General Public License v2
+# $Header: /var/cvsroot/gentoo-x86/media-sound/kwave/kwave-0.8.10.ebuild,v 1.1 2013/08/14 12:18:16 kensington Exp $
+
+EAPI=5
+
+KDE_LINGUAS="cs de fr"
+KDE_HANDBOOK="optional"
+inherit kde4-base
+
+DESCRIPTION="A sound editor for KDE that can edit many types of audio files"
+HOMEPAGE="http://kwave.sourceforge.net/"
+SRC_URI="mirror://sourceforge/${PN}/${P}-1.tar.bz2"
+
+LICENSE="BSD GPL-2 LGPL-2
+	handbook? ( FDL-1.2 )"
+SLOT="4"
+KEYWORDS="~amd64 ~x86"
+IUSE="alsa debug flac handbook mp3 opus oss phonon pulseaudio vorbis"
+
+RDEPEND="
+	media-libs/audiofile:=
+	>=sci-libs/fftw-3
+	media-libs/libsamplerate
+	alsa? ( media-libs/alsa-lib )
+	flac? ( media-libs/flac )
+	mp3? (
+		media-libs/id3lib
+		media-libs/libmad
+		|| ( media-sound/lame media-sound/twolame media-sound/toolame )
+	)
+	opus? (
+		media-libs/libogg
+		media-libs/opus
+	)
+	phonon? ( media-libs/phonon )
+	pulseaudio? ( media-sound/pulseaudio )
+	vorbis? (
+		media-libs/libogg
+		media-libs/libvorbis
+	)
+"
+DEPEND="${RDEPEND}
+	$(add_kdebase_dep kdesdk-misc extras)
+	|| ( media-gfx/imagemagick[png,svg] media-gfx/graphicsmagick[imagemagick,png,svg] )
+"
+
+DOCS=( AUTHORS CHANGES LICENSES README TODO )
+
+src_configure() {
+	local mycmakeargs=(
+		-DWITH_SAMPLERATE=ON
+		$(cmake-utils_use_with alsa)
+		$(cmake-utils_use_with flac)
+		$(cmake-utils_use_with mp3)
+		$(cmake-utils_use_with vorbis OGG_VORBIS)
+		$(cmake-utils_use_with opus OGG_OPUS)
+		$(cmake-utils_use_with oss)
+		$(cmake-utils_use_with phonon)
+		$(cmake-utils_use_with pulseaudio)
+		$(cmake-utils_use debug)
+	)
+
+	kde4-base_src_configure
+}
diff --git a/media-sound/kwave/metadata.xml b/media-sound/kwave/metadata.xml
index 85477937989b..44d8bd70fea4 100644
--- a/media-sound/kwave/metadata.xml
+++ b/media-sound/kwave/metadata.xml
@@ -4,6 +4,7 @@
 	<herd>kde</herd>
 	<longdescription>With Kwave you can edit many sorts of wav-files including multi-channel files. You are able to alter and play back each channel on its own. Kwave also includes many plugins (most are still under development) to transform the wave-file in several ways and presents a graphical view with a complete zoom- and scroll capability.</longdescription>
 	<use>
+		<flag name="opus">Enable Opus audio codec support</flag>
 		<flag name="phonon">Enable playback via Phonon</flag>
 	</use>
 	<upstream>