sys-block/aoetools/aoetools-22.ebuild


1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42

# Copyright 1999-2007 Gentoo Foundation
# Distributed under the terms of the GNU General Public License v2
# $Header: /var/cvsroot/gentoo-x86/sys-block/aoetools/aoetools-22.ebuild,v 1.1 2007/12/14 12:07:34 robbat2 Exp $

DESCRIPTION="aoetools are programs for users of the ATA over Ethernet (AoE) network storage protocol"
HOMEPAGE="http://sf.net/projects/aoetools/"
SRC_URI="mirror://sourceforge/aoetools/${P}.tar.gz"
LICENSE="GPL-2"
SLOT="0"
KEYWORDS="~amd64 ~ppc ~ppc64 ~x86"
IUSE=""
DEPEND="virtual/libc"
RDEPEND="${DEPEND}
		sys-apps/util-linux"

src_unpack() {
	unpack ${A}
	cd "${S}"
	# messy tarball
	emake -j1 clean  || die "Failed to clean up source"
	sed -i \
		-e 's,^CFLAGS.*,CFLAGS += -Wall,g' \
		Makefile || die "Failed to clean up makefile"
	for i in aoe-stat aoe-mkshelf.in ; do
		sed -i \
			-e '/bc/s!\\\*!*!g' \
			-e '/bc/s!"!!g' \
			-e '/bc/s!=`echo \(.*\) | bc`!=$((\1))!g' \
			"${i}"
	done
}
src_compile() {
	emake -j1 configure || die "emake configure failed"
	emake || die "emake failed"
}

src_install() {
	into /usr
	dodir /usr/sbin /usr/bin
	emake -j1 install DESTDIR="${D}" SBINDIR="/usr/sbin" MANDIR="/usr/share/man"
	dodoc HACKING NEWS README TODO devnodes.txt
}