Added a patch to build PIC libs wrt bug #156016, removed -fPIC append-cflag for amd64, moved relevant stuff to src_unpack, made a patchset tarball

(Portage version: 2.1.2_rc2-r1)

3 files changed, 162 insertions, 1 deletions

diff --git a/media-video/gpac/ChangeLog b/media-video/gpac/ChangeLog
index 571b4d675bce..469fca9bcf64 100644
--- a/media-video/gpac/ChangeLog
+++ b/media-video/gpac/ChangeLog
@@ -1,6 +1,12 @@
 # ChangeLog for media-video/gpac
 # Copyright 1999-2006 Gentoo Foundation; Distributed under the GPL v2
-# $Header: /var/cvsroot/gentoo-x86/media-video/gpac/ChangeLog,v 1.27 2006/10/09 21:42:59 aballier Exp $
+# $Header: /var/cvsroot/gentoo-x86/media-video/gpac/ChangeLog,v 1.28 2006/11/23 19:57:37 aballier Exp $
+
+*gpac-0.4.2-r1 (23 Nov 2006)
+
+  23 Nov 2006; Alexis Ballier <aballier@gentoo.org> +gpac-0.4.2-r1.ebuild:
+  Added a patch to build PIC libs wrt bug #156016, removed -fPIC append-cflag
+  for amd64, moved relevant stuff to src_unpack, made a patchset tarball
 
   09 Oct 2006; Alexis Ballier <aballier@gentoo.org>
   +files/gpac-0.4.2-ffmpeg-snapshots-compat.patch, gpac-0.4.2.ebuild:
