[app-crypt/qca] Version bump, bug #528620

Package-Manager: portage-2.2.15

3 files changed, 148 insertions, 0 deletions

diff --git a/app-crypt/qca/Manifest b/app-crypt/qca/Manifest
new file mode 100644
index 0000000000..18123dcaf8
--- /dev/null
+++ b/app-crypt/qca/Manifest
@@ -0,0 +1 @@
+DIST qca-qt5-2.1.0.3.tar.xz 685652 SHA256 ab0170696a8ff87588d38a72d36d0b4b42db9080c991d1a40ceb3f8311d289f9 SHA512 2f50c92d3ff927c83353b65ae56ff49a5c1ea439fcef94cea0092b718f04abcc18f455abd91337ac786fddedae980ff55c9d090b5743a96890174dc7eee4f3f1 WHIRLPOOL 9db2770b031dbf5c9c117d4150e0b395c94d8a0af1bda9fac5e1ee862a8a40f1c03fb0c4901e3aaba0b12e8c0b4e71cb55a872bbc54eea8331aff3fbe1fd853c
diff --git a/app-crypt/qca/metadata.xml b/app-crypt/qca/metadata.xml
new file mode 100644
index 0000000000..71e64852ee
--- /dev/null
+++ b/app-crypt/qca/metadata.xml
@@ -0,0 +1,18 @@
+<?xml version="1.0" encoding="UTF-8"?>
+<!DOCTYPE pkgmetadata SYSTEM "http://www.gentoo.org/dtd/metadata.dtd">
+<pkgmetadata>
+<herd>crypto</herd>
+<herd>qt</herd>
+<herd>kde</herd>
+<use>
+	<flag name="botan">Enable botan plugin</flag>
+	<flag name="gcrypt">Enable gcrypt plugin</flag>
+	<flag name="gpg">Enable GnuPG plugin</flag>
+	<flag name="logger">Enable logger plugin</flag>
+	<flag name="nss">Enable NSS plugin</flag>
+	<flag name="openssl">Enable OpenSSL plugin</flag>
+	<flag name="pkcs11">Enable PKCS#11 plugin</flag>
+	<flag name="sasl">Enable SASL plugin</flag>
+	<flag name="softstore">Enable softstore plugin</flag>
+</use>
+</pkgmetadata>
diff --git a/app-crypt/qca/qca-2.1.0.3.ebuild b/app-crypt/qca/qca-2.1.0.3.ebuild
new file mode 100644
index 0000000000..d3d1819833
--- /dev/null
+++ b/app-crypt/qca/qca-2.1.0.3.ebuild
@@ -0,0 +1,129 @@
+# Copyright 1999-2015 Gentoo Foundation
+# Distributed under the terms of the GNU General Public License v2
+# $Header: $
+
+EAPI=5
+
+MY_PN="${PN}-qt5"
+inherit multilib cmake-utils multibuild
+
+DESCRIPTION="Qt Cryptographic Architecture (QCA)"
+HOMEPAGE="http://delta.affinix.com/qca/"
+SRC_URI="mirror://kde/stable/${MY_PN}/${PV}/src/${MY_PN}-${PV}.tar.xz"
+
+LICENSE="LGPL-2.1"
+SLOT="2"
+KEYWORDS="~amd64"
+
+IUSE="botan debug doc examples gcrypt gpg logger nss openssl pkcs11 +qt4 qt5 sasl softstore test"
+REQUIRED_USE="|| ( qt4 qt5 )"
+
+RDEPEND="
+	!app-crypt/qca-cyrus-sasl
+	!app-crypt/qca-gnupg
+	!app-crypt/qca-logger
+	!app-crypt/qca-ossl
+	!app-crypt/qca-pkcs11
+	botan? ( dev-libs/botan )
+	gcrypt? ( dev-libs/libgcrypt:= )
+	gpg? ( app-crypt/gnupg )
+	nss? ( dev-libs/nss )
+	openssl? ( dev-libs/openssl:0 )
+	pkcs11? (
+		dev-libs/openssl:0
+		dev-libs/pkcs11-helper
+	)
+	qt4? ( dev-qt/qtcore:4 )
+	qt5? (
+		dev-qt/qtcore:5
+		dev-qt/qtconcurrent:5
+		dev-qt/qtnetwork:5
+	)
+	sasl? ( dev-libs/cyrus-sasl:2 )
+"
+DEPEND="${RDEPEND}
+	doc? ( app-doc/doxygen )
+	test? (
+		qt4? ( dev-qt/qttest:4 )
+		qt5? ( dev-qt/qttest:5 )
+	)
+"
+
+DOCS=( README TODO )
+
+S=${WORKDIR}/${MY_PN}-${PV}
+
+qca_plugin_use() {
+	echo "-DWITH_${2:-$1}_PLUGIN=$(use $1 && echo yes || echo no)"
+}
+
+pkg_setup() {
+	MULTIBUILD_VARIANTS=()
+	if use qt4; then
+		MULTIBUILD_VARIANTS+=(qt4)
+	fi
+
+	if use qt5; then
+		MULTIBUILD_VARIANTS+=(qt5)
+	fi
+}
+
+src_configure() {
+	myconfigure() {
+		local mycmakeargs=(
+			$(qca_plugin_use botan)
+			$(qca_plugin_use gcrypt)
+			$(qca_plugin_use gpg gnupg)
+			$(qca_plugin_use logger)
+			$(qca_plugin_use nss)
+			$(qca_plugin_use openssl ossl)
+			$(qca_plugin_use pkcs11)
+			$(qca_plugin_use sasl cyrus-sasl)
+			$(qca_plugin_use softstore)
+			$(cmake-utils_use_build test TESTS)
+		)
+
+		if [[ ${MULTIBUILD_VARIANT} = qt4 ]]; then
+			mycmakeargs+=(
+				-DQT4_BUILD=ON
+				-DQCA_PLUGINS_INSTALL_DIR="${EPREFIX}/usr/$(get_libdir)/qt4/plugins"
+				-DQCA_FEATURE_INSTALL_DIR="${EPREFIX}/usr/share/qt4/mkspecs/features"
+			)
+		fi
+
+		if [[ ${MULTIBUILD_VARIANT} = qt5 ]]; then
+			mycmakeargs+=(
+				-DQCA_PLUGINS_INSTALL_DIR="${EPREFIX}/usr/$(get_libdir)/qt5/plugins"
+				-DQCA_FEATURE_INSTALL_DIR="${EPREFIX}/usr/$(get_libdir)/qt5/mkspecs/features"
+			)
+		fi
+
+		cmake-utils_src_configure
+	}
+
+	multibuild_foreach_variant myconfigure
+}
+
+src_compile() {
+	multibuild_foreach_variant cmake-utils_src_compile
+}
+
+src_install() {
+	multibuild_foreach_variant cmake-utils_src_install
+
+	if use doc; then
+		pushd "${BUILD_DIR}" >/dev/null
+		doxygen Doxyfile || die
+		dohtml apidocs/html/*
+		popd >/dev/null
+	fi
+
+	if use examples; then
+		insinto /usr/share/doc/${PF}
+		doins -r "${S}"/examples
+	fi
+}
+
+src_test() {
+	multibuild_foreach_variant cmake-utils_src_test
+}