app-text/gtranslator/gtranslator-2.90.5.ebuild


1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
65
66
67
68
69
70
71
72
73
74
75
76
77
78
79
80
81
82
83

# Copyright 1999-2011 Gentoo Foundation
# Distributed under the terms of the GNU General Public License v2
# $Header: /var/cvsroot/gentoo-x86/app-text/gtranslator/gtranslator-2.90.5.ebuild,v 1.1 2011/10/01 16:59:51 nirbheek Exp $

EAPI="3"
GCONF_DEBUG="no"
GNOME2_LA_PUNT="yes"
PYTHON_DEPEND="gnome? 2"

inherit eutils gnome2 multilib python

DESCRIPTION="An enhanced gettext po file editor for GNOME"
HOMEPAGE="http://gtranslator.sourceforge.net/"

LICENSE="GPL-2"
SLOT="0"
KEYWORDS="~amd64 ~x86"
IUSE="doc gnome"

COMMON_DEPEND="
	>=dev-libs/glib-2.28.0:2
	>=x11-libs/gtk+-3.0.3:3
	>=x11-libs/gtksourceview-3.0.0:3.0
	>=dev-libs/gdl-2.91.91:3
	>=dev-libs/libxml2-2.4.12:2
	>=dev-libs/json-glib-0.12.0
	>=dev-libs/libpeas-1.0.0[gtk]
	>=gnome-extra/libgda-4.2.0:4
	>=app-text/iso-codes-0.35

	gnome-base/gsettings-desktop-schemas

	gnome? (
		gnome-extra/gnome-utils
		x11-libs/gtk+:3[introspection] )"
RDEPEND="${COMMON_DEPEND}
	gnome? (
		>=dev-libs/libpeas-1.0.0[gtk,python]
		|| ( dev-python/pygobject:2[introspection] dev-python/pygobject:3 )
		gnome-extra/gucharmap:2.90[introspection] )"
DEPEND="${COMMON_DEPEND}
	>=app-text/scrollkeeper-0.1.4
	>=dev-util/intltool-0.40
	>=sys-devel/gettext-0.17
	dev-util/pkgconfig
	app-text/gnome-doc-utils
	app-text/docbook-xml-dtd:4.1.2
	doc? ( >=dev-util/gtk-doc-1 )"

pkg_setup() {
	DOCS="AUTHORS ChangeLog HACKING INSTALL NEWS README THANKS"
	# gtkspell hasn't been ported to gtk+3 yet
	G2CONF="${G2CONF}
		--disable-static
		--without-gtkspell
		$(use_with gnome dictionary)
		$(use_enable gnome introspection)"
}

src_prepare() {
	gnome2_src_prepare

	# disable pyc compiling
	ln -sfn $(type -P true) py-compile
	if ! use gnome; then
		# don't install charmap plugin, it requires gnome-extra/gucharmap
		sed -e 's:\scharmap\s: :g' -i plugins/Makefile.* ||
			die "sed plugins/Makefile.* failed"
	fi
}

pkg_postinst() {
	gnome2_pkg_postinst
	if use gnome; then
		python_need_rebuild
		python_mod_optimize /usr/$(get_libdir)/gtranslator/plugins
	fi
}

pkg_postrm() {
	gnome2_pkg_postrm
	use gnome && python_mod_cleanup /usr/$(get_libdir)/gtranslator/plugins
}