Version bump to fix incompatibility with fcgi 0.9.x.

(Portage version: 2.2.7/cvs/Linux x86_64, signed Manifest commit with key 0x8883FA56A308A8D7!)

2 files changed, 63 insertions, 1 deletions

diff --git a/www-servers/gorg/ChangeLog b/www-servers/gorg/ChangeLog
index 0fca7dbd7f85..526a1e128ca7 100644
--- a/www-servers/gorg/ChangeLog
+++ b/www-servers/gorg/ChangeLog
@@ -1,6 +1,11 @@
 # ChangeLog for www-servers/gorg
 # Copyright 1999-2013 Gentoo Foundation; Distributed under the GPL v2
-# $Header: /var/cvsroot/gentoo-x86/www-servers/gorg/ChangeLog,v 1.43 2013/12/21 07:55:59 graaff Exp $
+# $Header: /var/cvsroot/gentoo-x86/www-servers/gorg/ChangeLog,v 1.44 2013/12/25 19:51:34 graaff Exp $
+
+*gorg-0.7.1 (25 Dec 2013)
+
+  25 Dec 2013; Hans de Graaff <graaff@gentoo.org> +gorg-0.7.1.ebuild:
+  Version bump to fix incompatibility with fcgi 0.9.x.
 
   21 Dec 2013; Hans de Graaff <graaff@gentoo.org> -gorg-0.6.4-r1.ebuild,
   -gorg-0.6.5.ebuild:
diff --git a/www-servers/gorg/gorg-0.7.1.ebuild b/www-servers/gorg/gorg-0.7.1.ebuild
new file mode 100644
index 000000000000..dd6e8ad5d892
--- /dev/null
+++ b/www-servers/gorg/gorg-0.7.1.ebuild
@@ -0,0 +1,57 @@
+# Copyright 1999-2013 Gentoo Foundation
+# Distributed under the terms of the GNU General Public License v2
+# $Header: /var/cvsroot/gentoo-x86/www-servers/gorg/gorg-0.7.1.ebuild,v 1.1 2013/12/25 19:51:34 graaff Exp $
+
+EAPI=5
+USE_RUBY="ruby18 ruby19 ruby20"
+
+inherit ruby-ng eutils
+
+DESCRIPTION="Back-end XSLT processor for an XML-based web site"
+HOMEPAGE="http://www.gentoo.org/proj/en/gdp/doc/gorg.xml"
+SRC_URI="https://github.com/gentoo/gorg/archive/v${PV}.tar.gz -> ${P}.tar.gz"
+IUSE="fastcgi"
+
+SLOT="0"
+LICENSE="GPL-2"
+KEYWORDS="~amd64 ~ppc ~x86"
+
+CDEPEND="
+	>=dev-libs/libxml2-2.6.16
+	>=dev-libs/libxslt-1.1.12"
+DEPEND="${DEPEND} ${CDEPEND}"
+RDEPEND="${RDEPEND} ${CDEPEND}
+		fastcgi? ( virtual/httpd-fastcgi )"
+
+ruby_add_rdepend "
+	fastcgi? ( >=dev-ruby/fcgi-0.8.5-r1 )"
+
+pkg_setup() {
+	enewgroup gorg
+	enewuser  gorg -1 -1 -1 gorg
+}
+
+each_ruby_configure() {
+	${RUBY} setup.rb config --prefix=/usr || die
+}
+
+each_ruby_compile() {
+	${RUBY} setup.rb setup || die
+}
+
+each_ruby_install() {
+	${RUBY} setup.rb config --prefix="${D}"/usr || die
+	${RUBY} setup.rb install                    || die
+
+	# install doesn't seem to chmod these correctly, forcing it here
+	SITE_LIB_DIR=$(ruby_rbconfig_value 'sitelibdir')
+	chmod +x "${D}"/${SITE_LIB_DIR}/gorg/cgi-bin/*.cgi
+	chmod +x "${D}"/${SITE_LIB_DIR}/gorg/fcgi-bin/*.fcgi
+}
+
+all_ruby_install() {
+	keepdir /etc/gorg; insinto /etc/gorg ; doins etc/gorg/*
+	diropts -m0770 -o gorg -g gorg; keepdir /var/cache/gorg
+
+	dodoc Changelog README
+}