Version bump by bircoph and k_f (bug 494638).

(Portage version: 2.2.20/cvs/Linux x86_64, signed Manifest commit with key 62EEF090)

2 files changed, 64 insertions, 1 deletions

diff --git a/sys-power/suspend/ChangeLog b/sys-power/suspend/ChangeLog
index 34e3cc0804fd..afc4d1eb212a 100644
--- a/sys-power/suspend/ChangeLog
+++ b/sys-power/suspend/ChangeLog
@@ -1,6 +1,11 @@
 # ChangeLog for sys-power/suspend
 # Copyright 1999-2015 Gentoo Foundation; Distributed under the GPL v2
-# $Header: /var/cvsroot/gentoo-x86/sys-power/suspend/ChangeLog,v 1.29 2015/04/29 19:35:35 mrueg Exp $
+# $Header: /var/cvsroot/gentoo-x86/sys-power/suspend/ChangeLog,v 1.30 2015/08/06 21:53:54 xmw Exp $
+
+*suspend-1.0_p20150622 (06 Aug 2015)
+
+  06 Aug 2015; Michael Weber <xmw@gentoo.org> +suspend-1.0_p20150622.ebuild:
+  Version bump by bircoph and k_f (bug 494638).
 
   29 Apr 2015; Manuel Rüger <mrueg@gentoo.org>
   -files/suspend-overflow-gentoo.patch, -suspend-0.8-r1.ebuild:
diff --git a/sys-power/suspend/suspend-1.0_p20150622.ebuild b/sys-power/suspend/suspend-1.0_p20150622.ebuild
new file mode 100644
index 000000000000..e84a791f88b9
--- /dev/null
+++ b/sys-power/suspend/suspend-1.0_p20150622.ebuild
@@ -0,0 +1,58 @@
+# Copyright 1999-2015 Gentoo Foundation
+# Distributed under the terms of the GNU General Public License v2
+# $Header: /var/cvsroot/gentoo-x86/sys-power/suspend/suspend-1.0_p20150622.ebuild,v 1.1 2015/08/06 21:53:54 xmw Exp $
+
+EAPI=5
+
+inherit autotools eutils
+
+BASE_PV="1.0_p20120915"
+
+DESCRIPTION="Userspace Software Suspend and S2Ram"
+HOMEPAGE="http://suspend.sourceforge.net/"
+SRC_URI="http://dev.gentoo.org/~bircoph/distfiles/${PN}-${BASE_PV}.tar.xz
+	http://dev.gentoo.org/~bircoph/patches/${P}.patch.xz"
+
+LICENSE="GPL-2"
+SLOT="0"
+KEYWORDS="~amd64 ~x86"
+IUSE="crypt fbsplash +lzo threads"
+
+RDEPEND="
+	dev-libs/libx86
+	crypt? (
+		>=dev-libs/libgcrypt-1.6.3:0[static-libs]
+		dev-libs/libgpg-error[static-libs] )
+	fbsplash? ( >=media-gfx/splashutils-1.5.2 )
+	lzo? ( >=dev-libs/lzo-2[static-libs] ) "
+DEPEND="${RDEPEND}
+	>=dev-lang/perl-5.10
+	>=sys-apps/pciutils-2.2.4
+	virtual/pkgconfig"
+
+S="${WORKDIR}/${PN}"
+
+src_prepare() {
+	epatch "${WORKDIR}/${P}.patch"
+	eautoreconf
+}
+
+src_configure() {
+	econf \
+		--docdir="/usr/share/doc/${PF}" \
+		$(use_enable crypt encrypt) \
+		$(use_enable fbsplash) \
+		$(use_enable lzo compress) \
+		$(use_enable threads)
+}
+
+src_install() {
+	dodir etc
+	emake DESTDIR="${D}" install
+	rm "${D}/usr/share/doc/${PF}"/COPYING* || die
+}
+
+pkg_postinst() {
+	elog "In order to make this package work with genkernel see:"
+	elog "http://bugs.gentoo.org/show_bug.cgi?id=156445"
+}