Adding myself to maintainers (mostly for dibbler-client), version bump

(Portage version: 2.2.7/cvs/Linux x86_64, signed Manifest commit with key C74525F2)

1 files changed, 52 insertions, 0 deletions

diff --git a/net-misc/dibbler/dibbler-0.8.4.ebuild b/net-misc/dibbler/dibbler-0.8.4.ebuild
new file mode 100644
index 000000000000..53f4f7613234
--- /dev/null
+++ b/net-misc/dibbler/dibbler-0.8.4.ebuild
@@ -0,0 +1,52 @@
+# Copyright 1999-2013 Gentoo Foundation
+# Distributed under the terms of the GNU General Public License v2
+# $Header: /var/cvsroot/gentoo-x86/net-misc/dibbler/dibbler-0.8.4.ebuild,v 1.1 2013/12/02 14:30:20 voyageur Exp $
+
+EAPI="5"
+inherit eutils readme.gentoo systemd
+
+DESCRIPTION="Portable DHCPv6 implementation (server, client and relay)"
+HOMEPAGE="http://klub.com.pl/dhcpv6/"
+SRC_URI="http://klub.com.pl/dhcpv6/dibbler/${P}.tar.gz"
+
+LICENSE="GPL-2"
+SLOT="0"
+KEYWORDS="~amd64 ~hppa ~mips ~x86"
+IUSE="doc"
+
+DEPEND="doc? ( || (
+		dev-texlive/texlive-latexextra
+		dev-tex/floatflt )
+	)"
+RDEPEND=""
+
+DOC_CONTENTS="Make sure that you modify client.conf, server.conf and/or relay.conf
+to suit your needs. They are stored in /etc/dibbler"
+
+src_prepare() {
+	epatch_user
+}
+
+src_compile() {
+	emake
+	# devel documentation is broken and users should consult the online version
+	# http://klub.com.pl/dhcpv6/doxygen/
+	use doc && emake -C doc/ user
+}
+
+src_install() {
+	readme.gentoo_create_doc
+
+	dosbin dibbler-{client,relay,server}
+	doman doc/man/*.8
+
+	insinto /etc/dibbler
+	doins doc/examples/*.conf
+	dodir /var/lib/dibbler
+
+	dodoc AUTHORS CHANGELOG RELNOTES TODO
+	use doc && dodoc doc/dibbler-user.pdf
+
+	doinitd "${FILESDIR}"/dibbler-{client,relay,server}
+	systemd_dounit "${FILESDIR}"/dibbler-client.service
+}