New snapshot.

(Portage version: 2.2.14/cvs/Linux x86_64, signed Manifest commit with key 0BBEEA1FEA4843A4)

3 files changed, 115 insertions, 5 deletions

diff --git a/net-misc/freerdp/ChangeLog b/net-misc/freerdp/ChangeLog
index edfe80cdef65..0b44762017b9 100644
--- a/net-misc/freerdp/ChangeLog
+++ b/net-misc/freerdp/ChangeLog
@@ -1,6 +1,12 @@
 # ChangeLog for net-misc/freerdp
 # Copyright 1999-2014 Gentoo Foundation; Distributed under the GPL v2
-# $Header: /var/cvsroot/gentoo-x86/net-misc/freerdp/ChangeLog,v 1.77 2014/11/12 08:35:29 jlec Exp $
+# $Header: /var/cvsroot/gentoo-x86/net-misc/freerdp/ChangeLog,v 1.78 2014/11/17 05:12:52 floppym Exp $
+
+*freerdp-1.2.0_beta1_pre20141115 (17 Nov 2014)
+
+  17 Nov 2014; Mike Gilbert <floppym@gentoo.org>
+  +freerdp-1.2.0_beta1_pre20141115.ebuild, freerdp-9999.1.ebuild:
+  New snapshot.
 
   12 Nov 2014; Justin Lecher <jlec@gentoo.org>
   freerdp-1.1.0_beta1_p20130710-r2.ebuild,
