blob: 3af43c7789a5ac057404bc2b6d6fc8805808b74d (
plain)
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
65
66
67
68
69
70
71
72
73
74
75
76
77
78
79
80
81
82
83
84
85
86
87
88
89
90
91
92
93
94
95
96
97
98
99
100
101
102
103
104
105
106
107
108
109
110
111
112
113
114
115
116
117
118
119
120
121
122
123
|
# Copyright 1999-2014 Gentoo Foundation
# Distributed under the terms of the GNU General Public License v2
# $Header: /var/cvsroot/gentoo-x86/media-video/mjpegtools/mjpegtools-2.1.0-r2.ebuild,v 1.3 2014/06/18 20:31:11 mgorny Exp $
EAPI=5
inherit autotools eutils flag-o-matic multilib-minimal toolchain-funcs
DESCRIPTION="Tools for MJPEG video"
HOMEPAGE="http://mjpeg.sourceforge.net/"
SRC_URI="mirror://sourceforge/mjpeg/${P}.tar.gz"
LICENSE="GPL-2"
SLOT="1"
KEYWORDS="~alpha ~amd64 ~arm ~hppa ~ia64 ~ppc ~ppc64 ~sparc ~x86 ~amd64-fbsd"
IUSE="dv gtk mmx png quicktime sdl sdlgfx static-libs v4l"
REQUIRED_USE="sdlgfx? ( sdl )"
RDEPEND=">=virtual/jpeg-0-r2[${MULTILIB_USEDEP}]
quicktime? ( >=media-libs/libquicktime-1.2.4-r1[${MULTILIB_USEDEP}] )
dv? ( >=media-libs/libdv-1.0.0-r3[${MULTILIB_USEDEP}] )
png? ( media-libs/libpng:0= )
gtk? ( x11-libs/gtk+:2 )
sdl? ( >=media-libs/libsdl-1.2.15-r4[${MULTILIB_USEDEP}]
>=x11-libs/libX11-1.6.2[${MULTILIB_USEDEP}]
sdlgfx? ( media-libs/sdl-gfx )
)"
DEPEND="${RDEPEND}
mmx? ( dev-lang/nasm )
>=sys-apps/sed-4
virtual/awk
>=virtual/pkgconfig-0-r1[${MULTILIB_USEDEP}]"
RDEPEND="${RDEPEND}
abi_x86_32? (
!<=app-emulation/emul-linux-x86-medialibs-20140508-r4
!app-emulation/emul-linux-x86-medialibs[-abi_x86_32(-)]
)"
pkg_pretend() {
if has_version ">=sys-kernel/linux-headers-2.6.38" && use v4l; then
ewarn "Current versions of mjpegtools only support V4L1 which is not available"
ewarn "for kernel versions 2.6.38 and above. V4L1 will be disabled."
fi
}
src_prepare() {
epatch "${FILESDIR}"/${P}-pic.patch
# https://sourceforge.net/p/mjpeg/bugs/139/
epatch "${FILESDIR}"/${P}-sdl-cflags.patch
eautoreconf
sed -i -e '/ARCHFLAGS=/s:=.*:=:' configure
}
multilib_src_configure() {
[[ $(gcc-major-version) -eq 3 ]] && append-flags -mno-sse2
local myconf=(
--enable-compile-warnings
$(use_enable mmx simd-accel)
$(use_enable static-libs static)
--enable-largefile
$(use_with quicktime libquicktime)
$(use_with dv libdv)
$(use_with sdl libsdl)
$(use_with v4l)
$(use_with sdl x)
# used by tools only
$(multilib_native_use_with gtk)
$(multilib_native_use_with png libpng)
$(multilib_native_use_with sdlgfx)
# used only in V4LCONF_LIBS that is not used anywhere...
--without-dga
)
ECONF_SOURCE=${S} \
econf "${myconf[@]}"
}
multilib_src_compile() {
if multilib_is_native_abi; then
default
else
# avoid building programs
emake bin_PROGRAMS=
fi
}
multilib_src_test() {
# there are no tests at the moment, so it would just build
# all programs in non-native ABIs...
multilib_is_native_abi && default
}
multilib_src_install() {
if multilib_is_native_abi; then
default
else
emake DESTDIR="${D}" install \
bin_PROGRAMS=
fi
}
multilib_src_install_all() {
einstalldocs
dodoc mjpeg_howto.txt PLANS HINTS docs/FAQ.txt
prune_libtool_files --all
}
pkg_postinst() {
if [[ -z "${REPLACING_VERSIONS}" ]]; then
elog "mjpegtools installs user contributed scripts which require additional"
elog "dependencies not pulled in by the installation."
elog "These have to be installed manually."
elog "Currently known extra dpendencies are: ffmpeg, mencoder from mplayer,"
elog "parts of transcode, mpeg2dec from libmpeg2, sox, toolame, vcdimager, python."
fi
}
|
GitWeb