1 files changed, 58 insertions, 0 deletions
diff --git a/games-emulation/mednafen/mednafen-0.8.10.ebuild b/games-emulation/mednafen/mednafen-0.8.10.ebuild
new file mode 100644
index 000000000000..8e0bfe912779
--- /dev/null
+++ b/games-emulation/mednafen/mednafen-0.8.10.ebuild
@@ -0,0 +1,58 @@
+# Copyright 1999-2009 Gentoo Foundation
+# Distributed under the terms of the GNU General Public License v2
+# $Header: /var/cvsroot/gentoo-x86/games-emulation/mednafen/mednafen-0.8.10.ebuild,v 1.1 2009/01/30 02:19:05 mr_bones_ Exp $
+
+EAPI=2
+inherit autotools games
+
+DESCRIPTION="An advanced NES, GB/GBC/GBA, TurboGrafx 16/CD, NGPC and Lynx emulator"
+HOMEPAGE="http://mednafen.sourceforge.net/"
+SRC_URI="mirror://sourceforge/${PN}/mednafen-${PV/10/A}.tar.bz2"
+
+LICENSE="GPL-2"
+SLOT="0"
+KEYWORDS="~amd64 ~ppc ~x86"
+IUSE="alsa cjk debug jack nls"
+
+RDEPEND="virtual/opengl
+	media-libs/libsndfile
+	dev-libs/libcdio
+	media-libs/libsdl
+	media-libs/sdl-net
+	alsa? ( media-libs/alsa-lib )
+	jack? ( media-sound/jack-audio-connection-kit )
+	nls? ( virtual/libintl )"
+DEPEND="${RDEPEND}
+	dev-util/pkgconfig
+	nls? ( sys-devel/gettext )"
+
+S=${WORKDIR}/${PN}
+
+src_prepare() {
+	sed -i \
+		-e 's:$(datadir)/locale:/usr/share/locale:' \
+		-e 's:$(localedir):/usr/share/locale:' \
+		$(find . -name 'Makefile.*') \
+		|| die 'sed failed'
+	sed -i \
+		-e '/-fomit-frame/d' configure.ac \
+		|| die "sed failed"
+	eautoreconf
+}
+
+src_configure() {
+	egamesconf \
+		--disable-dependency-tracking \
+		$(use_enable alsa) \
+		$(use_enable cjk cjk-fonts) \
+		$(use_enable debug debugger) \
+		$(use_enable jack) \
+		$(use_enable nls)
+}
+
+src_install() {
+	emake DESTDIR="${D}" install || die "emake install failed"
+	dodoc Documentation/cheats.txt AUTHORS ChangeLog TODO
+	dohtml Documentation/*
+	prepgamesdirs
+}