media-gfx/dawn/dawn-3.88a.ebuild


1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61

# Copyright 1999-2009 Gentoo Foundation
# Distributed under the terms of the GNU General Public License v2
# $Header: /var/cvsroot/gentoo-x86/media-gfx/dawn/dawn-3.88a.ebuild,v 1.6 2009/03/22 21:40:36 darkside Exp $

#EAPI=0
inherit eutils versionator

MYP=${PN}_$(replace_version_separator 1 _)

DESCRIPTION="3D geometrical postscript renderer"
HOMEPAGE="http://geant4.kek.jp/~tanaka/DAWN/About_DAWN.html"
SRC_URI="http://geant4.kek.jp/~tanaka/src/${MYP}.taz"

LICENSE="public-domain"
SLOT="0"

KEYWORDS="amd64 ~hppa ~ppc sparc ~x86"
IUSE="doc opengl X"

RDEPEND="dev-lang/tk
	X? ( x11-libs/libX11 )
	opengl? ( virtual/opengl )"
DEPEND="${RDEPEND}
	app-shells/tcsh
	doc? ( virtual/latex-base )"

S="${WORKDIR}/${MYP}"

src_unpack() {
	# unpack does not recognize taz suffix
	tar xfz "${DISTDIR}"/${MYP}.taz
	cd "${S}"
	epatch "${FILESDIR}"/${P}-no-interactive.patch
	sed -i -e '/strip/d' Makefile*in || die "sed Makefile failed"
}

src_compile() {
	emake clean
	emake guiclean
	if ! use X && ! use opengl; then
		./configure_min || die "configure failed"
	elif ! use opengl; then
		./configure_xwin || die "configure_xwin failed"
	else
		./configure || die "configure failed"
	fi
	einfo "Compiling"
	emake  || die "emake failed"
}

src_install() {
	dodir /usr/bin
	emake DESTDIR="${D}" install || die "emake install failed"
	dodoc README.txt
	if use doc; then
		pdflatex DOC/G4PRIM_FORMAT_24.tex || die "pdf generation failed"
		insinto /usr/share/doc/${PF}
		doins DOC/G4PRIM_FORMAT_24.pdf
		dohtml DOC/*.html
	fi
}