new version, cleaned up ebuild, fixes #125710

(Portage version: 2.1)

3 files changed, 66 insertions, 1 deletions

diff --git a/net-news/liferea/ChangeLog b/net-news/liferea/ChangeLog
index a2185f2c34fd..b4a2c8b6a375 100644
--- a/net-news/liferea/ChangeLog
+++ b/net-news/liferea/ChangeLog
@@ -1,6 +1,12 @@
 # ChangeLog for net-news/liferea
 # Copyright 2000-2006 Gentoo Foundation; Distributed under the GPL v2
-# $Header: /var/cvsroot/gentoo-x86/net-news/liferea/ChangeLog,v 1.37 2006/04/29 14:26:10 weeve Exp $
+# $Header: /var/cvsroot/gentoo-x86/net-news/liferea/ChangeLog,v 1.38 2006/06/15 15:10:12 allanonjl Exp $
+
+*liferea-1.0.15 (15 Jun 2006)
+
+  15 Jun 2006; John N. Laliberte <allanonjl@gentoo.org>
+  +liferea-1.0.15.ebuild:
+  new version, cleaned up ebuild, fixes #125710
 
   29 Apr 2006; Jason Wever <weeve@gentoo.org> liferea-0.9.6.ebuild:
   Stable on SPARC.
diff --git a/net-news/liferea/files/digest-liferea-1.0.15 b/net-news/liferea/files/digest-liferea-1.0.15
new file mode 100644
index 000000000000..9d3783ccd4b0
--- /dev/null
+++ b/net-news/liferea/files/digest-liferea-1.0.15
@@ -0,0 +1,3 @@
+MD5 c41074d8617081f5316e4edbf88aca49 liferea-1.0.15.tar.gz 1575426
+RMD160 76379640c03aeabb7832a207f415c099fce8aea5 liferea-1.0.15.tar.gz 1575426
+SHA256 6f328f554f7697d63e22edfdf582b739b3e5e176248f1d2b01a655673076f5d9 liferea-1.0.15.tar.gz 1575426
diff --git a/net-news/liferea/liferea-1.0.15.ebuild b/net-news/liferea/liferea-1.0.15.ebuild
new file mode 100644
index 000000000000..75d6b4089d55
--- /dev/null
+++ b/net-news/liferea/liferea-1.0.15.ebuild
@@ -0,0 +1,56 @@
+# Copyright 1999-2006 Gentoo Foundation
+# Distributed under the terms of the GNU General Public License v2
+# $Header: /var/cvsroot/gentoo-x86/net-news/liferea/liferea-1.0.15.ebuild,v 1.1 2006/06/15 15:10:12 allanonjl Exp $
+
+inherit gnome2
+
+DESCRIPTION="News Aggregator for RDF/RSS/CDF/Atom/Echo/etc feeds"
+HOMEPAGE="http://liferea.sourceforge.net/"
+SRC_URI="mirror://sourceforge/${PN}/${P}.tar.gz"
+LICENSE="GPL-2"
+
+SLOT="0"
+KEYWORDS="~amd64 ~ppc ~ppc64 ~sparc ~x86"
+IUSE="dbus firefox gtkhtml mozilla"
+
+RDEPEND=">=x11-libs/gtk+-2.4.0
+	>=dev-libs/libxml2-2.5.10
+	firefox? ( www-client/mozilla-firefox )
+	!firefox? ( mozilla? ( www-client/mozilla ) )
+	gtkhtml? ( =gnome-extra/gtkhtml-2* )
+	!mozilla? ( !firefox? ( =gnome-extra/gtkhtml-2* ) )
+	>=gnome-base/gconf-2
+	dbus? ( >=sys-apps/dbus-0.30 )"
+
+DEPEND="${RDEPEND}
+	dev-util/pkgconfig"
+
+DOCS="AUTHORS ChangeLog NEWS README"
+
+pkg_setup() {
+
+	# if you don't choose a gecko to use, we will automatically
+	# use gtkhtml2 as the backend.
+	if ! use mozilla && ! use firefox || use gtkhtml ; then
+		G2CONF="${G2CONF} --enable-gtkhtml2"
+	else
+		G2CONF="${G2CONF} --disable-gtkhtml2"
+	fi
+
+	# we prefer firefox over mozilla
+	if use firefox ; then
+		G2CONF="${G2CONF} --enable-gecko=firefox"
+	elif use mozilla ; then
+		G2CONF="${G2CONF} --enable-gecko=mozilla"
+	else
+		G2CONF="${G2CONF} --disable-gecko"
+	fi
+
+	G2CONF="${G2CONF} $(use_enable dbus)"
+}
+
+src_install() {
+	gnome2_src_install
+	rm -f ${D}/usr/bin/${PN}
+	mv ${D}/usr/bin/${PN}-bin ${D}/usr/bin/${PN}
+}