dev-lang/uasm: new package, add 2.56.2

Imported from ::guru as of commit ea612f548c48f74fce1abc60d5ad205c521c7492.

Adding arthur and myself as well as NRK as discussed in #gentoo-guru. Dep of
to-be-shortly-added app-arch/7zip for AES HW acceleration.

Bug: https://bugs.gentoo.org/664664
Signed-off-by: Sam James <sam@gentoo.org>

1 files changed, 36 insertions, 0 deletions

diff --git a/dev-lang/uasm/uasm-2.56.2.ebuild b/dev-lang/uasm/uasm-2.56.2.ebuild
new file mode 100644
index 000000000000..1a4c8c42f2cd
--- /dev/null
+++ b/dev-lang/uasm/uasm-2.56.2.ebuild
@@ -0,0 +1,36 @@
+# Copyright 2024 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=8
+
+inherit toolchain-funcs flag-o-matic
+
+DESCRIPTION="UASM is a free MASM-compatible assembler"
+HOMEPAGE="https://www.terraspace.co.uk/uasm.html"
+SRC_URI="https://github.com/Terraspace/UASM/archive/v${PV}.tar.gz -> ${P}.tar.gz"
+LICENSE="Watcom-1.0"
+
+SLOT="0"
+KEYWORDS="~amd64"
+
+S="${WORKDIR}/UASM-${PV}"
+PATCHES=(
+	"${FILESDIR}/build-fix.patch"
+)
+
+src_prepare() {
+	default
+	# don't strip binary
+	sed -i gccLinux64.mak -e 's/ -s / /g' || die
+}
+
+src_compile() {
+	append-cflags -fcommon  # Bug: https://github.com/Terraspace/UASM/issues/143
+	emake -f gccLinux64.mak CC="$(tc-getCC)" \
+		CFLAGS="${CFLAGS}" LDFLAGS="${LDFLAGS}"
+}
+
+src_install() {
+	dobin GccUnixR/uasm
+	dodoc *.txt Doc/*.txt
+}