dev-python/qscintilla-python: bump to 2.10.7, EAPI 7, python3_7 support

Package-Manager: Portage-2.3.48, Repoman-2.3.10

3 files changed, 71 insertions, 1 deletions

diff --git a/dev-python/qscintilla-python/Manifest b/dev-python/qscintilla-python/Manifest
index 9726cb430a4c..67300618010d 100644
--- a/dev-python/qscintilla-python/Manifest
+++ b/dev-python/qscintilla-python/Manifest
@@ -1 +1,2 @@
 DIST QScintilla_gpl-2.10.4.tar.gz 2721322 BLAKE2B df50dd0a34db96dd57147ddc399d4a30751b1bb4922dc1b8b3c3c1989e810937dc8345f92128e8a606b1edc04fde4b930a424ab8344818c9899c8fe496793a77 SHA512 dee6684f68173784d098931554c839a30e129b89f980cd9704f818c44eb7023199bd3682e4b342091fa3e0ce577ec576d34046477bdd1d7fc58ca5dd2ba947a3
+DIST QScintilla_gpl-2.10.7.tar.gz 2734778 BLAKE2B 9fea764828e1c95ce842b06b06c45398b52669c0823a660bcd45a4af4a33a4a5b75b6349f84dc844e18d394c301bbb66f3485abd9f56a5c056d2b507b67a0148 SHA512 d5489a308da265f09c305128d9984b195c90003e52a55f5342c8ea50090392619425a0fc3df692aae0d09467d5b0b496b548eb31ff93cba97c9f4f406500007c
diff --git a/dev-python/qscintilla-python/qscintilla-python-2.10.4.ebuild b/dev-python/qscintilla-python/qscintilla-python-2.10.4.ebuild
index f683ef80e872..dbc23b01d914 100644
--- a/dev-python/qscintilla-python/qscintilla-python-2.10.4.ebuild
+++ b/dev-python/qscintilla-python/qscintilla-python-2.10.4.ebuild
@@ -8,7 +8,7 @@ inherit python-r1 qmake-utils
 
 MY_P=QScintilla_gpl-${PV/_pre/.dev}
 
-DESCRIPTION="Python bindings for Qscintilla"
+DESCRIPTION="Python bindings for QScintilla"
 HOMEPAGE="https://www.riverbankcomputing.com/software/qscintilla/intro"
 SRC_URI="mirror://sourceforge/pyqt/${MY_P}.tar.gz"
 
diff --git a/dev-python/qscintilla-python/qscintilla-python-2.10.7.ebuild b/dev-python/qscintilla-python/qscintilla-python-2.10.7.ebuild
new file mode 100644
index 000000000000..1d3059473f9a
--- /dev/null
+++ b/dev-python/qscintilla-python/qscintilla-python-2.10.7.ebuild
@@ -0,0 +1,69 @@
+# Copyright 1999-2018 Gentoo Foundation
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=7
+
+PYTHON_COMPAT=( python2_7 python3_{4,5,6,7} )
+inherit python-r1 qmake-utils
+
+MY_P=QScintilla_gpl-${PV/_pre/.dev}
+
+DESCRIPTION="Python bindings for QScintilla"
+HOMEPAGE="https://www.riverbankcomputing.com/software/qscintilla/intro"
+SRC_URI="mirror://sourceforge/pyqt/${MY_P}.tar.gz"
+
+LICENSE="GPL-3"
+SLOT="0"
+KEYWORDS="~amd64 ~ppc64 ~x86"
+IUSE="debug"
+
+REQUIRED_USE="${PYTHON_REQUIRED_USE}"
+
+DEPEND="
+	${PYTHON_DEPS}
+	>=dev-python/sip-4.19:=[${PYTHON_USEDEP}]
+	dev-python/PyQt5[gui,printsupport,widgets,${PYTHON_USEDEP}]
+	dev-qt/qtcore:5
+	dev-qt/qtgui:5
+	dev-qt/qtprintsupport:5
+	dev-qt/qtwidgets:5
+	~x11-libs/qscintilla-${PV}:=
+"
+RDEPEND="${DEPEND}"
+
+S=${WORKDIR}/${MY_P}/Python
+
+src_configure() {
+	configuration() {
+		# Fix out-of-source build and installation of .sip files
+		ln -s "${S}"/sip || die
+
+		local myconf=(
+			"${PYTHON}"
+			"${S}"/configure.py
+			--pyqt=PyQt5
+			--qmake="$(qt5_get_bindir)"/qmake
+			--sip-incdir="$(python_get_includedir)"
+			$(usex debug '--debug --trace' '')
+			--verbose
+		)
+		echo "${myconf[@]}"
+		"${myconf[@]}" || die
+
+		# Run eqmake to respect toolchain, build flags, and prevent stripping
+		eqmake5 -recursive
+	}
+	python_foreach_impl run_in_build_dir configuration
+}
+
+src_compile() {
+	python_foreach_impl run_in_build_dir default
+}
+
+src_install() {
+	installation() {
+		emake INSTALL_ROOT="${D}" install
+		python_optimize
+	}
+	python_foreach_impl run_in_build_dir installation
+}