diff --git a/media-video/gpac/files/digest-gpac-0.4.2-r1 b/media-video/gpac/files/digest-gpac-0.4.2-r1
new file mode 100644
index 000000000000..b12762f34419
--- /dev/null
+++ b/media-video/gpac/files/digest-gpac-0.4.2-r1
@@ -0,0 +1,12 @@
+MD5 cfd9012bff83afdf5ad069b86d3063b6 26104-610.zip 292640
+RMD160 84b2642709ca072c30658a71a6d8bec50fceb2fe 26104-610.zip 292640
+SHA256 8dc9453f9b93202247b4800a1d946ae6eaa3b9d0c48237ae8848144feb88399e 26104-610.zip 292640
+MD5 e78e35eabe09eea50198f1a27b81eb60 26204-600.zip 255764
+RMD160 d85a1879e60deeaa9b371646a1d43dd07ae07777 26204-600.zip 255764
+SHA256 01513a7ae5d26ff16a37fba5deec2994a1992829180b4a15d9c646c51eb8fcdb 26204-600.zip 255764
+MD5 7c40146553ab621154e52a8c43344083 gpac-0.4.2-patches.tar.bz2 3899
+RMD160 42f9de741f27ca2a942728640582978a497e8721 gpac-0.4.2-patches.tar.bz2 3899
+SHA256 d0316a55dfc6077437645b8b11a6b0f77ff9d896efd31c8b6fae4d827e7e0e84 gpac-0.4.2-patches.tar.bz2 3899
+MD5 834910b42ef007410fcc49a5acd4656b gpac-0.4.2.tar.gz 3916608
+RMD160 17d2691651b633497ae96ec71912cfafa864c90a gpac-0.4.2.tar.gz 3916608
+SHA256 0e300b02824f12767e5fa0c70b138b6a17375c3d6000aea2568464a9bb1cd956 gpac-0.4.2.tar.gz 3916608
diff --git a/media-video/gpac/gpac-0.4.2-r1.ebuild b/media-video/gpac/gpac-0.4.2-r1.ebuild
new file mode 100644
index 000000000000..541cbab84fc7
--- /dev/null
+++ b/media-video/gpac/gpac-0.4.2-r1.ebuild
@@ -0,0 +1,143 @@
+# Copyright 1999-2006 Gentoo Foundation
+# Distributed under the terms of the GNU General Public License v2
+# $Header: /var/cvsroot/gentoo-x86/media-video/gpac/gpac-0.4.2-r1.ebuild,v 1.1 2006/11/23 19:57:37 aballier Exp $
+
+inherit eutils wxwidgets flag-o-matic multilib
+
+DESCRIPTION="GPAC is an implementation of the MPEG-4 Systems standard developed from scratch in ANSI C."
+HOMEPAGE="http://gpac.sourceforge.net/"
+NBV="610"
+WBV="600"
+SRC_URI="mirror://sourceforge/${PN}/${P}.tar.gz
+	mirror://gentoo/${P}-patches.tar.bz2
+	amr? ( http://www.3gpp.org/ftp/Specs/archive/26_series/26.104/26104-${NBV}.zip
+		http://www.3gpp.org/ftp/Specs/archive/26_series/26.204/26204-${WBV}.zip )"
+
+LICENSE="GPL-2"
+SLOT="0"
+KEYWORDS="~alpha ~amd64 ~ppc ~ppc64 ~x86"
+IUSE="aac amr debug ffmpeg jpeg javascript mad ogg opengl oss png sdl ssl theora truetype vorbis wxwindows xml xvid"
+
+S="${WORKDIR}/${PN}"
+
+RDEPEND="aac? ( media-libs/faad2 )
+	ffmpeg? ( media-video/ffmpeg )
+	jpeg? ( media-libs/jpeg )
+	javascript? ( dev-lang/spidermonkey )
+	mad? ( media-libs/libmad )
+	opengl? ( virtual/opengl )
+	ogg? ( media-libs/libogg )
+	png? ( media-libs/libpng )
+	vorbis? ( media-libs/libvorbis )
+	theora? ( media-libs/libtheora )
+	truetype? ( >=media-libs/freetype-2.1 )
+	wxwindows? ( >=x11-libs/wxGTK-2.6.0 )
+	xml? ( >=dev-libs/libxml2-2.6.0 )
+	xvid? ( >=media-libs/xvid-1.0.1 )
+	sdl? ( media-libs/libsdl )
+		|| ( (
+			x11-libs/libXt
+			x11-libs/libX11
+			x11-libs/libXext
+		) virtual/x11 )"
+
+DEPEND="${RDEPEND}"
+
+my_use() {
+	local flag="$1" pflag="${2:-$1}"
+	if use ${flag}; then
+		echo "--use-${pflag}=system"
+	else
+		echo "--use-${pflag}=no"
+	fi
+}
+
+src_unpack() {
+	unpack ${A}
+	cd "${S}"
+
+	epatch "${WORKDIR}/${P}-configure-ogg.patch"
+	epatch "${WORKDIR}/${P}-DESTDIR.patch"
+	epatch "${WORKDIR}/${P}-static-defs.patch"
+	epatch "${WORKDIR}/${P}-nostrip.patch"
+	epatch "${WORKDIR}/${P}-soname.patch"
+	epatch "${WORKDIR}/${P}-ffmpeg-snapshots-compat.patch"
+	sed -ie '/ldconfig / d' "${S}/Makefile"
+
+	if use amr; then
+		cd modules/amr_float_dec
+		unzip -jaq ${WORKDIR}/26104-${NBV}_ANSI_C_source_code.zip -d amr_nb_ft
+		unzip -jaq ${WORKDIR}/26204-${WBV}_ANSI-C_source_code.zip -d amr_wb_ft
+	fi
+
+	cd "${S}"
+
+	chmod +x configure
+	# make sure configure looks for wx-2.6
+	if use wxwindows; then
+		sed -i -e 's/wx-config/wx-config-2.6/' configure
+	else
+		sed -i 's:^has_wx="yes:has_wx="no:' configure
+	fi
+
+	use !sdl && sed -i 's:^has_sdl=yes:has_sdl=no:' configure
+
+	# fix hardcoded paths in source
+	sed -i -e \
+		"s:\([^f]\)\ M4_PLUGIN_PATH:\1 \"/usr/$(get_libdir)\":" \
+		applications/mp4client/main.c \
+		applications/osmo4_wx/wxOsmo4.cpp \
+		|| die "path fixation failed"
+
+	# make sure mozilla won't be used
+	sed -i -e 's/osmozilla//g' applications/Makefile
+
+	# use this to cute down on the warnings noise
+	append-flags -fno-strict-aliasing
+
+	# multilib libdir fix
+	sed -i 's:$(prefix)/lib:$(prefix)/'$(get_libdir)':' Makefile src/Makefile
+	sed -i 's:/lib/gpac:/'$(get_libdir)'/gpac:' configure
+
+	epatch "${WORKDIR}/${P}-pic.patch"
+}
+
+src_compile() {
+	if use ogg; then
+		myconf="${myconf} --use-ogg=system"
+		if use vorbis; then
+			myconf="${myconf} --use-vorbis=system"
+		fi
+		if use theora; then
+			myconf="${myconf} --use-theora=system"
+		fi
+	else
+		myconf="${myconf} --use-ogg=no"
+	fi
+
+	econf \
+		--enable-svg \
+		$(use_enable amr) \
+		$(use_enable debug) \
+		$(use_enable opengl) \
+		$(use_enable oss oss-audio) \
+		$(use_enable ssl) \
+		$(my_use ffmpeg) \
+		$(my_use aac faad) \
+		$(my_use jpeg) \
+		$(my_use mad) \
+		$(my_use javascript js) \
+		$(my_use png) \
+		$(my_use truetype ft) \
+		$(my_use xvid) \
+		${myconf} || die "configure died"
+
+	make OPTFLAGS="${CFLAGS}" || die "emake failed."
+}
+
+src_install() {
+	make OPTFLAGS="${CFLAGS}" DESTDIR="${D}" install || die
+	make OPTFLAGS="${CFLAGS}" DESTDIR="${D}" install-lib || die
+	dodoc AUTHORS BUGS Changelog README TODO
+	dodoc doc/*.html doc/*.txt doc/libisomedia_license doc/SGGen
+}