dev-python/kombu: Bump to 5.3.1

Signed-off-by: Michał Górny <mgorny@gentoo.org>

2 files changed, 83 insertions, 0 deletions

diff --git a/dev-python/kombu/Manifest b/dev-python/kombu/Manifest
index f604b95479e1..32668a15fc92 100644
--- a/dev-python/kombu/Manifest
+++ b/dev-python/kombu/Manifest
@@ -1,2 +1,3 @@
 DIST kombu-5.3.0.tar.gz 434097 BLAKE2B ef378014e4e52d83dc917f9dc6245111e94eddb70d9852da1add1b532ee733578db83c9ca5b4aa82771c443ecbd00e87384b7a373102e78aebcc6724ab1bf6b2 SHA512 688782cab692f0e18444289654e43f53b9a54627d5495933e9717b9676d689ddeb6de368081ea796df26727d4dfd5239ed7554736c13bfce7236e8d73f62b4a9
 DIST kombu-5.3.0b3.tar.gz 436058 BLAKE2B d8470eea43a1d5f862d93e3b3608a3240b25cad6ccb342318a7bebda17e6ce818dce2889cb7af22fd77d2f6e69d1fdfa6926c77ba715c76dd40e973f3d9920dc SHA512 c330e1dd334810ed5fdeea234c49606aa8e43f84006703ff26d900f40ec7ce4920418bef3fd43abc8c792fb750499031191394475c45bfac50f7d29a6e30f5f8
+DIST kombu-5.3.1.tar.gz 434284 BLAKE2B 8df6d441d1229fe188584a34cab6d40250dc119a189215ab8ae8ec6660dc25e85166f48786b6b4c2abd56b4eb9e6fdc15a92372078d6f412b728ce45be0a81e5 SHA512 608e70cc66dc19915fd2b40c3b908f3147f60a7c971be1d8bf04f3a18f78999a7a140073ecc9f38ec9aec49c1ef0a6f01fb5f2d27d68fc68bd64aade1924edfa
diff --git a/dev-python/kombu/kombu-5.3.1.ebuild b/dev-python/kombu/kombu-5.3.1.ebuild
new file mode 100644
index 000000000000..53ba0b0d0998
--- /dev/null
+++ b/dev-python/kombu/kombu-5.3.1.ebuild
@@ -0,0 +1,82 @@
+# Copyright 1999-2023 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=8
+
+DISTUTILS_USE_PEP517=setuptools
+PYTHON_COMPAT=( python3_{10..11} )
+
+inherit distutils-r1 optfeature pypi
+
+DESCRIPTION="AMQP Messaging Framework for Python"
+HOMEPAGE="
+	https://github.com/celery/kombu/
+	https://pypi.org/project/kombu/
+"
+
+LICENSE="BSD"
+SLOT="0"
+KEYWORDS="~amd64 ~arm64 ~x86"
+IUSE="examples"
+
+RDEPEND="
+	>=dev-python/py-amqp-5.1.1[${PYTHON_USEDEP}]
+	<dev-python/py-amqp-6.0.0[${PYTHON_USEDEP}]
+	dev-python/vine[${PYTHON_USEDEP}]
+"
+BDEPEND="
+	test? (
+		app-arch/brotli[python,${PYTHON_USEDEP}]
+		>=dev-python/boto3-1.22.2[${PYTHON_USEDEP}]
+		dev-python/hypothesis[${PYTHON_USEDEP}]
+		>=dev-python/msgpack-0.3.0[${PYTHON_USEDEP}]
+		dev-python/pycurl[${PYTHON_USEDEP}]
+		>=dev-python/pymongo-4.1.1[${PYTHON_USEDEP}]
+		dev-python/pytest-freezegun[${PYTHON_USEDEP}]
+		dev-python/zstandard[${PYTHON_USEDEP}]
+		dev-python/pytz[${PYTHON_USEDEP}]
+		>=dev-python/pyyaml-3.10[${PYTHON_USEDEP}]
+		>=dev-python/redis-4.2.2[${PYTHON_USEDEP}]
+		dev-python/sqlalchemy[${PYTHON_USEDEP}]
+	)
+"
+
+distutils_enable_tests pytest
+distutils_enable_sphinx docs \
+	dev-python/sphinx-celery
+
+python_test() {
+	local EPYTEST_DESELECT=(
+		# TODO
+		t/unit/transport/test_redis.py::test_Channel::test_connparams_health_check_interval_supported
+	)
+	local EPYTEST_IGNORE=(
+		# obsolete Pyro4
+		t/unit/transport/test_pyro.py
+		# unpackaged azure
+		t/unit/transport/test_azurestoragequeues.py
+	)
+
+	epytest
+}
+
+python_install_all() {
+	if use examples; then
+		docompress -x "/usr/share/doc/${PF}/examples"
+		docinto examples
+		dodoc -r examples/.
+	fi
+	distutils-r1_python_install_all
+}
+
+pkg_postinst() {
+	optfeature "Amazon SQS backend" "dev-python/boto3 dev-python/pycurl"
+	optfeature "Etcd backend" dev-python/python-etcd
+	optfeature "MongoDB backend" dev-python/pymongo
+	optfeature "Redis backend" dev-python/redis
+	optfeature "sqlalchemy backend" dev-python/sqlalchemy
+	optfeature "yaml backend" dev-python/pyyaml
+	optfeature "MessagePack (de)serializer for Python" dev-python/msgpack
+	optfeature "brotli compression" "app-arch/brotli[python]"
+	optfeature "zstd compression" dev-python/zstandard
+}