Version Bump, fixes for python ABI compatibiliy

(Portage version: 2.2_rc67/cvs/Linux x86_64)

4 files changed, 239 insertions, 18 deletions

diff --git a/sci-libs/plplot/ChangeLog b/sci-libs/plplot/ChangeLog
index c83a7088bd60..3879068d1294 100644
--- a/sci-libs/plplot/ChangeLog
+++ b/sci-libs/plplot/ChangeLog
@@ -1,6 +1,12 @@
 # ChangeLog for sci-libs/plplot
 # Copyright 1999-2010 Gentoo Foundation; Distributed under the GPL v2
-# $Header: /var/cvsroot/gentoo-x86/sci-libs/plplot/ChangeLog,v 1.28 2010/01/29 18:11:49 bicatali Exp $
+# $Header: /var/cvsroot/gentoo-x86/sci-libs/plplot/ChangeLog,v 1.29 2010/07/04 18:27:02 jlec Exp $
+
+*plplot-5.9.6 (04 Jul 2010)
+
+  04 Jul 2010; Justin Lecher <jlec@gentoo.org> plplot-5.9.5.ebuild,
+  +plplot-5.9.6.ebuild, +files/plplot-5.9.6-python.patch:
+  Version Bump, fixes for python ABI compatibiliy
 
   29 Jan 2010; Sébastien Fabbro <bicatali@gentoo.org> plplot-5.9.5.ebuild:
   Fixed qt4 automagic dependencies, thanks Kacper Kowalik closing bug
diff --git a/sci-libs/plplot/files/plplot-5.9.6-python.patch b/sci-libs/plplot/files/plplot-5.9.6-python.patch
new file mode 100644
index 000000000000..d62ece2ec416
--- /dev/null
+++ b/sci-libs/plplot/files/plplot-5.9.6-python.patch
@@ -0,0 +1,13 @@
+diff --git a/examples/python/CMakeLists.txt b/examples/python/CMakeLists.txt
+index 7599164..8457490 100644
+--- a/examples/python/CMakeLists.txt
++++ b/examples/python/CMakeLists.txt
+@@ -214,7 +214,7 @@ if(CORE_BUILD)
+     @ONLY
+     )
+ 
+-  set(python_location1 ${PYTHON_INSTDIR})
++  set(python_location1)
+   set(python_location2)
+   set(python_location3)
+   set(python_location4)
diff --git a/sci-libs/plplot/plplot-5.9.5.ebuild b/sci-libs/plplot/plplot-5.9.5.ebuild
index e887bc8a1011..2703ecc70e1b 100644
--- a/sci-libs/plplot/plplot-5.9.5.ebuild
+++ b/sci-libs/plplot/plplot-5.9.5.ebuild
@@ -1,10 +1,13 @@
 # Copyright 1999-2010 Gentoo Foundation
 # Distributed under the terms of the GNU General Public License v2
-# $Header: /var/cvsroot/gentoo-x86/sci-libs/plplot/plplot-5.9.5.ebuild,v 1.5 2010/02/01 17:41:34 ssuominen Exp $
+# $Header: /var/cvsroot/gentoo-x86/sci-libs/plplot/plplot-5.9.5.ebuild,v 1.6 2010/07/04 18:27:02 jlec Exp $
 
 EAPI="2"
+
 WX_GTK_VER="2.8"
-inherit eutils cmake-utils toolchain-funcs wxwidgets java-pkg-opt-2
+PYTHON_DEPEND="python? 2"
+
+inherit eutils cmake-utils python toolchain-funcs wxwidgets java-pkg-opt-2
 
 DESCRIPTION="Multi-language scientific plotting library"
 HOMEPAGE="http://plplot.sourceforge.net/"
@@ -17,40 +20,44 @@ KEYWORDS="~amd64 ~x86"
 IUSE="ada cairo doc examples fortran gd gnome java jpeg latex octave
 	 pdf perl png python qhull qt4 svg svga tcl threads tk truetype wxwidgets X"
 
