dev-python/dbus-python: Bump to 1.2.18

Closes: https://bugs.gentoo.org/719626
Package-Manager: Portage-3.0.22, Repoman-3.0.3
Signed-off-by: Pacho Ramos <pacho@gentoo.org>

2 files changed, 82 insertions, 0 deletions

diff --git a/dev-python/dbus-python/Manifest b/dev-python/dbus-python/Manifest
index 40ba4cdce245..200202a96a52 100644
--- a/dev-python/dbus-python/Manifest
+++ b/dev-python/dbus-python/Manifest
@@ -1 +1,2 @@
 DIST dbus-python-1.2.16.tar.gz 576701 BLAKE2B 58d9f9ea092cd3a6b872c084a6159baf03f1aab615282e161a0e3da1d01ff5f4940862e693d21907b0c146d285b9067386759a1306ae2e6907f5e2ff4ef9944d SHA512 e76c00c5fd3fe6884e4c24f258987fd3b80d21bd4e0f96aa8fda152078a860b62321324f6efcbfe7226d5ab2521a14b5bda7cf2468d2cae5f376c124a71aa05c
+DIST dbus-python-1.2.18.tar.gz 578204 BLAKE2B 932a06f4b0145f7a47cf1ab6ea33c14eb4e36570ef548e7557d4aa5b780e49f2d284cdb51f0ec2d8a1cb286097fb9eabb2193d7cbeb387eaf43cbe209b7f11fa SHA512 72f422c59637392bd78b741b66dff2afadcc706452c3e82fdc14b1dc052a0c5cb8a85e2758d18c5cbdc08004419a0b3c16b67b99688d96307084403e72585900
diff --git a/dev-python/dbus-python/dbus-python-1.2.18.ebuild b/dev-python/dbus-python/dbus-python-1.2.18.ebuild
new file mode 100644
index 000000000000..819005012383
--- /dev/null
+++ b/dev-python/dbus-python/dbus-python-1.2.18.ebuild
@@ -0,0 +1,81 @@
+# Copyright 1999-2021 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=7
+
+PYTHON_COMPAT=( python3_{7..10} )
+PYTHON_REQ_USE="threads(+)"
+
+inherit autotools python-r1
+
+DESCRIPTION="Python bindings for the D-Bus messagebus"
+HOMEPAGE="https://www.freedesktop.org/wiki/Software/DBusBindings/ https://dbus.freedesktop.org/doc/dbus-python/"
+SRC_URI="https://dbus.freedesktop.org/releases/${PN}/${P}.tar.gz"
+
+LICENSE="MIT"
+SLOT="0"
+KEYWORDS="~alpha ~amd64 ~arm ~arm64 ~hppa ~ia64 ~mips ~ppc ~ppc64 ~riscv ~s390 ~sparc ~x86"
+
+IUSE="doc examples test"
+REQUIRED_USE="${PYTHON_REQUIRED_USE}"
+
+RESTRICT="!test? ( test )"
+
+RDEPEND="${PYTHON_DEPS}
+	>=sys-apps/dbus-1.8:=
+	>=dev-libs/glib-2.40
+"
+DEPEND="${RDEPEND}"
+BDEPEND="
+	virtual/pkgconfig
+	doc? ( $(python_gen_any_dep '
+			dev-python/sphinx[${PYTHON_USEDEP}]
+			dev-python/sphinx_rtd_theme[${PYTHON_USEDEP}]
+		') )
+	test? ( dev-python/pygobject:3[${PYTHON_USEDEP}]
+		dev-python/tappy[${PYTHON_USEDEP}] )
+"
+
+python_check_deps() {
+	has_version "dev-python/sphinx[${PYTHON_USEDEP}]"
+	has_version "dev-python/sphinx_rtd_theme[${PYTHON_USEDEP}]"
+}
+
+src_prepare() {
+	default
+	# Update py-compile, bug 529502.
+	eautoreconf
+	python_copy_sources
+}
+
+src_configure() {
+	use doc && python_setup
+	local SPHINX_IMPL=${EPYTHON}
+
+	configuring() {
+		local myconf=(
+			--disable-documentation
+		)
+		[[ ${EPYTHON} == ${SPHINX_IMPL} ]] &&
+			myconf+=( --enable-documentation )
+
+		econf "${myconf[@]}"
+	}
+	python_foreach_impl run_in_build_dir configuring
+}
+
+src_compile() {
+	python_foreach_impl run_in_build_dir default
+}
+
+src_test() {
+	unset DBUS_SESSION_BUS_ADDRESS
+	python_foreach_impl run_in_build_dir default
+}
+
+src_install() {
+	python_foreach_impl run_in_build_dir default
+	find "${D}" -name '*.la' -type f -delete || die
+
+	use examples && dodoc -r examples
+}