sys-fs/xfsprogs/xfsprogs-2.6.3.ebuild


1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
65
66
67

# Copyright 1999-2004 Gentoo Foundation
# Distributed under the terms of the GNU General Public License v2
# $Header: /var/cvsroot/gentoo-x86/sys-fs/xfsprogs/xfsprogs-2.6.3.ebuild,v 1.8 2004/07/28 19:27:07 avenj Exp $

inherit flag-o-matic

DESCRIPTION="xfs filesystem utilities"
HOMEPAGE="http://oss.sgi.com/projects/xfs/"
SRC_URI="ftp://oss.sgi.com/projects/xfs/download/cmd_tars/${P}.src.tar.gz"

LICENSE="LGPL-2.1"
SLOT="0"
KEYWORDS="x86 ~ppc ~sparc ~alpha ~mips ~hppa amd64 ~ia64"
IUSE=""

RDEPEND="virtual/libc
	sys-fs/e2fsprogs"
DEPEND="${RDEPEND}
	>=sys-apps/sed-4"

src_unpack() {
	unpack ${A}
	cd ${S}
	sed -i \
		-e "/^PKG_DOC_DIR/s:=.*:= /usr/share/doc/${PF}:" \
		-e '/^GCFLAGS/s:-O1::' \
		-e '/^PKG_[[:upper:]]*_DIR/s:= := $(DESTDIR):' \
		include/builddefs.in \
		|| die "sed include/builddefs.in failed"
}

src_compile() {
	replace-flags -O[2-9] -O1
	export OPTIMIZER="${CFLAGS}"
	export DEBUG=-DNDEBUG

	# Some archs need the PLATFORM var unset
	if hasq ${ARCH} mips ppc sparc; then
		unset PLATFORM
	fi

	econf \
		--bindir=/bin \
		--sbindir=/sbin \
		--libdir=/lib \
		--libexecdir=/lib \
		|| die "config failed"
	emake || die
}

src_install() {
	make \
		DESTDIR=${D} \
		DK_INC_DIR=${D}/usr/include/disk \
		install install-dev \
		|| die "make install failed"
	dosym /lib/libhandle.so.1 /lib/libhandle.so

	dodir /usr/lib
	sed \
		-e 's:installed=no:installed=yes:g' \
		${S}/libhandle/.libs/libhandle.la \
		> ${D}/usr/lib/libhandle.la \
		|| die "sed failed"
	mv ${D}/lib/*.a ${D}/usr/lib/ || die "mv failed"
	prepalldocs
}