app-i18n/libchewing: Add live ebuild.

2 files changed, 71 insertions, 1 deletions

diff --git a/app-i18n/libchewing/libchewing-0.5.1.ebuild b/app-i18n/libchewing/libchewing-0.5.1.ebuild
index 76f1d6b06eba..806f1c579a76 100644
--- a/app-i18n/libchewing/libchewing-0.5.1.ebuild
+++ b/app-i18n/libchewing/libchewing-0.5.1.ebuild
@@ -3,9 +3,19 @@
 
 EAPI="6"
 
+if [[ "${PV}" == "9999" ]]; then
+	inherit autotools git-r3
+
+	EGIT_REPO_URI="https://github.com/chewing/libchewing"
+fi
+
 DESCRIPTION="Intelligent phonetic (Zhuyin/Bopomofo) input method library"
 HOMEPAGE="http://chewing.im/ https://github.com/chewing/libchewing"
-SRC_URI="https://github.com/${PN/lib}/${PN}/releases/download/v${PV}/${P}.tar.bz2"
+if [[ "${PV}" == "9999" ]]; then
+	SRC_URI=""
+else
+	SRC_URI="https://github.com/chewing/${PN}/releases/download/v${PV}/${P}.tar.bz2"
+fi
 
 LICENSE="LGPL-2.1"
 SLOT="0/3"
@@ -16,6 +26,14 @@ RDEPEND="dev-db/sqlite:3"
 DEPEND="${RDEPEND}
 	test? ( sys-libs/ncurses[unicode] )"
 
+src_prepare() {
+	default
+
+	if [[ "${PV}" == "9999" ]]; then
+		eautoreconf
+	fi
+}
+
 src_configure() {
 	# libchewing.a is required for building of tests.
 	econf \
diff --git a/app-i18n/libchewing/libchewing-9999.ebuild b/app-i18n/libchewing/libchewing-9999.ebuild
new file mode 100644
index 000000000000..3dbd6c51e6fe
--- /dev/null
+++ b/app-i18n/libchewing/libchewing-9999.ebuild
@@ -0,0 +1,52 @@
+# Copyright 1999-2017 Gentoo Foundation
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI="6"
+
+if [[ "${PV}" == "9999" ]]; then
+	inherit autotools git-r3
+
+	EGIT_REPO_URI="https://github.com/chewing/libchewing"
+fi
+
+DESCRIPTION="Intelligent phonetic (Zhuyin/Bopomofo) input method library"
+HOMEPAGE="http://chewing.im/ https://github.com/chewing/libchewing"
+if [[ "${PV}" == "9999" ]]; then
+	SRC_URI=""
+else
+	SRC_URI="https://github.com/chewing/${PN}/releases/download/v${PV}/${P}.tar.bz2"
+fi
+
+LICENSE="LGPL-2.1"
+SLOT="0/3"
+KEYWORDS=""
+IUSE="static-libs test"
+
+RDEPEND="dev-db/sqlite:3"
+DEPEND="${RDEPEND}
+	test? ( sys-libs/ncurses[unicode] )"
+
+src_prepare() {
+	default
+
+	if [[ "${PV}" == "9999" ]]; then
+		eautoreconf
+	fi
+}
+
+src_configure() {
+	# libchewing.a is required for building of tests.
+	econf \
+		--with-sqlite3 \
+		$(if use static-libs || use test; then echo --enable-static; else echo --disable-static; fi)
+}
+
+src_test() {
+	emake -j1 check
+}
+
+src_install() {
+	default
+	find "${D}" -name "*.la" -delete || die
+	use static-libs || find "${D}" -name "*.a" -delete || die
+}