-RDEPEND="ada? ( virtual/gnat )
+RDEPEND="
+	ada? ( virtual/gnat )
 	cairo? ( x11-libs/cairo[svg?,X?] )
 	java? ( >=virtual/jre-1.5 )
 	gd? ( media-libs/gd[jpeg?,png?] )
-	gnome? ( gnome-base/libgnomeui
-			 gnome-base/libgnomeprintui
-			 python? ( dev-python/gnome-python ) )
+	gnome? (
+			gnome-base/libgnomeui
+			gnome-base/libgnomeprintui
+			python? ( dev-python/gnome-python ) )
 	latex? ( virtual/latex-base app-text/ghostscript-gpl )
 	octave? ( >=sci-mathematics/octave-3 )
 	pdf? ( media-libs/libharu )
 	perl? ( dev-perl/PDL dev-perl/XML-DOM )
 	python? ( dev-python/numpy )
-	qt4? ( x11-libs/qt-gui:4
+	qt4? (
+		x11-libs/qt-gui:4
 		x11-libs/qt-svg:4 )
 	svga? ( media-libs/svgalib )
 	tcl? ( dev-lang/tcl dev-tcltk/itcl )
 	tk? ( dev-lang/tk dev-tcltk/itk )
-	truetype? ( media-fonts/freefont-ttf
+	truetype? (
+				media-fonts/freefont-ttf
 				media-libs/lasi
 				gd? ( media-libs/gd[truetype] ) )
 	wxwidgets? ( x11-libs/wxGTK:2.8[X] x11-libs/agg[truetype?] )
 	X? ( x11-libs/libX11 x11-libs/libXau x11-libs/libXdmcp )"
-
 DEPEND="${RDEPEND}
 	>=dev-util/cmake-2.6
 	dev-util/pkgconfig
-	doc? ( app-text/opensp
-		   app-text/jadetex
-		   app-text/docbook2X
-		   app-text/docbook-dsssl-stylesheets
-		   dev-perl/XML-DOM
-		   virtual/latex-base
-		   app-text/ghostscript-gpl
-		   sys-apps/texinfo )
+	doc? (
+			app-text/opensp
+			app-text/jadetex
+			app-text/docbook2X
+			app-text/docbook-dsssl-stylesheets
+			dev-perl/XML-DOM
+			virtual/latex-base
+			app-text/ghostscript-gpl
+			sys-apps/texinfo )
 	java? ( >=virtual/jdk-1.5 dev-lang/swig )
 	python? ( dev-lang/swig )
 	qhull? ( media-libs/qhull )"
@@ -61,6 +68,9 @@ pkg_setup() {
 	else
 		export FC="" F77=""
 	fi
+	use wxwidgets && wxwidgets_pkg_setup
+	use python && python_set_active_version 2
+	use java && java-pkg-opt-2_pkg_setup
 }
 
 src_prepare() {
@@ -91,6 +101,8 @@ src_prepare() {
 	sed -i \
 		-e 's:xml/declaration:sgml:' \
 		cmake/modules/docbook.cmake || die
+
+	use java && java-utils-2_src_prepare
 }
 
 src_configure() {
diff --git a/sci-libs/plplot/plplot-5.9.6.ebuild b/sci-libs/plplot/plplot-5.9.6.ebuild
new file mode 100644
index 000000000000..0516fae57cfc
--- /dev/null
+++ b/sci-libs/plplot/plplot-5.9.6.ebuild
@@ -0,0 +1,190 @@
+# Copyright 1999-2010 Gentoo Foundation
+# Distributed under the terms of the GNU General Public License v2
+# $Header: /var/cvsroot/gentoo-x86/sci-libs/plplot/plplot-5.9.6.ebuild,v 1.1 2010/07/04 18:27:02 jlec Exp $
+
+EAPI="2"
+
+WX_GTK_VER="2.8"
+PYTHON_DEPEND="python? 2"
+
+inherit eutils cmake-utils python toolchain-funcs wxwidgets java-pkg-opt-2
+
+DESCRIPTION="Multi-language scientific plotting library"
+HOMEPAGE="http://plplot.sourceforge.net/"
+SRC_URI="mirror://sourceforge/${PN}/${P}.tar.gz"
+
+LICENSE="LGPL-2"
+SLOT="0"
+KEYWORDS="~amd64 ~x86"
+IUSE="ada cairo doc examples fortran gd gnome java jpeg latex octave
+	 pdf perl png python qhull qt4 svg svga tcl threads tk truetype wxwidgets X"
+
+RDEPEND="
+	ada? ( virtual/gnat )
+	cairo? ( x11-libs/cairo[svg?,X?] )
+	java? ( >=virtual/jre-1.5 )
+	gd? ( media-libs/gd[jpeg?,png?] )
+	gnome? (
+			gnome-base/libgnomeui
+			gnome-base/libgnomeprintui
+			python? ( dev-python/gnome-python ) )
+	latex? ( virtual/latex-base app-text/ghostscript-gpl )
+	octave? ( >=sci-mathematics/octave-3 )
+	pdf? ( media-libs/libharu )
+	perl? ( dev-perl/PDL dev-perl/XML-DOM )
+	python? ( dev-python/numpy )
+	qt4? (
+		x11-libs/qt-gui:4
+		x11-libs/qt-svg:4 )
+	svga? ( media-libs/svgalib )
+	tcl? ( dev-lang/tcl dev-tcltk/itcl )
+	tk? ( dev-lang/tk dev-tcltk/itk )
+	truetype? (
+				media-fonts/freefont-ttf
+				media-libs/lasi
+				gd? ( media-libs/gd[truetype] ) )
+	wxwidgets? ( x11-libs/wxGTK:2.8[X] x11-libs/agg[truetype?] )
+	X? ( x11-libs/libX11 x11-libs/libXau x11-libs/libXdmcp )"
+DEPEND="${RDEPEND}
+	>=dev-util/cmake-2.6
+	dev-util/pkgconfig
+	doc? (
+			app-text/opensp
+			app-text/jadetex
+			app-text/docbook2X
+			app-text/docbook-dsssl-stylesheets
+			dev-perl/XML-DOM
+			virtual/latex-base
+			app-text/ghostscript-gpl
+			sys-apps/texinfo )
+	java? ( >=virtual/jdk-1.5 dev-lang/swig )
+	python? ( dev-lang/swig )
+	qhull? ( media-libs/qhull )"
+
+pkg_setup() {
+	if use fortran; then
+		export FC=$(tc-getFC) F77=$(tc-getF77)
+	else
+		export FC="" F77=""
+	fi
+	use wxwidgets && wxwidgets_pkg_setup
+	use python && python_set_active_version 2
+	use java && java-pkg-opt-2_pkg_setup
+}
+
+src_prepare() {
+	# path for python independent of python version
+	epatch "${FILESDIR}"/${P}-python.patch
+
+	# remove license
+	sed -i -e '/COPYING.LIB/d' CMakeLists.txt || die
+
+	# change default install directories for doc and examples
+	sed -i \
+		-e 's:${DATA_DIR}/examples:${DOC_DIR}/examples:g' \
+		examples/CMakeLists.txt examples/*/CMakeLists.txt || die
+	sed -i \
+		-e 's:${VERSION}::g' \
+		-e "s:doc/\${PACKAGE}:doc/${PF}:" \
+		cmake/modules/instdirs.cmake || die
+
+	# haru pdf devide does not build with HPDF_SHARED
+	sed -i \
+		-e 's:-DHPDF_SHARED::' \
+		cmake/modules/pdf.cmake || die
+
+	# default location for docbook crap
+	sed -i \
+		-e 's:xml/declaration:sgml:' \
+		cmake/modules/docbook.cmake || die
+
+	# Problem if old version is installed
+	sed "/TEST_DYNDRIVERS/s:ON:OFF:g" -i drivers/CMakeLists.txt
+
+	use java && java-utils-2_src_prepare
+}
+
+src_configure() {
+	# see http://www.miscdebris.net/plplot_wiki/index.php?title=CMake_options_for_PLplot
+	cmake-utils_pld() { _use_me_now PLD "$@" ; }
+
+	mycmakeargs="
+		-DUSE_RPATH=OFF
+		-DDEFAULT_ALL_DEVICES=ON
+		-DCMAKE_INSTALL_LIBDIR=/usr/$(get_libdir)
+		$(cmake-utils_use_has python numpy)
+		$(cmake-utils_use_has qhull QHULL)
+		$(cmake-utils_use_has threads PTHREAD)
+		$(cmake-utils_use_with truetype FREETYPE)
+		$(cmake-utils_use_enable ada ada)
+		$(cmake-utils_use_enable fortran f77)
+		$(cmake-utils_use_enable java java)
+		$(cmake-utils_use_enable gnome gnome2)
+		$(cmake-utils_use_enable octave octave)
+		$(cmake-utils_use_enable perl pdl)
+		$(cmake-utils_use_enable python python)
+		$(cmake-utils_use_enable qt4 qt)
+		$(cmake-utils_use_enable tcl tcl)
+		$(cmake-utils_use_enable tcl itcl)
+		$(cmake-utils_use_enable tk tk)
+		$(cmake-utils_use_enable tk itk)
+		$(cmake-utils_pld qt4 _svgqt)
+		$(cmake-utils_pld wxwidgets _wxwidgets)
+		$(cmake-utils_pld wxwidgets _wxpng)
+		$(cmake-utils_pld pdf pdf)
+		$(cmake-utils_pld truetype psttf)
+		$(cmake-utils_pld latex pstex)
+		$(cmake-utils_pld svga linuxvga)"
+
+	use fortran && [[ $(tc-getFC) != g77 ]] && \
+		mycmakeargs="${mycmakeargs} $(cmake-utils_use_enable fortran f95)"
+
+	use truetype && mycmakeargs="${mycmakeargs}
+		-DPL_FREETYPE_FONT_PATH:PATH=/usr/share/fonts/freefont-ttf"
+
+	if use python && use gnome; then
+		mycmakeargs="${mycmakeargs}	-DENABLE_pygcw=ON"
+	else
+		mycmakeargs="${mycmakeargs}	-DENABLE_pygcw=OFF"
+	fi
+	if use cairo; then
+		# memcairo buggy, see cmake/modules/drivers-init.cmake
+		mycmakeargs="${mycmakeargs}
+			-DPLD_memcairo=OFF
+			-DPLD_extcairo=OFF
+			-DPLD_pdfcairo=ON
+			-DPLD_pngcairo=ON
+			-DPLD_pscairo=ON
+			$(cmake-utils_pld svg svgcairo)
+			$(cmake-utils_pld X xcairo)"
+	else
+		mycmakeargs="${mycmakeargs}
+			-DPLD_memcairo=OFF
+			-DPLD_extcairo=OFF
+			-DPLD_pdfcairo=OFF
+			-DPLD_pngcairo=OFF
+			-DPLD_pscairo=OFF
+			-DPLD_svgcairo=OFF
+			-DPLD_xcairo=OFF"
+	fi
+	cmake-utils_src_configure
+}
+
+src_compile() {
+	# separate doc and normal because doc building crashes with parallel
+	cmake-utils_src_make
+	if use doc; then
+		mycmakeargs="${mycmakeargs}	-DBUILD_DOC=ON"
+		mycmakeargs="${mycmakeargs}	-DHAVE_DB_DTD=ON"
+		mycmakeargs="${mycmakeargs}	-DHAVE_DSSSL_DTD=ON"
+		mycmakeargs="${mycmakeargs}	-DHAVE_HTML_SS=ON"
+		mycmakeargs="${mycmakeargs}	-DHAVE_PRINT_SS=ON"
+		cmake-utils_src_configure
+		VARTEXFONTS="${T}/fonts" cmake-utils_src_make -j1
+	fi
+}
+
+src_install() {
+	cmake-utils_src_install
+	use examples || rm -rf "${D}"usr/share/doc/${PF}/examples
+}