Add ruby21. Fix compilation with format-security, bug 520560.

(Portage version: 2.2.8-r1/cvs/Linux x86_64, signed Manifest commit with key 0x8883FA56A308A8D7!)

2 files changed, 63 insertions, 1 deletions

diff --git a/www-servers/gorg/ChangeLog b/www-servers/gorg/ChangeLog
index 446eae4a31af..bb82641f8f3c 100644
--- a/www-servers/gorg/ChangeLog
+++ b/www-servers/gorg/ChangeLog
@@ -1,6 +1,11 @@
 # ChangeLog for www-servers/gorg
 # Copyright 1999-2014 Gentoo Foundation; Distributed under the GPL v2
-# $Header: /var/cvsroot/gentoo-x86/www-servers/gorg/ChangeLog,v 1.46 2014/05/07 19:04:51 mrueg Exp $
+# $Header: /var/cvsroot/gentoo-x86/www-servers/gorg/ChangeLog,v 1.47 2014/08/22 15:54:14 graaff Exp $
+
+*gorg-0.7.2 (22 Aug 2014)
+
+  22 Aug 2014; Hans de Graaff <graaff@gentoo.org> +gorg-0.7.2.ebuild:
+  Add ruby21. Fix compilation with format-security, bug 520560.
 
   07 May 2014; Manuel Rüger <mrueg@gentoo.org> gorg-0.7.0.ebuild,
   gorg-0.7.1.ebuild:
diff --git a/www-servers/gorg/gorg-0.7.2.ebuild b/www-servers/gorg/gorg-0.7.2.ebuild
new file mode 100644
index 000000000000..4a41ce324c0a
--- /dev/null
+++ b/www-servers/gorg/gorg-0.7.2.ebuild
@@ -0,0 +1,57 @@
+# Copyright 1999-2014 Gentoo Foundation
+# Distributed under the terms of the GNU General Public License v2
+# $Header: /var/cvsroot/gentoo-x86/www-servers/gorg/gorg-0.7.2.ebuild,v 1.1 2014/08/22 15:54:14 graaff Exp $
+
+EAPI=5
+USE_RUBY="ruby19 ruby20 ruby21"
+
+inherit ruby-ng eutils user
+
+DESCRIPTION="Back-end XSLT processor for an XML-based web site"
+HOMEPAGE="http://www.gentoo.org/proj/en/gdp/doc/gorg.xml"
+SRC_URI="https://github.com/gentoo/gorg/archive/v${PV}.tar.gz -> ${P}.tar.gz"
+IUSE="fastcgi"
+
+SLOT="0"
+LICENSE="GPL-2"
+KEYWORDS="~amd64 ~ppc ~x86"
+
+CDEPEND="
+	>=dev-libs/libxml2-2.6.16
+	>=dev-libs/libxslt-1.1.12"
+DEPEND="${DEPEND} ${CDEPEND}"
+RDEPEND="${RDEPEND} ${CDEPEND}
+		fastcgi? ( virtual/httpd-fastcgi )"
+
+ruby_add_rdepend "
+	fastcgi? ( >=dev-ruby/fcgi-0.8.5-r1 )"
+
+pkg_setup() {
+	enewgroup gorg
+	enewuser  gorg -1 -1 -1 gorg
+}
+
+each_ruby_configure() {
+	${RUBY} setup.rb config --prefix=/usr || die
+}
+
+each_ruby_compile() {
+	${RUBY} setup.rb setup || die
+}
+
+each_ruby_install() {
+	${RUBY} setup.rb config --prefix="${D}"/usr || die
+	${RUBY} setup.rb install                    || die
+
+	# install doesn't seem to chmod these correctly, forcing it here
+	SITE_LIB_DIR=$(ruby_rbconfig_value 'sitelibdir')
+	chmod +x "${D}"/${SITE_LIB_DIR}/gorg/cgi-bin/*.cgi
+	chmod +x "${D}"/${SITE_LIB_DIR}/gorg/fcgi-bin/*.fcgi
+}
+
+all_ruby_install() {
+	keepdir /etc/gorg; insinto /etc/gorg ; doins etc/gorg/*
+	diropts -m0770 -o gorg -g gorg; keepdir /var/cache/gorg
+
+	dodoc Changelog README
+}