1 files changed, 73 insertions, 0 deletions
diff --git a/net-dns/dnsmasq/dnsmasq-2.56.ebuild b/net-dns/dnsmasq/dnsmasq-2.56.ebuild
new file mode 100644
index 000000000000..e6874062a4fd
--- /dev/null
+++ b/net-dns/dnsmasq/dnsmasq-2.56.ebuild
@@ -0,0 +1,73 @@
+# Copyright 1999-2011 Gentoo Foundation
+# Distributed under the terms of the GNU General Public License v2
+# $Header: /var/cvsroot/gentoo-x86/net-dns/dnsmasq/dnsmasq-2.56.ebuild,v 1.1 2011/02/16 19:33:07 chutzpah Exp $
+
+EAPI=2
+
+inherit eutils toolchain-funcs flag-o-matic
+
+MY_P="${P/_/}"
+MY_PV="${PV/_/}"
+DESCRIPTION="Small forwarding DNS server"
+HOMEPAGE="http://www.thekelleys.org.uk/dnsmasq/"
+SRC_URI="http://www.thekelleys.org.uk/dnsmasq/${MY_P}.tar.lzma"
+
+LICENSE="GPL-2"
+SLOT="0"
+KEYWORDS="~alpha ~amd64 ~arm ~hppa ~ia64 ~mips ~ppc ~ppc64 ~s390 ~sh ~sparc ~x86 ~sparc-fbsd ~x86-fbsd"
+IUSE="dbus +dhcp ipv6 nls tftp"
+
+RDEPEND="dbus? ( sys-apps/dbus )
+	nls? (
+		sys-devel/gettext
+		net-dns/libidn
+	)"
+
+DEPEND="${RDEPEND}
+	dev-util/pkgconfig
+	|| ( app-arch/xz-utils app-arch/lzma-utils )"
+
+S="${WORKDIR}/${PN}-${MY_PV}"
+
+src_prepare() {
+	sed -i '/^AWK/s:nawk:gawk:' Makefile #214865
+
+	# dnsmasq on FreeBSD wants the config file in a silly location, this fixes
+	epatch "${FILESDIR}/${PN}-2.47-fbsd-config.patch"
+}
+
+src_configure() {
+	use tftp || append-flags -DNO_TFTP
+	use dhcp || append-flags -DNO_DHCP
+	use ipv6 || append-flags -DNO_IPV6
+	use dbus && sed -i '$ a #define HAVE_DBUS' src/config.h
+}
+
+src_compile() {
+	emake \
+		PREFIX=/usr \
+		CC="$(tc-getCC)" \
+		CFLAGS="${CFLAGS}" \
+		all$(use nls && echo "-i18n") || die
+}
+
+src_install() {
+	emake \
+		PREFIX=/usr \
+		MANDIR=/usr/share/man \
+		DESTDIR="${D}" \
+		install$(use nls && echo "-i18n") || die
+
+	dodoc CHANGELOG FAQ
+	dohtml *.html
+
+	newinitd "${FILESDIR}"/dnsmasq-init dnsmasq
+	newconfd "${FILESDIR}"/dnsmasq.confd dnsmasq
+	insinto /etc
+	newins dnsmasq.conf.example dnsmasq.conf
+
+	if use dbus ; then
+		insinto /etc/dbus-1/system.d
+		doins dbus/dnsmasq.conf
+	fi
+}