diff --git a/net-misc/freerdp/freerdp-1.2.0_beta1_pre20141115.ebuild b/net-misc/freerdp/freerdp-1.2.0_beta1_pre20141115.ebuild
new file mode 100644
index 000000000000..953d3733431b
--- /dev/null
+++ b/net-misc/freerdp/freerdp-1.2.0_beta1_pre20141115.ebuild
@@ -0,0 +1,105 @@
+# Copyright 1999-2014 Gentoo Foundation
+# Distributed under the terms of the GNU General Public License v2
+# $Header: /var/cvsroot/gentoo-x86/net-misc/freerdp/freerdp-1.2.0_beta1_pre20141115.ebuild,v 1.1 2014/11/17 05:12:52 floppym Exp $
+
+EAPI="5"
+
+inherit cmake-utils vcs-snapshot
+
+if [[ ${PV} != 9999* ]]; then
+	COMMIT="7a6c6b7436c2fcb02a38bf89e0b3efcdb43f2ef5"
+	SRC_URI="https://github.com/FreeRDP/FreeRDP/archive/${COMMIT}.tar.gz -> ${P}.tar.gz"
+	KEYWORDS="~amd64 ~ppc ~ppc64 ~x86"
+else
+	inherit git-r3
+	SRC_URI=""
+	EGIT_REPO_URI="git://github.com/FreeRDP/FreeRDP.git
+		https://github.com/FreeRDP/FreeRDP.git"
+fi
+
+DESCRIPTION="Free implementation of the Remote Desktop Protocol"
+HOMEPAGE="http://www.freerdp.com/"
+
+LICENSE="Apache-2.0"
+SLOT="0/1.2"
+IUSE="alsa +client cups debug directfb doc ffmpeg gstreamer jpeg
+	pulseaudio server smartcard sse2 test usb X xinerama xv"
+
+RDEPEND="
+	dev-libs/openssl
+	sys-libs/zlib
+	alsa? ( media-libs/alsa-lib )
+	cups? ( net-print/cups )
+	client? (
+		usb? (
+			virtual/libudev:0=
+			sys-apps/util-linux:0=
+			dev-libs/dbus-glib:0=
+			virtual/libusb:1=
+		)
+		X? (
+			x11-libs/libXcursor
+			x11-libs/libXext
+			x11-libs/libXi
+			x11-libs/libXrender
+			xinerama? ( x11-libs/libXinerama )
+			xv? ( x11-libs/libXv )
+		)
+	)
+	directfb? ( dev-libs/DirectFB )
+	ffmpeg? ( virtual/ffmpeg )
+	gstreamer? (
+		media-libs/gstreamer:1.0
+		media-libs/gst-plugins-base:1.0
+		x11-libs/libXrandr
+	)
+	jpeg? ( virtual/jpeg )
+	pulseaudio? ( media-sound/pulseaudio )
+	server? (
+		X? (
+			x11-libs/libXcursor
+			x11-libs/libXdamage
+			x11-libs/libXext
+			x11-libs/libXfixes
+			xinerama? ( x11-libs/libXinerama )
+		)
+	)
+	smartcard? ( sys-apps/pcsc-lite )
+	X? (
+		x11-libs/libX11
+		x11-libs/libxkbfile
+	)
+"
+DEPEND="${RDEPEND}
+	virtual/pkgconfig
+	client? ( X? ( doc? (
+		app-text/docbook-xml-dtd:4.1.2
+		app-text/xmlto
+	) ) )
+"
+
+DOCS=( README )
+
+src_configure() {
+	local mycmakeargs=(
+		$(cmake-utils_use_with alsa ALSA)
+		$(cmake-utils_use_with client CLIENT)
+		$(cmake-utils_use_with cups CUPS)
+		$(cmake-utils_use_with debug DEBUG_ALL)
+		$(cmake-utils_use_with doc MANPAGES)
+		$(cmake-utils_use_with directfb DIRECTFB)
+		$(cmake-utils_use_with ffmpeg FFMPEG)
+		$(cmake-utils_use_with gstreamer GSTREAMER_1_0)
+		$(cmake-utils_use_with jpeg JPEG)
+		$(cmake-utils_use_with pulseaudio PULSE)
+		$(cmake-utils_use_with server SERVER)
+		$(cmake-utils_use_with smartcard PCSC)
+		$(cmake-utils_use_with sse2 SSE2)
+		$(cmake-utils_use usb CHANNEL_URBDRC)
+		$(cmake-utils_use_with X X11)
+		$(cmake-utils_use_with xinerama XINERAMA)
+		$(cmake-utils_use_with xv XV)
+		$(cmake-utils_use_build test TESTING)
+	)
+	cmake-utils_src_configure
+}
diff --git a/net-misc/freerdp/freerdp-9999.1.ebuild b/net-misc/freerdp/freerdp-9999.1.ebuild
index c614e865cd55..8859318763ae 100644
--- a/net-misc/freerdp/freerdp-9999.1.ebuild
+++ b/net-misc/freerdp/freerdp-9999.1.ebuild
@@ -1,21 +1,20 @@
 # Copyright 1999-2014 Gentoo Foundation
 # Distributed under the terms of the GNU General Public License v2
-# $Header: /var/cvsroot/gentoo-x86/net-misc/freerdp/freerdp-9999.1.ebuild,v 1.19 2014/08/06 00:49:04 floppym Exp $
+# $Header: /var/cvsroot/gentoo-x86/net-misc/freerdp/freerdp-9999.1.ebuild,v 1.20 2014/11/17 05:12:52 floppym Exp $
 
 EAPI="5"
 
 inherit cmake-utils vcs-snapshot
 
 if [[ ${PV} != 9999* ]]; then
-	COMMIT="780d451afad21a22d2af6bd030ee71311856f038"
+	COMMIT="7a6c6b7436c2fcb02a38bf89e0b3efcdb43f2ef5"
 	SRC_URI="https://github.com/FreeRDP/FreeRDP/archive/${COMMIT}.tar.gz -> ${P}.tar.gz"
 	KEYWORDS="~amd64 ~ppc ~ppc64 ~x86"
 else
-	inherit git-2
+	inherit git-r3
 	SRC_URI=""
 	EGIT_REPO_URI="git://github.com/FreeRDP/FreeRDP.git
 		https://github.com/FreeRDP/FreeRDP.git"
-	KEYWORDS=""
 fi
 
 DESCRIPTION="Free implementation of the Remote Desktop Protocol"