Version bump, includes features regarding authentication and security

(Portage version: 2.2.0_alpha196/cvs/Linux x86_64, signed Manifest commit with key C74525F2)

3 files changed, 90 insertions, 1 deletions

diff --git a/net-misc/rdesktop/ChangeLog b/net-misc/rdesktop/ChangeLog
index d71f16863947..f8d82397418d 100644
--- a/net-misc/rdesktop/ChangeLog
+++ b/net-misc/rdesktop/ChangeLog
@@ -1,6 +1,12 @@
 # ChangeLog for net-misc/rdesktop
 # Copyright 1999-2013 Gentoo Foundation; Distributed under the GPL v2
-# $Header: /var/cvsroot/gentoo-x86/net-misc/rdesktop/ChangeLog,v 1.142 2013/02/22 19:05:17 zmedico Exp $
+# $Header: /var/cvsroot/gentoo-x86/net-misc/rdesktop/ChangeLog,v 1.143 2013/08/13 09:02:45 voyageur Exp $
+
+*rdesktop-1.8.0 (13 Aug 2013)
+
+  13 Aug 2013; Bernard Cafarelli <voyageur@gentoo.org> +rdesktop-1.8.0.ebuild,
+  metadata.xml:
+  Version bump, includes features regarding authentication and security
 
   22 Feb 2013; Zac Medico <zmedico@gentoo.org> rdesktop-1.7.1.ebuild:
   Add ~arm-linux keyword.
diff --git a/net-misc/rdesktop/metadata.xml b/net-misc/rdesktop/metadata.xml
index baa0eff86964..7203d86cbcb6 100644
--- a/net-misc/rdesktop/metadata.xml
+++ b/net-misc/rdesktop/metadata.xml
@@ -9,6 +9,7 @@
 An open source client for Windows NT Terminal Server and Windows 2000/2003 Terminal Services, capable of natively speaking Remote Desktop Protocol (RDP) in order to present the user's NT desktop. Unlike Citrix ICA, no server extensions are required.
 </longdescription>
   <use>
+	  <flag name="kerberos">Enable CredSPP support + Kerberos authentication with <pkg>net-libs/libgssglue</pkg></flag>
 	  <flag name="pcsc-lite">Enable smartcard support with <pkg>sys-apps/pcsc-lite</pkg> driver</flag>
   </use>
 </pkgmetadata>
diff --git a/net-misc/rdesktop/rdesktop-1.8.0.ebuild b/net-misc/rdesktop/rdesktop-1.8.0.ebuild
new file mode 100644
index 000000000000..8d7a9e434eb6
--- /dev/null
+++ b/net-misc/rdesktop/rdesktop-1.8.0.ebuild
@@ -0,0 +1,82 @@
+# Copyright 1999-2013 Gentoo Foundation
+# Distributed under the terms of the GNU General Public License v2
+# $Header: /var/cvsroot/gentoo-x86/net-misc/rdesktop/rdesktop-1.8.0.ebuild,v 1.1 2013/08/13 09:02:45 voyageur Exp $
+
+EAPI=5
+
+inherit autotools eutils
+
+MY_PV=${PV/_/-}
+
+DESCRIPTION="A Remote Desktop Protocol Client"
+HOMEPAGE="http://rdesktop.sourceforge.net/"
+SRC_URI="mirror://sourceforge/${PN}/${PN}-${MY_PV}.tar.gz"
+
+LICENSE="GPL-3"
+SLOT="0"
+KEYWORDS="~alpha ~amd64 ~arm ~hppa ~ia64 ~mips ~ppc ~ppc64 ~sparc ~x86 ~x86-fbsd ~x86-interix ~amd64-linux ~arm-linux ~x86-linux ~sparc-solaris ~x64-solaris ~x86-solaris"
+IUSE="alsa ao debug ipv6 kerberos libsamplerate oss pcsc-lite"
+
+S=${WORKDIR}/${PN}-${MY_PV}
+
+RDEPEND=">=dev-libs/openssl-0.9.6b
+	x11-libs/libX11
+	x11-libs/libXext
+	x11-libs/libXau
+	x11-libs/libXdmcp
+	alsa? ( media-libs/alsa-lib )
+	ao? ( >=media-libs/libao-0.8.6 )
+	kerberos? ( net-libs/libgssglue )
+	libsamplerate? ( media-libs/libsamplerate )
+	pcsc-lite? ( >=sys-apps/pcsc-lite-1.6.6 )"
+DEPEND="${RDEPEND}
+	virtual/pkgconfig
+	x11-libs/libXt"
+
+src_prepare() {
+	# Prevent automatic stripping
+	local strip="$(echo '$(STRIP) $(DESTDIR)$(bindir)/rdesktop')"
+	sed -i -e "s:${strip}::" Makefile.in \
+		|| die "sed failed in Makefile.in"
+
+	# Automagic dependency on libsamplerate
+	epatch "${FILESDIR}"/${PN}-1.6.0-sound_configure.patch
+	# bug #280923
+	epatch "${FILESDIR}"/${PN}-1.7.0-libao_crash.patch
+
+	eautoreconf
+}
+
+src_configure() {
+	if use ao; then
+		sound_conf=$(use_with ao sound libao)
+	else if use alsa; then
+			sound_conf=$(use_with alsa sound alsa)
+		else
+			sound_conf=$(use_with oss sound oss)
+		fi
+	fi
+
+	econf \
+		--with-openssl="${EPREFIX}"/usr \
+		$(use_with debug) \
+		$(use_with ipv6) \
+		$(use_with libsamplerate) \
+		$(use_enable kerberos credssp) \
+		$(use_enable pcsc-lite smartcard) \
+		${sound_conf}
+}
+
+src_install() {
+	emake DESTDIR="${D}" install
+	dodoc doc/HACKING doc/TODO doc/keymapping.txt
+
+	# For #180313 - applies to versions >= 1.5.0
+	# Fixes sf.net bug
+	# http://sourceforge.net/tracker/index.php?func=detail&aid=1725634&group_id=24366&atid=381349
+	# check for next version to see if this needs to be removed
+	insinto /usr/share/rdesktop/keymaps
+	newins "${FILESDIR}/rdesktop-keymap-additional" additional
+	newins "${FILESDIR}/rdesktop-keymap-cs" cs
+	newins "${FILESDIR}/rdesktop-keymap-sk" sk
+}