sci-visualization/fsleyes: version bump

Package-Manager: Portage-3.0.13, Repoman-3.0.2
Signed-off-by: Andrew Ammerlaan <andrewammerlaan@riseup.net>

3 files changed, 32 insertions, 98 deletions

diff --git a/sci-visualization/fsleyes/Manifest b/sci-visualization/fsleyes/Manifest
index 451be541a..b0bb02365 100644
--- a/sci-visualization/fsleyes/Manifest
+++ b/sci-visualization/fsleyes/Manifest
@@ -1,2 +1 @@
-DIST fsleyes-0.32.0.tar.gz 87700064 BLAKE2B 654905009490eb5d9c1eeecec0b4b2d3965e32e3935895e64a594655588fe60292a9289a3b78545786e9af4d41aa3069180928b8e8218737010068a1b320805f SHA512 de501e0527c94faad77bffdc6e9262ae185e661bc1b2ca494d75e7f33d7532b7b786c0b776682a0fa08fc48708e3d090de5319b02d4f9b3c0abb75c7cf1e9d1a
-DIST fsleyes-0.32.3.tar.gz 87756679 BLAKE2B 1d094041352ca301fc4574424d73b9dfb49efbf4d7dc69a941a297ba78a267035d62e5f9a384793b52167fb95874ae404103fe0b95f2028e74926286582268ec SHA512 0027f923deac82d7d5f4916716dd46579c9a824d86415896fbb096bcc94cd3eead2f2d754b55d666764783abc9025d6d6f6313d1cee60bd1035348191475dd0f
+DIST fsleyes-0.34.2.tar.gz 88940639 BLAKE2B 33b942f7f0873ebd3749c75a3a1926e4596d85d6c600a66c4fc5878e570315fa003f6e2124b0b9de79637a8298550e37365607867a52cd516ca1d0c301f6945d SHA512 9fdd87e54922a34c5eea71b47abed8cdd69749a94b15cc7d583f9608bdec78021ba08988206545eee9072ad328bbef32b15f6f984a0343fb808553c6b47ea4e4
diff --git a/sci-visualization/fsleyes/fsleyes-0.32.3.ebuild b/sci-visualization/fsleyes/fsleyes-0.32.3.ebuild
deleted file mode 100644
index 37c5a3827..000000000
--- a/sci-visualization/fsleyes/fsleyes-0.32.3.ebuild
+++ /dev/null
@@ -1,80 +0,0 @@
-# Copyright 1999-2020 Gentoo Authors
-# Distributed under the terms of the GNU General Public License v2
-
-EAPI=7
-
-PYTHON_COMPAT=( python3_7 )
-
-inherit distutils-r1 desktop virtualx
-
-DESCRIPTION="The new FSL image viewer, released with FSL 5.0.10"
-HOMEPAGE="https://git.fmrib.ox.ac.uk/fsl/fsleyes/fsleyes/tree/master"
-SRC_URI="
-	https://git.fmrib.ox.ac.uk/fsl/fsleyes/fsleyes/-/archive/${PV}/${P}.tar.gz
-	https://github.com/pauldmccarthy/fsleyes/archive/${PV}.tar.gz -> ${P}.tar.gz
-	"
-
-LICENSE="Apache-2.0"
-SLOT="0"
-KEYWORDS="~amd64 ~x86"
-IUSE="test"
-
-DEPEND="
-	test? (
-		${RDEPEND}
-		dev-python/mock[${PYTHON_USEDEP}]
-		dev-python/pytest[${PYTHON_USEDEP}]
-		)
-	dev-python/setuptools[${PYTHON_USEDEP}]
-	"
-
-RDEPEND="
-	>=dev-python/fslpy-1.13.2[${PYTHON_USEDEP}]
-	=dev-python/jinja-2*[${PYTHON_USEDEP}]
-	>=dev-python/matplotlib-1.5.1[${PYTHON_USEDEP}]
-	>=dev-python/numpy-1.14.0[${PYTHON_USEDEP}]
-	>=dev-python/pillow-3.4.2[${PYTHON_USEDEP}]
-	>=dev-python/pyopengl-3.1.0[${PYTHON_USEDEP}]
-	>=dev-python/pyopengl_accelerate-3.1.0[${PYTHON_USEDEP}]
-	=dev-python/pyparsing-2*[${PYTHON_USEDEP}]
-	=dev-python/six-1*[${PYTHON_USEDEP}]
-	>=dev-python/wxpython-3.0.2.0[${PYTHON_USEDEP}]
-	>=dev-python/scipy-0.18[${PYTHON_USEDEP}]
-	sci-libs/nibabel[${PYTHON_USEDEP}]
-	sci-visualization/fsleyes-widgets[${PYTHON_USEDEP}]
-	sci-visualization/fsleyes-props[${PYTHON_USEDEP}]
-	"
-#=sci-libs/nibabel-2*[${PYTHON_USEDEP}]
-
-PATCHES=(
-	"${FILESDIR}/${PN}-0.26.2-fsldir.patch"
-	"${FILESDIR}/${PN}-0.32.0-coverage.patch"
-	"${FILESDIR}/${PN}-0.32.0-tests_timeout.patch"
-	"${FILESDIR}/${PN}-0.32.0-tests_fail.patch"
-	)
-
-src_prepare() {
-	sed -i -e "s/Pillow>=3.2.0,<6.0/Pillow>=3.2.0/g" requirements.txt
-	distutils-r1_src_prepare
-}
-
-python_install_all() {
-	distutils-r1_python_install_all
-	doicon userdoc/images/fsleyes_icon.png
-	local size
-	for size in 16 32 128 256 512 ; do
-		doicon -s ${size} assets/icons/app_icon/${PN}.iconset/icon_${size}x${size}.png
-	done
-	make_desktop_entry fsleyes FSLeyes /usr/share/icons/hicolor/128x128/apps/icon_128x128.png
-}
-
-pkg_postinst() {
-	gnome2_icon_cache_update
-}
-pkg_postrm() {
-	gnome2_icon_cache_update
-}
-
-python_test() {
-	virtx pytest -vv || die
-}
diff --git a/sci-visualization/fsleyes/fsleyes-0.32.0.ebuild b/sci-visualization/fsleyes/fsleyes-0.34.2.ebuild
index 0ff118e75..8c69cbc50 100644
--- a/sci-visualization/fsleyes/fsleyes-0.32.0.ebuild
+++ b/sci-visualization/fsleyes/fsleyes-0.34.2.ebuild
@@ -1,9 +1,10 @@
-# Copyright 1999-2020 Gentoo Authors
+# Copyright 1999-2021 Gentoo Authors
 # Distributed under the terms of the GNU General Public License v2
 
 EAPI=7
 
