dev-java/gradle-bin: add 7.3.3, drop 7.3.2

Signed-off-by: Florian Schmaus <flow@gentoo.org>

1 files changed, 61 insertions, 0 deletions

diff --git a/dev-java/gradle-bin/gradle-bin-7.3.3.ebuild b/dev-java/gradle-bin/gradle-bin-7.3.3.ebuild
new file mode 100644
index 000000000000..dfbd1549205b
--- /dev/null
+++ b/dev-java/gradle-bin/gradle-bin-7.3.3.ebuild
@@ -0,0 +1,61 @@
+# Copyright 1999-2021 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=7
+
+IUSE="doc"
+JAVA_PKG_IUSE="source"
+
+inherit java-pkg-2
+
+MY_PN=${PN%%-bin}
+MY_P="${MY_PN}-${PV/_rc/-rc-}"
+
+DESCRIPTION="A project automation and build tool with a Groovy based DSL"
+SRC_URI="https://services.gradle.org/distributions/${MY_P}-all.zip -> ${P}.zip"
+HOMEPAGE="https://www.gradle.org/"
+
+LICENSE="Apache-2.0"
+SLOT="${PV}"
+KEYWORDS="~amd64 ~x86"
+
+DEPEND="app-eselect/eselect-gradle"
+BDEPEND="app-arch/unzip"
+RDEPEND="
+	${DEPEND}
+	>=virtual/jre-1.8:*
+"
+
+S="${WORKDIR}/${MY_P}"
+
+src_compile() {
+	:
+}
+
+src_install() {
+	local gradle_dir="/usr/share/${PN}-${SLOT}"
+
+	if use source; then
+		java-pkg_dosrc src
+	fi
+
+	docinto html
+	dodoc -r docs/release-notes.html
+	if use doc; then
+		dodoc -r docs/{dsl,userguide}
+		java-pkg_dojavadoc docs/javadoc
+	fi
+
+	insinto "${gradle_dir}"
+	doins -r bin/ lib/
+	fperms 755 "${gradle_dir}/bin/gradle"
+	dosym "${gradle_dir}/bin/gradle" "/usr/bin/${PN}-${SLOT}"
+}
+
+pkg_postinst() {
+	eselect gradle update ifunset
+}
+
+pkg_postrm() {
+	eselect gradle update ifunset
+}