media-video/vcdimager/vcdimager-0.7.23-r1.ebuild


1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44

# Copyright 1999-2012 Gentoo Foundation
# Distributed under the terms of the GNU General Public License v2
# $Header: /var/cvsroot/gentoo-x86/media-video/vcdimager/vcdimager-0.7.23-r1.ebuild,v 1.4 2012/11/17 06:31:57 ssuominen Exp $

EAPI=5
inherit eutils

DESCRIPTION="GNU VCDimager"
HOMEPAGE="http://www.vcdimager.org/"
SRC_URI="http://www.vcdimager.org/pub/${PN}/${PN}-${PV%.*}/${P}.tar.gz"

LICENSE="GPL-2"
SLOT="0"
KEYWORDS="~alpha ~amd64 ~arm ~hppa ~ia64 ~ppc ~ppc64 ~sh ~sparc ~x86 ~amd64-fbsd ~x86-fbsd"
IUSE="xml minimal static-libs"

RDEPEND=">=dev-libs/libcdio-0.71[-minimal]
	!minimal? ( dev-libs/popt )
	xml? ( >=dev-libs/libxml2-2.5.11 )"
DEPEND="${RDEPEND}
	virtual/pkgconfig"

RESTRICT="test" #226249

DOCS="AUTHORS BUGS ChangeLog FAQ HACKING NEWS README THANKS TODO"

src_configure() {
	local myconf

	# We disable the xmltest because the configure script includes differently
	# than the actual XML-frontend C files.
	use xml && myconf="--with-xml-prefix=/usr --disable-xmltest"
	use xml || myconf="--without-xml-frontend"

	econf \
		$(use_enable static-libs static) \
		$(use_with !minimal cli-frontends) \
		${myconf}
}

src_install() {
	default
	prune_libtool_files
}