Bump to 0.14.0, new feature: effects

(Portage version: 2.1.9.46/cvs/Linux x86_64)

2 files changed, 94 insertions, 1 deletions

diff --git a/media-video/pitivi/ChangeLog b/media-video/pitivi/ChangeLog
index 580249d41494..f0f1e910894f 100644
--- a/media-video/pitivi/ChangeLog
+++ b/media-video/pitivi/ChangeLog
@@ -1,6 +1,11 @@
 # ChangeLog for media-video/pitivi
 # Copyright 1999-2011 Gentoo Foundation; Distributed under the GPL v2
-# $Header: /var/cvsroot/gentoo-x86/media-video/pitivi/ChangeLog,v 1.23 2011/02/03 22:24:28 eva Exp $
+# $Header: /var/cvsroot/gentoo-x86/media-video/pitivi/ChangeLog,v 1.24 2011/06/06 18:46:00 nirbheek Exp $
+
+*pitivi-0.14.0 (06 Jun 2011)
+
+  06 Jun 2011; Nirbheek Chauhan <nirbheek@gentoo.org> +pitivi-0.14.0.ebuild:
+  Bump to 0.14.0, new feature: effects
 
   03 Feb 2011; Gilles Dartiguelongue <eva@gentoo.org> -pitivi-0.11.3.ebuild,
   -pitivi-0.13.1.ebuild, -pitivi-0.13.3.ebuild, pitivi-0.13.5.ebuild:
diff --git a/media-video/pitivi/pitivi-0.14.0.ebuild b/media-video/pitivi/pitivi-0.14.0.ebuild
new file mode 100644
index 000000000000..ab6e99136d6d
--- /dev/null
+++ b/media-video/pitivi/pitivi-0.14.0.ebuild
@@ -0,0 +1,88 @@
+# Copyright 1999-2011 Gentoo Foundation
+# Distributed under the terms of the GNU General Public License v2
+# $Header: /var/cvsroot/gentoo-x86/media-video/pitivi/pitivi-0.14.0.ebuild,v 1.1 2011/06/06 18:46:00 nirbheek Exp $
+
+EAPI="3"
+GCONF_DEBUG="no"
+PYTHON_DEPEND="2:2.5"
+
+inherit gnome2 python eutils virtualx
+
+DESCRIPTION="A non-linear video editor using the GStreamer multimedia framework"
+HOMEPAGE="http://www.pitivi.org"
+
+LICENSE="LGPL-2.1"
+SLOT="0"
+KEYWORDS="~amd64 ~x86"
+IUSE="v4l"
+
+# gst-plugins-good-0.10.24 needed for prefer-passthrough property
+# gst-plugins-base-0.10.31 needed for add-borders property, and decodebin2
+RDEPEND="
+	>=dev-python/pygtk-2.18:2
+	dev-python/dbus-python
+	>=dev-python/gconf-python-2.12
+	dev-python/pycairo
+	dev-python/pygoocanvas
+	net-zope/zope-interface
+	gnome-base/librsvg
+
+	>=media-libs/gstreamer-0.10.28:0.10
+	>=dev-python/gst-python-0.10.19
+	>=media-libs/gnonlin-0.10.16
+	>=media-libs/gst-plugins-base-0.10.31:0.10
+	>=media-libs/gst-plugins-good-0.10.24:0.10
+	>=media-plugins/gst-plugins-ffmpeg-0.10:0.10
+	>=media-plugins/gst-plugins-xvideo-0.10.31:0.10
+	>=media-plugins/gst-plugins-libpng-0.10.24:0.10
+
+	v4l? ( media-plugins/gst-plugins-v4l2:0.10 )"
+DEPEND="${RDEPEND}
+	dev-python/setuptools
+	>=dev-util/intltool-0.35.5"
+
+pkg_setup() {
+	DOCS="AUTHORS ChangeLog NEWS RELEASE"
+	python_set_active_version 2
+}
+
+src_prepare() {
+	gnome2_src_prepare
+
+	# disable pyc compiling
+	mv py-compile py-compile.orig
+	ln -s $(type -P true) py-compile
+}
+
+src_configure() {
+	addpredict $(unset HOME; echo ~)/.gconf
+	addpredict $(unset HOME; echo ~)/.gconfd
+	addpredict $(unset HOME; echo ~)/.gstreamer-0.10
+
+	gnome2_src_configure
+}
+
+src_test() {
+	export XDG_CONFIG_HOME="${WORKDIR}/.config"
+	export XDG_DATA_HOME="${WORKDIR}/.local"
+	# Force Xvfb to be used
+	unset DISPLAY
+	unset DBUS_SESSION_BUS_ADDRESS
+	export PITIVI_TOP_LEVEL_DIR="${S}"
+	Xemake check || die "tests failed"
+}
+
+src_install() {
+	gnome2_src_install
+	python_convert_shebangs -r 2 "${D}"
+}
+
+pkg_postinst() {
+	gnome2_pkg_postinst
+	python_mod_optimize "/usr/$(get_libdir)/${PN}/python/${PN}"
+}
+
+pkg_postrm() {
+	gnome2_pkg_postrm
+	python_mod_cleanup "/usr/$(get_libdir)/${PN}/python/${PN}"
+}