Add farstream-0.2.2 with gstreamer-1.0 support (bug #436238), parallel-installable with the 0.1 versions.

(Portage version: 2.2.0_alpha144/cvs/Linux x86_64, signed Manifest commit with key CF0ADD61)

3 files changed, 83 insertions, 4 deletions

diff --git a/net-libs/farstream/ChangeLog b/net-libs/farstream/ChangeLog
index 07620014b73f..75cf5ace6f01 100644
--- a/net-libs/farstream/ChangeLog
+++ b/net-libs/farstream/ChangeLog
@@ -1,6 +1,13 @@
 # ChangeLog for net-libs/farstream
 # Copyright 1999-2012 Gentoo Foundation; Distributed under the GPL v2
-# $Header: /var/cvsroot/gentoo-x86/net-libs/farstream/ChangeLog,v 1.14 2012/12/08 00:58:43 tetromino Exp $
+# $Header: /var/cvsroot/gentoo-x86/net-libs/farstream/ChangeLog,v 1.15 2012/12/08 01:23:36 tetromino Exp $
+
+*farstream-0.2.2 (08 Dec 2012)
+
+  08 Dec 2012; Alexandre Rostovtsev <tetromino@gentoo.org>
+  farstream-0.1.2-r1.ebuild, +farstream-0.2.2.ebuild:
+  Add farstream-0.2.2 with gstreamer-1.0 support (bug #436238),
+  parallel-installable with the 0.1 versions.
 
   08 Dec 2012; Alexandre Rostovtsev <tetromino@gentoo.org>
   farstream-0.1.2-r1.ebuild:
diff --git a/net-libs/farstream/farstream-0.1.2-r1.ebuild b/net-libs/farstream/farstream-0.1.2-r1.ebuild
index 2ae1c7046e60..faf3597a05bb 100644
--- a/net-libs/farstream/farstream-0.1.2-r1.ebuild
+++ b/net-libs/farstream/farstream-0.1.2-r1.ebuild
@@ -1,6 +1,6 @@
 # Copyright 1999-2012 Gentoo Foundation
 # Distributed under the terms of the GNU General Public License v2
-# $Header: /var/cvsroot/gentoo-x86/net-libs/farstream/farstream-0.1.2-r1.ebuild,v 1.12 2012/12/08 00:58:43 tetromino Exp $
+# $Header: /var/cvsroot/gentoo-x86/net-libs/farstream/farstream-0.1.2-r1.ebuild,v 1.13 2012/12/08 01:23:36 tetromino Exp $
 
 EAPI="4"
 PYTHON_DEPEND="2"
@@ -15,14 +15,14 @@ LICENSE="LGPL-2.1+"
 KEYWORDS="alpha amd64 arm hppa ia64 ppc ppc64 sparc x86 ~amd64-linux ~x86-linux"
 IUSE="+introspection python msn test upnp"
 
-SLOT="0"
+SLOT="0.1"
 
 # Tests need shmsink from gst-plugins-bad, which isn't packaged
 RESTRICT="test"
 
 COMMONDEPEND=">=media-libs/gstreamer-0.10.33:0.10
 	>=media-libs/gst-plugins-base-0.10.33:0.10
-	>=dev-libs/glib-2.26:2
+	>=dev-libs/glib-2.30:2
 	>=net-libs/libnice-0.1.0
 	introspection? ( >=dev-libs/gobject-introspection-0.10.11 )
 	python? (
@@ -41,6 +41,7 @@ RDEPEND="${COMMONDEPEND}
 # This package is just a rename from farsight2
 
 DEPEND="${COMMONDEPEND}
+	dev-util/gtk-doc-am
 	virtual/pkgconfig
 	test? (
 		media-libs/gst-plugins-good:0.10
diff --git a/net-libs/farstream/farstream-0.2.2.ebuild b/net-libs/farstream/farstream-0.2.2.ebuild
new file mode 100644
index 000000000000..b6671d9e9f64
--- /dev/null
+++ b/net-libs/farstream/farstream-0.2.2.ebuild
@@ -0,0 +1,71 @@
+# Copyright 1999-2012 Gentoo Foundation
+# Distributed under the terms of the GNU General Public License v2
+# $Header: /var/cvsroot/gentoo-x86/net-libs/farstream/farstream-0.2.2.ebuild,v 1.1 2012/12/08 01:23:36 tetromino Exp $
+
+EAPI="5"
+
+# no PYTHON_DEPEND, python is purely a build-time dependency
+inherit eutils python
+
+DESCRIPTION="Audio/video conferencing framework specifically designed for instant messengers"
+HOMEPAGE="http://www.freedesktop.org/wiki/Software/Farstream"
+SRC_URI="http://freedesktop.org/software/farstream/releases/${PN}/${P}.tar.gz"
+
+LICENSE="LGPL-2.1+"
+KEYWORDS="~alpha ~amd64 ~arm ~hppa ~ia64 ~ppc ~ppc64 ~sparc ~x86 ~amd64-linux ~x86-linux"
+IUSE="+introspection msn test upnp"
+
+SLOT="0.2"
+
+# Tests need shmsink from gst-plugins-bad, which isn't packaged
+RESTRICT="test"
+
+COMMONDEPEND="media-libs/gstreamer:1.0
+	media-libs/gst-plugins-base:1.0
+	>=dev-libs/glib-2.32:2
+	>=net-libs/libnice-0.1.3-r1
+	introspection? ( >=dev-libs/gobject-introspection-0.10.11 )
+	upnp? ( >=net-libs/gupnp-igd-0.2:= )"
+
+RDEPEND="${COMMONDEPEND}
+	media-libs/gst-plugins-good:1.0
+	media-libs/gst-plugins-bad:1.0
+	media-plugins/gst-plugins-libnice:1.0
+	msn? ( media-plugins/gst-plugins-mimic:1.0 )"
+
+DEPEND="${COMMONDEPEND}
+	=dev-lang/python-2*
+	dev-util/gtk-doc-am
+	virtual/pkgconfig
+	test? (
+		media-libs/gst-plugins-base:1.0[vorbis]
+		media-libs/gst-plugins-good:1.0 )"
+
+pkg_setup() {
+	python_set_active_version 2
+	python_pkg_setup
+}
+
+src_configure() {
+	plugins="fsrawconference,fsrtpconference,fsfunnel,fsrtcpfilter,fsvideoanyrate"
+	use msn && plugins="${plugins},fsmsnconference"
+	econf --disable-static \
+		$(use_enable introspection) \
+		$(use_enable upnp gupnp) \
+		--with-plugins=${plugins}
+}
+
+src_install() {
+	default
+	prune_libtool_files --modules
+}
+
+src_test() {
+	# FIXME: do an out-of-tree build for tests if USE=-msn
+	if ! use msn; then
+		elog "Tests disabled without msn use flag"
+		return
+	fi
+
+	emake -j1 check
+}