sci-libs/clipper/clipper-20091215.ebuild


1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63

# Copyright 1999-2010 Gentoo Foundation
# Distributed under the terms of the GNU General Public License v2
# $Header: /var/cvsroot/gentoo-x86/sci-libs/clipper/clipper-20091215.ebuild,v 1.1 2010/02/04 21:26:38 jlec Exp $

EAPI="3"

WANT_AUTOMAKE="1.11"

inherit autotools eutils flag-o-matic

DESCRIPTION="Object-oriented libraries for the organisation of crystallographic data and the performance of crystallographic computation"
HOMEPAGE="http://www.ysbl.york.ac.uk/~cowtan/clipper/clipper.html"
# Transform 4-digit year to 2 digits
SRC_URI="http://www.ysbl.york.ac.uk/~cowtan/clipper/clipper-2.1-${PV:2:${#PV}}-ac.tar.gz"

LICENSE="LGPL-2.1"
SLOT="0"
KEYWORDS="~x86 ~amd64"
IUSE="debug"

RDEPEND="
	sci-libs/ccp4-libs
	sci-libs/fftw"
DEPEND="${RDEPEND}"

S="${WORKDIR}"/${PN}-2.1

src_prepare() {
	epatch "${FILESDIR}"/${PV}-missing-var.patch

	# ccp4 provides these, and more.
	sed -i -e "s:examples::g" "${S}"/Makefile.am

	AT_M4DIR="config" eautoreconf
}

src_configure() {
	# Recommended on ccp4bb/coot ML to fix crashes when calculating maps
	# on 64-bit systems
	append-flags -fno-strict-aliasing

	econf \
		--enable-ccp4 \
		--enable-cif \
		--enable-cns \
		--enable-contrib \
		--enable-minimol \
		--enable-mmdb \
		--enable-phs \
		--with-mmdb=${EPREFIX}/usr \
		$(use_enable debug)
}

src_test() {
	emake \
		-C examples \
		check || die
}

src_install() {
	emake DESTDIR="${D}" install || die
	dodoc README ChangeLog NEWS || die
}