Adjust gtk-sharp dependency, bug #203610. Add intltool dependency, bug #203369. Add automake patch submitted to upstream, bug #202968.

(Portage version: 2.1.3.19)

9 files changed, 276 insertions, 12 deletions

diff --git a/net-dns/avahi/ChangeLog b/net-dns/avahi/ChangeLog
index eea93b5b9964..0c8e19161b8e 100644
--- a/net-dns/avahi/ChangeLog
+++ b/net-dns/avahi/ChangeLog
@@ -1,6 +1,15 @@
 # ChangeLog for net-dns/avahi
 # Copyright 1999-2008 Gentoo Foundation; Distributed under the GPL v2
-# $Header: /var/cvsroot/gentoo-x86/net-dns/avahi/ChangeLog,v 1.133 2008/01/01 19:57:12 swegener Exp $
+# $Header: /var/cvsroot/gentoo-x86/net-dns/avahi/ChangeLog,v 1.134 2008/01/03 17:53:10 swegener Exp $
+
+*avahi-0.6.22-r1 (03 Jan 2008)
+
+  03 Jan 2008; Sven Wegener <swegener@gentoo.org>
+  +files/avahi-0.6.22-gobject.patch, files/avahi-0.6.22-vncviewer.patch,
+  avahi-0.6.19-r2.ebuild, avahi-0.6.20-r2.ebuild, avahi-0.6.21.ebuild,
+  avahi-0.6.22.ebuild, +avahi-0.6.22-r1.ebuild:
+  Adjust gtk-sharp dependency, bug #203610. Add intltool dependency, bug
+  #203369. Add automake patch submitted to upstream, bug #202968.
 
   01 Jan 2008; Sven Wegener <swegener@gentoo.org> avahi-0.6.19-r2.ebuild,
   avahi-0.6.20-r2.ebuild, avahi-0.6.21.ebuild, avahi-0.6.22.ebuild:
diff --git a/net-dns/avahi/avahi-0.6.19-r2.ebuild b/net-dns/avahi/avahi-0.6.19-r2.ebuild
index 85400220abb7..7b4d346a85b0 100644
--- a/net-dns/avahi/avahi-0.6.19-r2.ebuild
+++ b/net-dns/avahi/avahi-0.6.19-r2.ebuild
@@ -1,6 +1,6 @@
 # Copyright 1999-2008 Gentoo Foundation
 # Distributed under the terms of the GNU General Public License v2
-# $Header: /var/cvsroot/gentoo-x86/net-dns/avahi/avahi-0.6.19-r2.ebuild,v 1.6 2008/01/01 19:57:12 swegener Exp $
+# $Header: /var/cvsroot/gentoo-x86/net-dns/avahi/avahi-0.6.19-r2.ebuild,v 1.7 2008/01/03 17:53:10 swegener Exp $
 
 WANT_AUTOMAKE="1.9"
 WANT_AUTOCONF="none"
@@ -40,7 +40,7 @@ RDEPEND=">=dev-libs/libdaemon-0.5
 	)
 	mono? (
 		>=dev-lang/mono-1.1.10
-		gtk? ( dev-dotnet/gtk-sharp )
+		gtk? ( >=dev-dotnet/gtk-sharp-2 )
 	)
 	howl-compat? ( !net-misc/howl )
 	mdnsresponder-compat? ( !net-misc/mDNSResponder )
@@ -55,6 +55,7 @@ RDEPEND=">=dev-libs/libdaemon-0.5
 	kernel_linux? ( sys-libs/libcap )
 	!net-misc/mDNSResponder"
 DEPEND="${RDEPEND}
