Version bump.

(Portage version: 2.2.18/cvs/Linux x86_64, signed Manifest commit with key 0BBEEA1FEA4843A4)

3 files changed, 87 insertions, 2 deletions

diff --git a/sys-fs/btrfs-progs/ChangeLog b/sys-fs/btrfs-progs/ChangeLog
index 9750f58f2f5f..28c45ad3626e 100644
--- a/sys-fs/btrfs-progs/ChangeLog
+++ b/sys-fs/btrfs-progs/ChangeLog
@@ -1,6 +1,12 @@
 # ChangeLog for sys-fs/btrfs-progs
 # Copyright 1999-2015 Gentoo Foundation; Distributed under the GPL v2
-# $Header: /var/cvsroot/gentoo-x86/sys-fs/btrfs-progs/ChangeLog,v 1.104 2015/05/09 23:08:18 floppym Exp $
+# $Header: /var/cvsroot/gentoo-x86/sys-fs/btrfs-progs/ChangeLog,v 1.105 2015/05/09 23:23:01 floppym Exp $
+
+*btrfs-progs-4.0 (09 May 2015)
+
+  09 May 2015; Mike Gilbert <floppym@gentoo.org> +btrfs-progs-4.0.ebuild,
+  metadata.xml:
+  Version bump.
 
   09 May 2015; Mike Gilbert <floppym@gentoo.org> -btrfs-progs-0.19-r3.ebuild,
   -btrfs-progs-0.19.11.ebuild, -btrfs-progs-0.20_rc1.ebuild,
diff --git a/sys-fs/btrfs-progs/btrfs-progs-4.0.ebuild b/sys-fs/btrfs-progs/btrfs-progs-4.0.ebuild
new file mode 100644
index 000000000000..51c8e21cd355
--- /dev/null
+++ b/sys-fs/btrfs-progs/btrfs-progs-4.0.ebuild
@@ -0,0 +1,80 @@
+# Copyright 1999-2015 Gentoo Foundation
+# Distributed under the terms of the GNU General Public License v2
+# $Header: /var/cvsroot/gentoo-x86/sys-fs/btrfs-progs/btrfs-progs-4.0.ebuild,v 1.1 2015/05/09 23:23:01 floppym Exp $
+
+EAPI=5
+
+inherit bash-completion-r1 eutils multilib toolchain-funcs
+
+libbtrfs_soname=0
+
+if [[ ${PV} != 9999 ]]; then
+	MY_PV=v${PV}
+	KEYWORDS="~alpha ~amd64 ~arm ~arm64 ~ia64 ~mips ~ppc ~ppc64 ~sparc ~x86"
+	SRC_URI="https://www.kernel.org/pub/linux/kernel/people/kdave/${PN}/${PN}-${MY_PV}.tar.xz"
+	S="${WORKDIR}"/${PN}-${MY_PV}
+else
+	WANT_LIBTOOL=none
+	inherit autotools git-r3
+	EGIT_REPO_URI="git://git.kernel.org/pub/scm/linux/kernel/git/kdave/btrfs-progs.git
+		https://git.kernel.org/pub/scm/linux/kernel/git/kdave/btrfs-progs.git"
+fi
+
+DESCRIPTION="Btrfs filesystem utilities"
+HOMEPAGE="https://btrfs.wiki.kernel.org"
+
+LICENSE="GPL-2"
+SLOT="0/${libbtrfs_soname}"
+IUSE="+convert"
+
+RESTRICT=test # tries to mount repared filesystems
+
+RDEPEND="
+	dev-libs/lzo:2=
+	sys-libs/zlib:0=
+	convert? (
+		sys-fs/e2fsprogs:0=
+		sys-libs/e2fsprogs-libs:0=
+	)
+"
+DEPEND="${RDEPEND}
+	convert? ( sys-apps/acl )
+	app-text/asciidoc
+	app-text/docbook-xml-dtd:4.5
+	app-text/xmlto
+"
+
+if [[ ${PV} == 9999 ]]; then
+	DEPEND+=" sys-devel/gnuconfig"
+fi
+
+src_prepare() {
+	epatch_user
+	if [[ ${PV} == 9999 ]]; then
+		eautoreconf
+		mkdir config || die
+		local automakedir="$(autotools_run_tool --at-output automake --print-libdir)"
+		[[ -e ${automakedir} ]] || die "Could not locate automake directory"
+		ln -s "${automakedir}"/install-sh config/install-sh || die
+		ln -s "${EPREFIX}"/usr/share/gnuconfig/config.guess config/config.guess || die
+		ln -s "${EPREFIX}"/usr/share/gnuconfig/config.sub config/config.sub || die
+	fi
+}
+
+src_configure() {
+	local myeconfargs=(
+		--bindir="${EPREFIX}"/sbin
+		$(use_enable convert)
+		$(use_enable elibc_glibc backtrace)
+	)
+	econf "${myeconfargs[@]}"
+}
+
+src_compile() {
+	emake V=1
+}
+
+src_install() {
+	default
+	newbashcomp btrfs-completion btrfs
+}
diff --git a/sys-fs/btrfs-progs/metadata.xml b/sys-fs/btrfs-progs/metadata.xml
index cb356ab9aa4e..99f2c6f7db29 100644
--- a/sys-fs/btrfs-progs/metadata.xml
+++ b/sys-fs/btrfs-progs/metadata.xml
@@ -11,6 +11,5 @@
   </maintainer>
   <use>
     <flag name='convert'>Build ext2 conversion utility (btrfs-convert)</flag>
-    <flag name='debug-utils'>Build additional utils for debugging</flag>
   </use>
 </pkgmetadata>