Fixed misc security vulnerabilities, bug #222121, thank Robert Buchholz for report and Klaus Singvogel for investigation/fixes.

(Portage version: 2.2_rc26/cvs/Linux i686)

2 files changed, 86 insertions, 1 deletions

diff --git a/net-analyzer/sarg/ChangeLog b/net-analyzer/sarg/ChangeLog
index ea96f05c44fe..f7a9c6a77ff4 100644
--- a/net-analyzer/sarg/ChangeLog
+++ b/net-analyzer/sarg/ChangeLog
@@ -1,6 +1,12 @@
 # ChangeLog for net-analyzer/sarg
 # Copyright 2002-2009 Gentoo Foundation; Distributed under the GPL v2
-# $Header: /var/cvsroot/gentoo-x86/net-analyzer/sarg/ChangeLog,v 1.44 2009/03/16 16:30:01 pva Exp $
+# $Header: /var/cvsroot/gentoo-x86/net-analyzer/sarg/ChangeLog,v 1.45 2009/03/23 09:05:26 pva Exp $
+
+*sarg-2.2.5-r1 (23 Mar 2009)
+
+  23 Mar 2009; Peter Volkov <pva@gentoo.org> +sarg-2.2.5-r1.ebuild:
+  Fixed misc security vulnerabilities, bug #222121, thank Robert Buchholz
+  for report and Klaus Singvogel for investigation/fixes.
 
   16 Mar 2009; Peter Volkov <pva@gentoo.org> -sarg-2.2.4.ebuild,
   sarg-2.2.5.ebuild:
diff --git a/net-analyzer/sarg/sarg-2.2.5-r1.ebuild b/net-analyzer/sarg/sarg-2.2.5-r1.ebuild
new file mode 100644
index 000000000000..88c8dc44530b
--- /dev/null
+++ b/net-analyzer/sarg/sarg-2.2.5-r1.ebuild
@@ -0,0 +1,79 @@
+# Copyright 1999-2009 Gentoo Foundation
+# Distributed under the terms of the GNU General Public License v2
+# $Header: /var/cvsroot/gentoo-x86/net-analyzer/sarg/sarg-2.2.5-r1.ebuild,v 1.1 2009/03/23 09:05:26 pva Exp $
+
+EAPI="2"
+
+inherit eutils autotools
+
+DESCRIPTION="Squid Analysis Report Generator"
+HOMEPAGE="http://sarg.sourceforge.net/sarg.php"
+SRC_URI="mirror://sourceforge/${PN}/${P}.tar.gz
+		mirror://gentoo/${P}-patchset-1.tar.bz2"
+
+LICENSE="GPL-2"
+KEYWORDS="~amd64 ~ppc ~x86"
+SLOT="0"
+IUSE=""
+
+DEPEND="media-libs/gd[png,truetype]"
+RDEPEND="${DEPEND}"
+
+src_prepare() {
+	EPATCH_SOURCE="${WORKDIR}/patches/" EPATCH_SUFFIX="patch" epatch
+
+	einfo "Running sed to substitute paths..."
+	sed \
+		-e 's:/usr/local/squid/var/logs/access.log:/var/log/squid/access.log:' \
+		-e 's:/usr/local/\(squidGuard/squidGuard.conf\):/etc/\1:' \
+		-e 's:/var/www/html/squid-reports:/var/www/localhost/htdocs/squid-reports:' \
+		-i sarg.conf || die
+
+	sed \
+		-e 's:"/usr/local/squid/var/logs/access.log":"/var/log/squid/access.log":' \
+		-e 's:"/var/www/html/squid-reports":"/var/www/localhost/htdocs/squid-reports":' \
+		-e 's:"/usr/local/sarg/passwd":"/etc/sarg/passwd":' \
+			-i log.c || die #43132
+
+	sed	-e 's:/usr/local/sarg/passwd:/etc/sarg/passwd:' \
+		-i htaccess || die
+
+	sed -e 's:/usr/local/squid/logs/access.log:/var/log/squid/access.log:' \
+		-i splitlog.c convlog.c || die
+
+	sed -e 's:/usr/local/\(sarg/sarg.conf\):/etc/\1:' \
+		-e 's:/usr/local/squid/etc/passwd:/etc/squid/passwd:' \
+		-i user_limit_block || die
+
+	sed -e 's:/usr/local/squid/etc/block.txt:/etc/squid/etc/block.txt:' \
+		-i sarg-php/sarg-block-it.php || die
+
+	sed -e 's:/usr/local/\(sarg/sarg.conf\):/etc/\1:' \
+		-e 's:/usr/local/\(squidGuard/squidGuard.conf\):/etc/\1:' \
+		-e 's:/usr/local/squid/logs/access.log:/var/log/squid/access.log:' \
+			-i sarg.1 sarg-php/sarg-squidguard-block.php || die
+
+	sed -i -e 's:sarg_tmp:sarg:' email.c || die #64743
+	eautoreconf
+}
+
+src_configure() {
+	econf \
+		--enable-bindir=/usr/bin \
+		--enable-mandir=/usr/share/man/man1 \
+		--enable-sysconfdir=/etc/sarg/
+}
+
+src_install() {
+	# This is workaround for sarg installation script, which does not create dirs
+	dodir /etc/sarg /usr/sbin
+
+	make \
+		BINDIR="${D}"/usr/sbin \
+		MANDIR="${D}"/usr/share/man/man1 \
+		SYSCONFDIR="${D}"/etc/sarg \
+		HTMLDIR="${D}"/var/www/html \
+		install || die "sarg installation failed"
+
+	dodoc BETA-TESTERS CONTRIBUTORS DONATIONS README ChangeLog htaccess
+}