+	>=dev-util/intltool-0.35
 	>=dev-util/pkgconfig-0.9.0
 	doc? (
 		app-doc/doxygen
diff --git a/net-dns/avahi/avahi-0.6.20-r2.ebuild b/net-dns/avahi/avahi-0.6.20-r2.ebuild
index fe0d3d631a08..3907783857f9 100644
--- a/net-dns/avahi/avahi-0.6.20-r2.ebuild
+++ b/net-dns/avahi/avahi-0.6.20-r2.ebuild
@@ -1,6 +1,6 @@
 # Copyright 2000-2008 Gentoo Foundation
 # Distributed under the terms of the GNU General Public License v2
-# $Header: /var/cvsroot/gentoo-x86/net-dns/avahi/avahi-0.6.20-r2.ebuild,v 1.6 2008/01/01 19:57:12 swegener Exp $
+# $Header: /var/cvsroot/gentoo-x86/net-dns/avahi/avahi-0.6.20-r2.ebuild,v 1.7 2008/01/03 17:53:10 swegener Exp $
 
 WANT_AUTOMAKE="1.9"
 WANT_AUTOCONF="none"
@@ -40,7 +40,7 @@ RDEPEND=">=dev-libs/libdaemon-0.11-r1
 	)
 	mono? (
 		>=dev-lang/mono-1.1.10
-		gtk? ( dev-dotnet/gtk-sharp )
+		gtk? ( >=dev-dotnet/gtk-sharp-2 )
 	)
 	howl-compat? ( !net-misc/howl )
 	mdnsresponder-compat? ( !net-misc/mDNSResponder )
@@ -55,6 +55,7 @@ RDEPEND=">=dev-libs/libdaemon-0.11-r1
 	kernel_linux? ( sys-libs/libcap )
 	!net-misc/mDNSResponder"
 DEPEND="${RDEPEND}
+	>=dev-util/intltool-0.35
 	>=dev-util/pkgconfig-0.9.0
 	doc? (
 		app-doc/doxygen
diff --git a/net-dns/avahi/avahi-0.6.21.ebuild b/net-dns/avahi/avahi-0.6.21.ebuild
index f96f4ae94702..c2e065bda759 100644
--- a/net-dns/avahi/avahi-0.6.21.ebuild
+++ b/net-dns/avahi/avahi-0.6.21.ebuild
@@ -1,6 +1,6 @@
 # Copyright 2000-2008 Gentoo Foundation
 # Distributed under the terms of the GNU General Public License v2
-# $Header: /var/cvsroot/gentoo-x86/net-dns/avahi/avahi-0.6.21.ebuild,v 1.10 2008/01/01 19:57:12 swegener Exp $
+# $Header: /var/cvsroot/gentoo-x86/net-dns/avahi/avahi-0.6.21.ebuild,v 1.11 2008/01/03 17:53:10 swegener Exp $
 
 inherit eutils mono python qt3 qt4 multilib
 
@@ -37,7 +37,7 @@ RDEPEND=">=dev-libs/libdaemon-0.11-r1
 	)
 	mono? (
 		>=dev-lang/mono-1.1.10
-		gtk? ( dev-dotnet/gtk-sharp )
+		gtk? ( >=dev-dotnet/gtk-sharp-2 )
 	)
 	howl-compat? ( !net-misc/howl )
 	mdnsresponder-compat? ( !net-misc/mDNSResponder )
@@ -52,6 +52,7 @@ RDEPEND=">=dev-libs/libdaemon-0.11-r1
 	kernel_linux? ( sys-libs/libcap )
 	!net-misc/mDNSResponder"
 DEPEND="${RDEPEND}
