dev-libs/libjcat: Bump to version 0.1.2

Package-Manager: Portage-2.3.99, Repoman-2.3.22
Signed-off-by: Lars Wendler <polynomial-c@gentoo.org>

2 files changed, 66 insertions, 0 deletions

diff --git a/dev-libs/libjcat/Manifest b/dev-libs/libjcat/Manifest
index a627d9c5941b..d0482c7ac396 100644
--- a/dev-libs/libjcat/Manifest
+++ b/dev-libs/libjcat/Manifest
@@ -1,2 +1,3 @@
 DIST libjcat-0.1.0.tar.gz 60808 BLAKE2B 384e5a846fb7c49c8a6d6ace5f2b17715693d7e9ecfce020859c6fb5d96f9b9398606a2161a2c9f795c16c90e8b7a0e9d08970c1f81e4412783097f4ca599083 SHA512 2172fd621c86b3a2d507c3bb8fcc5f40a46656a5352f4963a014c76642bb2c34e316bb8608c121fa7d728d63dc2593ed28d3e3478e1ec5bcf32daeffc43627fd
 DIST libjcat-0.1.1.tar.gz 62579 BLAKE2B fed33602d2b036605238945d09ede1c524847624f1be6301a7f5ff64d21ba27c7c765b37c522f81dfd49071db6339738ad82b2ad0b25f0494bf4fd806c64b5de SHA512 fd644c003ad3a317a9f8886c2bad6dcfabf953e61bcbf02b30a292e9a85a591f854f71d7ac17692d5d98d976a435cf53beba1394c662fa78836389d66d4a5824
+DIST libjcat-0.1.2.tar.gz 62630 BLAKE2B cb333098d984f840a80c4ea4b7feab32ca7d04882f2f4aa788c01dd13c616b85576af5bbcd0ca343a7f5b7221ab69b202c7a8cacb230eeeefab9a3a9a61d7d3f SHA512 9184b761cad5a43ac1f0b0cd4ff54c372ec067785c9b796d813aab6a936fbb522f419e965b70d4d71fbec9f7c25f9d185f957cf1e73cb0e5bdeca9492e11b0fd
diff --git a/dev-libs/libjcat/libjcat-0.1.2.ebuild b/dev-libs/libjcat/libjcat-0.1.2.ebuild
new file mode 100644
index 000000000000..06f0e8d33d08
--- /dev/null
+++ b/dev-libs/libjcat/libjcat-0.1.2.ebuild
@@ -0,0 +1,65 @@
+# Copyright 1999-2020 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=7
+
+PYTHON_COMPAT=( python3_{6,7,8} )
+PYTHON_REQ_USE="xml"
+
+inherit meson python-any-r1 vala xdg-utils
+
+DESCRIPTION="Library and tool for reading and writing Jcat files "
+HOMEPAGE="https://github.com/hughsie/libjcat"
+SRC_URI="https://github.com/hughsie/${PN}/archive/${PV}.tar.gz -> ${P}.tar.gz"
+
+LICENSE="LGPL-2.1+"
+SLOT="0"
+KEYWORDS="~amd64"
+IUSE="gpg gtk-doc +introspection +man pkcs7 test"
+
+RDEPEND="dev-libs/glib:2
+	dev-libs/json-glib:=
+	gpg? (
+		app-crypt/gpgme
+		dev-libs/libgpg-error
+	)
+	introspection? ( dev-libs/gobject-introspection:= )
+	pkcs7? ( net-libs/gnutls )
+	dev-lang/vala:="
+DEPEND="${RDEPEND}"
+BDEPEND="virtual/pkgconfig
+	$(python_gen_any_dep '
+		dev-python/setuptools[${PYTHON_USEDEP}]
+	')
+	gtk-doc? ( dev-util/gtk-doc )
+	man? ( sys-apps/help2man )
+	test? ( net-libs/gnutls[tools] )"
+
+RESTRICT="!test? ( test )"
+
+PATCHES=(
+	"${FILESDIR}"/${PN}-0.1.1-disable_installed_tests.patch
+)
+
+python_check_deps() {
+	has_version -b "dev-python/setuptools[${PYTHON_USEDEP}]"
+}
+
+src_prepare() {
+	xdg_environment_reset
+# TODO: make vala optional
+	vala_src_prepare
+	default
+}
+
+src_configure() {
+	local emesonargs=(
+		$(meson_use gtk-doc gtkdoc)
+		$(meson_use gpg)
+		$(meson_use introspection)
+		$(meson_use man)
+		$(meson_use pkcs7)
+		$(meson_use test tests)
+	)
+	meson_src_configure
+}