app-misc/hivex: add 1.3.20

Bug: https://bugs.gentoo.org/784584
Closes: https://bugs.gentoo.org/682238
Closes: https://bugs.gentoo.org/692528
Signed-off-by: Sam James <sam@gentoo.org>

2 files changed, 120 insertions, 0 deletions

diff --git a/app-misc/hivex/Manifest b/app-misc/hivex/Manifest
index 7af733a86f68..295aa26efecb 100644
--- a/app-misc/hivex/Manifest
+++ b/app-misc/hivex/Manifest
@@ -1 +1,2 @@
 DIST hivex-1.3.18.tar.gz 1542133 BLAKE2B 961d0797770a2bd3176ce288a509fab8685de91317d55f05e5295f9f56fd54c31acb64847e0cbb6a6074627ccbdfdf35bd0d35150beb7746a8b3de9128ac24e3 SHA512 1851351118921e81df9e505f90d00048a178572c2edd3de40194a69915176bdb615e2eb5afea408d57063e98257c8d1e3d0cd6730407153892cc9e3befc4aa3a
+DIST hivex-1.3.20.tar.gz 1727498 BLAKE2B db6448242fc4b72d75cc7234a49e146cb165b1b9b9e2e72fb2a05be37cbb1d8ca865ccc51c4d2d50199e69cae2d870743ecd41534290e9a100bb268c2437ee22 SHA512 366e84c2a13ff53c70036df60db6e2b469cd06e3405761df73c47978b4fa0245246a1ea912aa5852b1272221d55c6c100b40b00e4c9a6f5668d12ff7f93c787a
diff --git a/app-misc/hivex/hivex-1.3.20.ebuild b/app-misc/hivex/hivex-1.3.20.ebuild
new file mode 100644
index 000000000000..3fd24d446ca2
--- /dev/null
+++ b/app-misc/hivex/hivex-1.3.20.ebuild
@@ -0,0 +1,119 @@
+# Copyright 1999-2021 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=7
+
+USE_RUBY="ruby24 ruby25 ruby26"
+RUBY_OPTIONAL=yes
+
+PYTHON_COMPAT=( python3_{7,8,9} )
+
+inherit l10n perl-module ruby-ng python-single-r1
+
+DESCRIPTION="Library for reading and writing Windows Registry 'hive' binary files"
+HOMEPAGE="https://libguestfs.org"
+SRC_URI="https://libguestfs.org/download/${PN}/${P}.tar.gz"
+S="${WORKDIR}/${P}"
+
+LICENSE="LGPL-2.1"
+SLOT="0"
+KEYWORDS="~amd64 ~x86"
+IUSE="ocaml readline +perl python test ruby"
+
+RDEPEND="
+	dev-libs/libxml2:2
+	virtual/libiconv
+	virtual/libintl
+	ocaml? (
+		dev-lang/ocaml[ocamlopt]
+		dev-ml/findlib[ocamlopt]
+	 )
+	perl? (
+		dev-lang/perl:=
+		dev-perl/IO-stringy
+	)
+	python? ( ${PYTHON_DEPS} )
+	readline? ( sys-libs/readline:0 )
+	ruby? ( $(ruby_implementations_depend) )
+"
+DEPEND="${RDEPEND}
+	perl? (
+		test? (
+			dev-perl/Pod-Coverage
+			dev-perl/Test-Pod-Coverage
+		)
+	)"
+
+ruby_add_bdepend "ruby? ( dev-ruby/rake
+			virtual/rubygems
+			dev-ruby/rdoc )"
+ruby_add_rdepend "ruby? ( virtual/rubygems )"
+
+REQUIRED_USE="python? ( ${PYTHON_REQUIRED_USE} )
+			ruby? ( || ( $(ruby_get_use_targets) ) )"
+
+DOCS=( README )
+
+pkg_setup() {
+	if use python; then
+		python-single-r1_pkg_setup
+	fi
+}
+
+src_unpack() {
+	default
+	cp -prlP "${WORKDIR}/${P}" "${WORKDIR}"/all || die
+}
+
+src_configure() {
+	use ruby && ruby-ng_src_configure
+
+	if use perl; then
+		pushd perl || die
+		perl-module_src_configure
+		popd || die
+	fi
+
+	local myeconfargs=(
+		$(use_with readline)
+		$(use_enable ocaml)
+		$(use_enable perl)
+		--enable-nls
+		--disable-ruby
+		$(use_enable python)
+		--disable-rpath
+		--disable-static
+	)
+
+	econf "${myeconfargs[@]}"
+}
+
+src_compile() {
+	default
+
+	use ruby && ruby-ng_src_compile
+}
+
+src_install() {
+	strip-linguas -i po
+
+	emake install DESTDIR="${ED}" "LINGUAS=""${LINGUAS}"""
+
+	if use python; then
+		python_optimize
+	fi
+
+	if use ruby; then
+		ruby-ng_src_install
+	fi
+
+	if use perl; then
+		perl_delete_localpod
+
+		# Workaround Build.PL for now (see libguestfs too)
+		doman "${ED}"/usr/man/man3/*
+		rm -rf "${ED}"/usr/man || die
+	fi
+
+	find "${ED}" -name '*.la' -delete || die
+}