+	>=dev-util/intltool-0.35
 	>=dev-util/pkgconfig-0.9.0
 	doc? (
 		app-doc/doxygen
diff --git a/net-dns/avahi/avahi-0.6.22-r1.ebuild b/net-dns/avahi/avahi-0.6.22-r1.ebuild
new file mode 100644
index 000000000000..03455ffedeab
--- /dev/null
+++ b/net-dns/avahi/avahi-0.6.22-r1.ebuild
@@ -0,0 +1,202 @@
+# Copyright 2000-2008 Gentoo Foundation
+# Distributed under the terms of the GNU General Public License v2
+# $Header: /var/cvsroot/gentoo-x86/net-dns/avahi/avahi-0.6.22-r1.ebuild,v 1.1 2008/01/03 17:53:10 swegener Exp $
+
+WANT_AUTOMAKE="1.9"
+WANT_AUTOCONF="none"
+
+inherit eutils mono python qt3 qt4 multilib autotools
+
+DESCRIPTION="System which facilitates service discovery on a local network"
+HOMEPAGE="http://avahi.org/"
+SRC_URI="http://avahi.org/download/${P}.tar.gz"
+
+LICENSE="LGPL-2.1"
+SLOT="0"
+KEYWORDS="~alpha ~amd64 ~arm ~hppa ~ia64 ~mips ~ppc ~ppc64 ~s390 ~sh ~sparc ~x86"
+IUSE="bookmarks howl-compat mdnsresponder-compat gdbm dbus doc mono gtk python qt3 qt4 autoipd kernel_linux test ipv6"
+
+RDEPEND=">=dev-libs/libdaemon-0.11-r1
+	dev-libs/expat
+	>=dev-libs/glib-2
+	gdbm? ( sys-libs/gdbm )
+	qt3? ( $(qt_min_version 3.3.6-r2) )
+	qt4? ( $(qt4_min_version 4) )
+	gtk? (
+		>=x11-libs/gtk+-2.4.0
+		>=gnome-base/libglade-2.4.0
+	)
+	dbus? (
+		>=sys-apps/dbus-0.30
+		python? (
+			|| (
+				dev-python/dbus-python
+				(
+					<sys-apps/dbus-0.90
+					>=sys-apps/dbus-0.30
+				)
+			)
+		)
+	)
+	mono? (
+		>=dev-lang/mono-1.1.10
+		gtk? ( >=dev-dotnet/gtk-sharp-2 )
+	)
+	howl-compat? ( !net-misc/howl )
+	mdnsresponder-compat? ( !net-misc/mDNSResponder )
+	python? (
+		>=virtual/python-2.4
+		gtk? ( >=dev-python/pygtk-2 )
+	)
+	bookmarks? (
+		dev-python/twisted
+		dev-python/twisted-web
+	)
+	kernel_linux? ( sys-libs/libcap )
+	!net-misc/mDNSResponder"
+DEPEND="${RDEPEND}
+	>=dev-util/intltool-0.35
+	>=dev-util/pkgconfig-0.9.0
+	doc? (
+		app-doc/doxygen
+		mono? ( >=dev-util/monodoc-1.1.8 )
+	)"
+
+pkg_setup() {
+	if use python && ! built_with_use dev-lang/python gdbm
+	then
+		die "For python support you need dev-lang/python compiled with gdbm support!"
+	fi
+
+	if use python && use dbus && ! has_version dev-python/dbus-python && ! built_with_use sys-apps/dbus python
+	then
+		die "For python and dbus support you need sys-apps/dbus compiled with python support or dev-python/dbus-python!"
+	fi
+
+	if ( use mdnsresponder-compat || use howl-compat || use mono ) && ! use dbus
+	then
+		die "For *-compat or mono support you also need to enable the dbus USE flag!"
+	fi
+
+	if use bookmarks && ! ( use python && use dbus && use gtk )
+	then
+		die "For bookmarks support you also need to enable the python, dbus and gtk USE flags!"
+	fi
+}
+
+pkg_preinst() {
+	enewgroup netdev
+	enewgroup avahi
+	enewuser avahi -1 -1 -1 avahi
+
+	if use autoipd
+	then
+		enewgroup avahi-autoipd
+		enewuser avahi-autoipd -1 -1 -1 avahi-autoipd
+	fi
+}
+
+src_unpack() {
+	unpack ${A}
+	cd "${S}"
+
+	epatch "${FILESDIR}"/${P}-vncviewer.patch
+	epatch "${FILESDIR}"/${P}-gobject.patch
+
+	eautomake
+
+	use ipv6 && sed -i -e s/use-ipv6=no/use-ipv6=yes/ avahi-daemon/avahi-daemon.conf
+
+	sed -i -e "s:\\.\\./\\.\\./\\.\\./doc/avahi-docs/html/:../../../doc/${PF}/html/:" doxygen_to_devhelp.xsl
+}
+
+src_compile() {
+	local myconf=""
+
+	if use python
+	then
+		use dbus && myconf="${myconf} --enable-python-dbus"
+		use gtk && myconf="${myconf} --enable-pygtk"
+	fi
+
+	if use mono && use doc
+	then
+		myconf="${myconf} --enable-monodoc"
+	fi
+
+	# We need to unset DISPLAY, else the configure script might have problems detecting the pygtk module
+	unset DISPLAY
+
+	econf \
+		--localstatedir=/var \
+		--with-distro=gentoo \
+		--disable-python-dbus \
+		--disable-pygtk \
+		--disable-xmltoman \
+		--disable-monodoc \
+		--enable-glib \
+		$(use_enable test tests) \
+		$(use_enable autoipd) \
+		$(use_enable mdnsresponder-compat compat-libdns_sd) \
+		$(use_enable howl-compat compat-howl) \
+		$(use_enable doc doxygen-doc) \
+		$(use_enable mono) \
+		$(use_enable dbus) \
+		$(use_enable python) \
+		$(use_enable gtk) \
+		$(use_enable qt3) \
+		$(use_enable qt4) \
+		$(use_enable gdbm) \
+		${myconf} \
+		|| die "econf failed"
+	emake || die "emake failed"
+
+	use doc && emake avahi.devhelp
+}
+
+src_install() {
+	emake install py_compile=true DESTDIR="${D}" || die "make install failed"
+	use bookmarks || rm -f "${D}"/usr/bin/avahi-bookmarks
+
+	use howl-compat && ln -s avahi-compat-howl.pc "${D}"/usr/$(get_libdir)/pkgconfig/howl.pc
+	use mdnsresponder-compat && ln -s avahi-compat-libdns_sd/dns_sd.h "${D}"/usr/include/dns_sd.h
+
+	if use autoipd
+	then
+		insinto /$(get_libdir)/rcscripts/net
+		doins "${FILESDIR}"/autoipd.sh
+	fi
+
+	dodoc docs/{AUTHORS,README,TODO}
+
+	if use doc
+	then
+		dohtml -r doxygen/html/.
+		insinto /usr/share/devhelp/books/avahi
+		doins avahi.devhelp
+	fi
+}
+
+pkg_postrm() {
+	use python && python_mod_cleanup
+}
+
+pkg_postinst() {
+	use python && python_mod_optimize "${ROOT}"/usr/lib*/python*/site-packages/avahi
+
+	if use autoipd
+	then
+		elog
+		elog "To use avahi-autoipd to configure your interfaces with IPv4LL (RFC3927)"
+		elog "addresses, just set config_<interface>=( autoipd ) in /etc/conf.d/net!"
+		elog
+	fi
+
+	if use dbus
+	then
+		elog
+		elog "If this is your first install of avahi please reload your dbus config"
+		elog "with /etc/init.d/dbus reload before starting avahi-daemon!"
+		elog
+	fi
+}
diff --git a/net-dns/avahi/avahi-0.6.22.ebuild b/net-dns/avahi/avahi-0.6.22.ebuild
index fa43080a381a..a6ac75c5e4b3 100644
--- a/net-dns/avahi/avahi-0.6.22.ebuild
+++ b/net-dns/avahi/avahi-0.6.22.ebuild
@@ -1,6 +1,6 @@
 # Copyright 2000-2008 Gentoo Foundation
 # Distributed under the terms of the GNU General Public License v2
-# $Header: /var/cvsroot/gentoo-x86/net-dns/avahi/avahi-0.6.22.ebuild,v 1.2 2008/01/01 19:57:12 swegener Exp $
+# $Header: /var/cvsroot/gentoo-x86/net-dns/avahi/avahi-0.6.22.ebuild,v 1.3 2008/01/03 17:53:10 swegener Exp $
 
 inherit eutils mono python qt3 qt4 multilib
 
@@ -37,7 +37,7 @@ RDEPEND=">=dev-libs/libdaemon-0.11-r1
 	)
 	mono? (
 		>=dev-lang/mono-1.1.10
-		gtk? ( dev-dotnet/gtk-sharp )
+		gtk? ( >=dev-dotnet/gtk-sharp-2 )
 	)
 	howl-compat? ( !net-misc/howl )
 	mdnsresponder-compat? ( !net-misc/mDNSResponder )
