Version bump.

(Portage version: 2.2.0_alpha98/cvs/Linux x86_64)

2 files changed, 80 insertions, 1 deletions

diff --git a/media-sound/ncmpcpp/ChangeLog b/media-sound/ncmpcpp/ChangeLog
index 66a4b4601b85..eb5c415351bb 100644
--- a/media-sound/ncmpcpp/ChangeLog
+++ b/media-sound/ncmpcpp/ChangeLog
@@ -1,6 +1,11 @@
 # ChangeLog for media-sound/ncmpcpp
 # Copyright 1999-2012 Gentoo Foundation; Distributed under the GPL v2
-# $Header: /var/cvsroot/gentoo-x86/media-sound/ncmpcpp/ChangeLog,v 1.61 2012/03/17 18:00:17 jer Exp $
+# $Header: /var/cvsroot/gentoo-x86/media-sound/ncmpcpp/ChangeLog,v 1.62 2012/04/02 11:51:03 jer Exp $
+
+*ncmpcpp-0.5.10 (02 Apr 2012)
+
+  02 Apr 2012; Jeroen Roovers <jer@gentoo.org> +ncmpcpp-0.5.10.ebuild:
+  Version bump.
 
 *ncmpcpp-0.5.9 (17 Mar 2012)
 
diff --git a/media-sound/ncmpcpp/ncmpcpp-0.5.10.ebuild b/media-sound/ncmpcpp/ncmpcpp-0.5.10.ebuild
new file mode 100644
index 000000000000..be6512f965b3
--- /dev/null
+++ b/media-sound/ncmpcpp/ncmpcpp-0.5.10.ebuild
@@ -0,0 +1,74 @@
+# Copyright 1999-2012 Gentoo Foundation
+# Distributed under the terms of the GNU General Public License v2
+# $Header: /var/cvsroot/gentoo-x86/media-sound/ncmpcpp/ncmpcpp-0.5.10.ebuild,v 1.1 2012/04/02 11:51:03 jer Exp $
+
+EAPI="4"
+
+inherit bash-completion-r1 eutils
+
+DESCRIPTION="An ncurses mpd client, ncmpc clone with some new features, written in C++"
+HOMEPAGE="http://unkart.ovh.org/ncmpcpp"
+SRC_URI="http://unkart.ovh.org/${PN}/${P}.tar.bz2"
+
+LICENSE="GPL-2"
+IUSE="bash-completion clock curl fftw iconv outputs taglib unicode visualizer"
+SLOT="0"
+KEYWORDS="~amd64 ~arm ~hppa ~ppc ~sparc ~x86"
+
+RDEPEND="
+	sys-libs/ncurses[unicode?]
+	>=media-libs/libmpdclient-2.1
+	curl? ( net-misc/curl )
+	visualizer? ( fftw? ( sci-libs/fftw:3.0 ) )
+	iconv? ( virtual/libiconv )
+	taglib? ( media-libs/taglib )
+"
+DEPEND="
+	${RDEPEND}
+	dev-util/pkgconfig
+"
+
+src_configure() {
+	local myconf=""
+	if use fftw; then
+		myconf="$(use_with visualizer fftw)"
+		if ! use visualizer; then
+			ewarn "For the fftw USE flag to have any effect, you must also"
+			ewarn "enable the visualizer USE flag."
+		fi
+	else
+		myconf="--without-fftw"
+	fi
+	econf \
+		${myconf} \
+		$(use_enable clock) \
+		$(use_enable outputs) \
+		$(use_enable unicode) \
+		$(use_enable visualizer) \
+		$(use_with curl) \
+		$(use_with iconv) \
+		$(use_with taglib)
+}
+
+src_install() {
+	default
+
+	# use dodoc instead of upstream's doc install which does not compress
+	rm -rf "${D}"/usr/share/doc/${PN}
+	dodoc AUTHORS NEWS doc/config doc/keys
+
+	newbashcomp doc/${PN}-completion.bash ${PN}
+}
+
+pkg_postinst() {
+	echo
+	elog "Example configuration files have been installed at"
+	elog "${ROOT}usr/share/doc/${PF}"
+	elog "${P} uses ~/.ncmpcpp/config and ~/.ncmpcpp/keys"
+	elog "as user configuration files."
+	echo
+	if use visualizer; then
+	elog "If you want to use the visualizer, you need mpd with fifo enabled."
+	echo
+	fi
+}