-PYTHON_COMPAT=( python3_7 )
+PYTHON_COMPAT=( python3_{7,8} )
+DISTUTILS_USE_SETUPTOOLS=rdepend
 
 inherit distutils-r1 desktop virtualx
 
@@ -17,44 +18,58 @@ SRC_URI="
 LICENSE="Apache-2.0"
 SLOT="0"
 KEYWORDS="~amd64 ~x86"
-IUSE="test"
 
 DEPEND="
 	test? (
 		${RDEPEND}
 		dev-python/mock[${PYTHON_USEDEP}]
-		dev-python/pytest[${PYTHON_USEDEP}]
 		)
-	dev-python/setuptools[${PYTHON_USEDEP}]
 	"
 
 RDEPEND="
-	>=dev-python/fslpy-1.13.2[${PYTHON_USEDEP}]
+	>=dev-python/fslpy-3.1[${PYTHON_USEDEP}]
 	=dev-python/jinja-2*[${PYTHON_USEDEP}]
 	>=dev-python/matplotlib-1.5.1[${PYTHON_USEDEP}]
 	>=dev-python/numpy-1.14.0[${PYTHON_USEDEP}]
-	>=dev-python/pillow-3.4.2[${PYTHON_USEDEP}]
+	>=dev-python/pillow-3.2.0[${PYTHON_USEDEP}]
 	>=dev-python/pyopengl-3.1.0[${PYTHON_USEDEP}]
 	>=dev-python/pyopengl_accelerate-3.1.0[${PYTHON_USEDEP}]
 	=dev-python/pyparsing-2*[${PYTHON_USEDEP}]
 	=dev-python/six-1*[${PYTHON_USEDEP}]
 	>=dev-python/wxpython-3.0.2.0[${PYTHON_USEDEP}]
 	>=dev-python/scipy-0.18[${PYTHON_USEDEP}]
-	=sci-libs/nibabel-2*[${PYTHON_USEDEP}]
-	sci-visualization/fsleyes-widgets[${PYTHON_USEDEP}]
-	sci-visualization/fsleyes-props[${PYTHON_USEDEP}]
+	>=sci-libs/nibabel-2.3[${PYTHON_USEDEP}]
+	>=sci-visualization/fsleyes-widgets-0.8.4[${PYTHON_USEDEP}]
+	>=sci-visualization/fsleyes-props-1.6.7[${PYTHON_USEDEP}]
 	"
 
 PATCHES=(
 	"${FILESDIR}/${PN}-0.26.2-fsldir.patch"
-	"${FILESDIR}/${PN}-0.32.0-coverage.patch"
 	"${FILESDIR}/${PN}-0.32.0-tests_timeout.patch"
 	"${FILESDIR}/${PN}-0.32.0-tests_fail.patch"
 	)
 
-src_prepare() {
-	sed -i -e "s/Pillow>=3.2.0,<6.0/Pillow>=3.2.0/g" requirements.txt
-	distutils-r1_src_prepare
+distutils_enable_tests pytest
+
+python_prepare_all() {
+	# do not depend on pytest-cov
+	sed -i -e '/addopts/d' setup.cfg || die
+
+	# Fatal Python error: Segmentation fault
+	sed -i -e 's:test_crop:_&:' \
+		tests/test_ortho_cropmode.py || die
+	sed -i -e 's:test_fillSelection:_&:' \
+		tests/test_ortho_editmode.py || die
+
+	# KeyError: 'Unknown atlas ID: harvardoxford-cortical'
+	sed -i -e 's:test_atlaspanel_toggleOverlay:_&:' \
+		tests/test_atlaspanel.py || die
+
+	# This hangs forever
+	sed -i -e 's:test_lightbox:_&:' \
+		tests/test_layouts.py || die
+
+	distutils-r1_python_prepare_all
 }
 
 python_install_all() {
@@ -62,9 +77,9 @@ python_install_all() {
 	doicon userdoc/images/fsleyes_icon.png
 	local size
 	for size in 16 32 128 256 512 ; do
-		doicon -s ${size} assets/icons/app_icon/${PN}.iconset/icon_${size}x${size}.png
+		newicon -s ${size} assets/icons/app_icon/${PN}.iconset/icon_${size}x${size}.png "${PN}.png"
 	done
-	make_desktop_entry fsleyes FSLeyes /usr/share/icons/hicolor/128x128/apps/icon_128x128.png
+	make_desktop_entry fsleyes FSLeyes "${PN}"
 }
 
 pkg_postinst() {