app-cdr/dolphin-plugins-mountiso: 21.11.90 version bump

Signed-off-by: Andreas Sturmlechner <asturm@gentoo.org>

2 files changed, 66 insertions, 0 deletions

diff --git a/app-cdr/dolphin-plugins-mountiso/Manifest b/app-cdr/dolphin-plugins-mountiso/Manifest
index 3c644ff083b6..96a9eab41e7d 100644
--- a/app-cdr/dolphin-plugins-mountiso/Manifest
+++ b/app-cdr/dolphin-plugins-mountiso/Manifest
@@ -1 +1,2 @@
 DIST dolphin-plugins-21.08.3.tar.xz 254604 BLAKE2B 9a7a9c7a1cf82d458c1fd0bbce6b47c233b8a7a20bd1d1696bc75d6b04c8e4a9d6464025d8ad39b3bb96b8dd428fb880a5d318f7c0d13ef3bc8bf24a42c24169 SHA512 2fb7fbd6490d768f3eb7d756429d858337b8088a7c87836ed4a54fc3f863f50c4973bbe2ae149d53d2769d7ce3c31fbd737bc4afc74fd14260a158da83992076
+DIST dolphin-plugins-21.11.90.tar.xz 254640 BLAKE2B c6755fc407b523759c0ac6c362311ee12322efd47e7a5ea4765ee08bc948e532b8e476d35ad2a16390be5150e2f94a5ce6d8cb185718160856bedc081cb4abca SHA512 7e2877666b41cf69dca6c4544a6bf9b6f0d6a09fbcc26c44ca0a3a4521caeda257af41a112ae6e26feb02d1ef7f63f7cd0f417b5b0f04367a65c83391f29dd64
diff --git a/app-cdr/dolphin-plugins-mountiso/dolphin-plugins-mountiso-21.11.90.ebuild b/app-cdr/dolphin-plugins-mountiso/dolphin-plugins-mountiso-21.11.90.ebuild
new file mode 100644
index 000000000000..2883eaf8adf4
--- /dev/null
+++ b/app-cdr/dolphin-plugins-mountiso/dolphin-plugins-mountiso-21.11.90.ebuild
@@ -0,0 +1,65 @@
+# Copyright 1999-2021 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=8
+
+ECM_HANDBOOK="false"
+KDE_GEAR="true"
+KDE_ORG_CATEGORY="sdk"
+KDE_ORG_NAME="dolphin-plugins"
+MY_PLUGIN_NAME="mountiso"
+KFMIN=5.88.0
+PVCUT=$(ver_cut 1-3)
+QTMIN=5.15.2
+inherit ecm kde.org
+
+DESCRIPTION="Dolphin plugin for ISO loopback device mounting"
+HOMEPAGE="https://apps.kde.org/dolphin_plugins/"
+
+LICENSE="GPL-2" # TODO: CHECK
+SLOT="5"
+KEYWORDS="~amd64 ~arm64 ~ppc64 ~x86"
+IUSE=""
+
+DEPEND="
+	>=dev-qt/qtdbus-${QTMIN}:5
+	>=dev-qt/qtgui-${QTMIN}:5
+	>=dev-qt/qtwidgets-${QTMIN}:5
+	>=kde-apps/dolphin-${PVCUT}:5
+	>=kde-frameworks/kcompletion-${KFMIN}:5
+	>=kde-frameworks/kconfig-${KFMIN}:5
+	>=kde-frameworks/kcoreaddons-${KFMIN}:5
+	>=kde-frameworks/ki18n-${KFMIN}:5
+	>=kde-frameworks/kio-${KFMIN}:5
+	>=kde-frameworks/ktextwidgets-${KFMIN}:5
+	>=kde-frameworks/solid-${KFMIN}:5
+"
+RDEPEND="${DEPEND}"
+
+src_prepare() {
+	ecm_src_prepare
+	# kxmlgui, qtnetwork only required by dropbox
+	ecm_punt_bogus_dep Qt5 Network
+	ecm_punt_bogus_dep KF5 XmlGui
+	# delete non-${PN} translations
+	if [[ ${KDE_BUILD_TYPE} = release ]]; then
+		find po -type f -name "*po" -and -not -name "*${MY_PLUGIN_NAME}plugin" -delete || die
+	fi
+}
+
+src_configure() {
+	local mycmakeargs=(
+		-DBUILD_${MY_PLUGIN_NAME}=ON
+		-DBUILD_bazaar=OFF
+		-DBUILD_dropbox=OFF
+		-DBUILD_git=OFF
+		-DBUILD_hg=OFF
+		-DBUILD_svn=OFF
+	)
+	ecm_src_configure
+}
+
+src_install() {
+	ecm_src_install
+	rm "${D}"/usr/share/metainfo/org.kde.dolphin-plugins.metainfo.xml || die
+}