@@ -52,6 +52,7 @@ RDEPEND=">=dev-libs/libdaemon-0.11-r1
 	kernel_linux? ( sys-libs/libcap )
 	!net-misc/mDNSResponder"
 DEPEND="${RDEPEND}
+	>=dev-util/intltool-0.35
 	>=dev-util/pkgconfig-0.9.0
 	doc? (
 		app-doc/doxygen
diff --git a/net-dns/avahi/files/avahi-0.6.22-gobject.patch b/net-dns/avahi/files/avahi-0.6.22-gobject.patch
new file mode 100644
index 000000000000..2546ee1c7ddf
--- /dev/null
+++ b/net-dns/avahi/files/avahi-0.6.22-gobject.patch
@@ -0,0 +1,44 @@
+build avahi-gobject only when avahi-client is also built
+
+(modified to only patch the makefiles)
+
+Index: trunk/avahi-gobject/Makefile.am
+===================================================================
+--- trunk/avahi-gobject/Makefile.am	(revision 1669)
++++ trunk/avahi-gobject/Makefile.am	(revision 1670)
+@@ -23,6 +23,7 @@
+ AM_CFLAGS+='-DDEBUG_TRAP=__asm__("int $$3")'
+ 
+ if HAVE_GOBJECT
++if HAVE_DBUS
+ 
+ avahigobjectincludedir=$(includedir)/avahi-gobject
+ 
+@@ -109,6 +110,7 @@
+ 	$< > $@
+ 
+ endif
++endif
+ 
+ indent:
+ 	indent -brf -nbbo -nbc -ip0 -cs -nbfde -npsl -br -brs -bap -i4 -bs -cdw -ce -npcs -hnl -cli4 -nut -ci8 ga-*.[ch]
+Index: trunk/Makefile.am
+===================================================================
+--- trunk/Makefile.am	(revision 1669)
++++ trunk/Makefile.am	(revision 1670)
+@@ -112,6 +112,7 @@
+ 	$(srcdir)/avahi-glib/glib-malloc.h
+ 
+ if HAVE_GOBJECT
++if HAVE_DBUS
+ DX_INPUT += \
+ 	$(srcdir)/avahi-gobject/ga-client.h \
+ 	$(srcdir)/avahi-gobject/ga-entry-group.h \
+@@ -122,6 +123,7 @@
+ 	$(srcdir)/avahi-gobject/ga-service-resolver.h
+ endif
+ endif
++endif
+ 
+ if HAVE_DBUS
+ DX_INPUT += \
diff --git a/net-dns/avahi/files/avahi-0.6.22-vncviewer.patch b/net-dns/avahi/files/avahi-0.6.22-vncviewer.patch
index f20e22f4225c..3a47e79ff7f2 100644
--- a/net-dns/avahi/files/avahi-0.6.22-vncviewer.patch
+++ b/net-dns/avahi/files/avahi-0.6.22-vncviewer.patch
@@ -1,6 +1,8 @@
-diff -Nur avahi-0.6.22.orig/avahi-ui/bssh.c avahi-0.6.22/avahi-ui/bssh.c
---- avahi-0.6.22.orig/avahi-ui/bssh.c	2007-12-17 15:12:57.000000000 +0000
-+++ avahi-0.6.22/avahi-ui/bssh.c	2007-12-17 16:07:54.021586488 +0000
+xvncviewer is an alternative on debian.
+vncviewer is what the vnc distribution and we use.
+
+--- avahi-0.6.22/avahi-ui/bssh.c
++++ avahi-0.6.22/avahi-ui/bssh.c
 @@ -86,8 +86,8 @@
  
              gtk_widget_destroy(d);
diff --git a/net-dns/avahi/files/digest-avahi-0.6.22-r1 b/net-dns/avahi/files/digest-avahi-0.6.22-r1
new file mode 100644
index 000000000000..197f80d3c14b
--- /dev/null
+++ b/net-dns/avahi/files/digest-avahi-0.6.22-r1
@@ -0,0 +1,3 @@
+MD5 c84b1a8a23126e188426728710414dc8 avahi-0.6.22.tar.gz 1199901
+RMD160 fad35f473a9109c8648e43b0f6f547c32b18e32f avahi-0.6.22.tar.gz 1199901
+SHA256 9dc6f870b6ce050059054a26bfc15d6e7a836fa299edd1b89c63c1089bfedd52 avahi-0.6.22.tar.gz 1199901