Version Bump

(Portage version: 2.2.20/cvs/Linux x86_64, signed Manifest commit with key E9402A79B03529A2!)

2 files changed, 114 insertions, 1 deletions

diff --git a/sci-libs/scikits_learn/ChangeLog b/sci-libs/scikits_learn/ChangeLog
index 2c2c457980a7..55e73f70fb54 100644
--- a/sci-libs/scikits_learn/ChangeLog
+++ b/sci-libs/scikits_learn/ChangeLog
@@ -1,6 +1,11 @@
 # ChangeLog for sci-libs/scikits_learn
 # Copyright 1999-2015 Gentoo Foundation; Distributed under the GPL v2
-# $Header: /var/cvsroot/gentoo-x86/sci-libs/scikits_learn/ChangeLog,v 1.29 2015/04/08 18:49:15 mgorny Exp $
+# $Header: /var/cvsroot/gentoo-x86/sci-libs/scikits_learn/ChangeLog,v 1.30 2015/05/22 14:42:42 jlec Exp $
+
+*scikits_learn-0.16.1 (22 May 2015)
+
+  22 May 2015; Justin Lecher <jlec@gentoo.org> +scikits_learn-0.16.1.ebuild:
+  Version Bump
 
   08 Apr 2015; Michał Górny <mgorny@gentoo.org> scikits_learn-0.13.1.ebuild,
   scikits_learn-0.14.1.ebuild:
diff --git a/sci-libs/scikits_learn/scikits_learn-0.16.1.ebuild b/sci-libs/scikits_learn/scikits_learn-0.16.1.ebuild
new file mode 100644
index 000000000000..ae56becc4eb2
--- /dev/null
+++ b/sci-libs/scikits_learn/scikits_learn-0.16.1.ebuild
@@ -0,0 +1,108 @@
+# Copyright 1999-2015 Gentoo Foundation
+# Distributed under the terms of the GNU General Public License v2
+# $Header: /var/cvsroot/gentoo-x86/sci-libs/scikits_learn/scikits_learn-0.16.1.ebuild,v 1.1 2015/05/22 14:42:42 jlec Exp $
+
+EAPI=5
+
+PYTHON_COMPAT=( python2_7 python3_{3,4} )
+
+inherit distutils-r1 eutils multilib flag-o-matic
+
+MYPN="${PN/scikits_/scikit-}"
+MYP="${MYPN}-${PV}"
+
+DESCRIPTION="Python modules for machine learning and data mining"
+HOMEPAGE="http://scikit-learn.org"
+SRC_URI="mirror://pypi/${MYPN:0:1}/${MYPN}/${MYP}.tar.gz"
+
+LICENSE="BSD"
+SLOT="0"
+KEYWORDS="~amd64 ~x86 ~amd64-linux ~x86-linux"
+IUSE="doc examples test"
+
+RDEPEND="
+	dev-python/joblib[${PYTHON_USEDEP}]
+	dev-python/matplotlib[${PYTHON_USEDEP}]
+	dev-python/nose[${PYTHON_USEDEP}]
+	dev-python/numpy[lapack,${PYTHON_USEDEP}]
+	sci-libs/scikits[${PYTHON_USEDEP}]
+	sci-libs/scipy[${PYTHON_USEDEP}]"
+DEPEND="
+	dev-python/cython[${PYTHON_USEDEP}]
+	dev-python/numpy[lapack,${PYTHON_USEDEP}]
+	dev-python/setuptools[${PYTHON_USEDEP}]
+	sci-libs/scipy[${PYTHON_USEDEP}]
+	doc? (
+		dev-python/joblib[${PYTHON_USEDEP}]
+		dev-python/matplotlib[${PYTHON_USEDEP}]
+		dev-python/sphinx[${PYTHON_USEDEP}]
+		)"
+
+S="${WORKDIR}/${MYP}"
+
+python_prepare_all() {
+	# bug #397605
+	[[ ${CHOST} == *-darwin* ]] \
+		&& append-ldflags -bundle "-undefined dynamic_lookup" \
+		|| append-ldflags -shared
+
+	# scikits-learn now uses the horrible numpy.distutils automagic
+	export SCIPY_FCONFIG="config_fc --noopt --noarch"
+
+	# use system joblib
+	rm -r sklearn/externals/joblib/* || die
+	echo "from joblib import *" > sklearn/externals/joblib/__init__.py
+	sed -i -e '/joblib\/test/d' sklearn/externals/setup.py || die
+	sed -i -e 's/..externals.joblib/joblib/g' \
+		sklearn/decomposition/tests/test_sparse_pca.py \
+		sklearn/metrics/pairwise.py || die
+
+	# use gentoo cblas infrastructure
+	epatch "${FILESDIR}"/${PN}-0.14.1-system-cblas.patch
+
+	distutils-r1_python_prepare_all
+}
+
+python_compile() {
+	distutils-r1_python_compile ${SCIPY_FCONFIG}
+}
+
+python_compile_all() {
+	if use doc; then
+		cd "${S}/doc"
+		local d="${BUILD_DIR}"/lib
+		ln -s "${S}"/sklearn/datasets/{data,descr,images} \
+			"${d}"/sklearn/datasets
+		VARTEXFONTS="${T}"/fonts \
+			MPLCONFIGDIR="${BUILD_DIR}" \
+			PYTHONPATH="${d}" \
+			emake html
+		rm -r "${d}"/sklearn/datasets/{data,desr,images}
+	fi
+}
+
+python_test() {
+	# doc builds and runs tests
+	use doc && return
+	distutils_install_for_testing ${SCIPY_FCONFIG}
+	esetup.py \
+		install --root="${T}/test-${EPYTHON}" \
+		--no-compile ${SCIPY_FCONFIG}
+	pushd "${T}/test-${EPYTHON}/$(python_get_sitedir)" || die > /dev/null
+	nosetests -v sklearn --exe || die
+	popd > /dev/null
+}
+
+python_install() {
+	distutils-r1_python_install ${SCIPY_FCONFIG}
+}
+
+python_install_all() {
+	find "${S}" -name \*LICENSE.txt -delete
+	use doc && HTML_DOCS=( doc/_build/html/. )
+	distutils-r1_python_install_all
+	if use examples; then
+		insinto /usr/share/doc/${PF}
+		doins -r examples
+	fi
+}