games-strategy/warzone2100: remove deprecated games eclass

Also update to EAPI 6

Gentoo-Bug: https://bugs.gentoo.org/574082

Package-Manager: portage-2.3.0

1 files changed, 100 insertions, 0 deletions

diff --git a/games-strategy/warzone2100/warzone2100-3.1.5-r1.ebuild b/games-strategy/warzone2100/warzone2100-3.1.5-r1.ebuild
new file mode 100644
index 000000000000..e1829ce08023
--- /dev/null
+++ b/games-strategy/warzone2100/warzone2100-3.1.5-r1.ebuild
@@ -0,0 +1,100 @@
+# Copyright 1999-2016 Gentoo Foundation
+# Distributed under the terms of the GNU General Public License v2
+# $Id$
+
+EAPI=6
+inherit toolchain-funcs eutils versionator gnome2-utils
+
+MY_PV=$(get_version_component_range -2)
+VIDEOS_PV=2.2
+VIDEOS_P=${PN}-videos-${VIDEOS_PV}.wz
+DESCRIPTION="3D real-time strategy game"
+HOMEPAGE="http://wz2100.net/"
+SRC_URI="mirror://sourceforge/warzone2100/${P}.tar.xz
+	videos? ( mirror://sourceforge/warzone2100/warzone2100/Videos/${VIDEOS_PV}/high-quality-en/sequences.wz -> ${VIDEOS_P} )"
+
+LICENSE="GPL-2+ CC-BY-SA-3.0 public-domain"
+SLOT="0"
+KEYWORDS="~amd64 ~ppc ~x86"
+# upstream requested debug support
+IUSE="debug nls qt4 videos"
+
+# TODO: unbundle miniupnpc and quesoglc
+# quesoglc-0.7.2 is buggy: http://developer.wz2100.net/ticket/2828
+RDEPEND=">=dev-games/physfs-2[zip]
+	dev-libs/fribidi
+	dev-qt/qtcore:4
+	dev-qt/qtscript:4
+	media-libs/fontconfig
+	media-libs/freetype:2
+	media-libs/glew:=
+	media-libs/libogg
+	media-libs/libpng:0
+	media-libs/libtheora
+	media-libs/libvorbis
+	media-libs/openal
+	sys-libs/zlib
+	virtual/glu
+	virtual/opengl
+	x11-libs/libX11
+	x11-libs/libXrandr
+	nls? ( virtual/libintl )
+	qt4? (
+		dev-qt/qtgui:4
+		dev-qt/qtopengl:4
+	)
+	!qt4? ( media-libs/libsdl[opengl,video,X] )"
+DEPEND="${RDEPEND}
+	app-arch/zip
+	virtual/pkgconfig
+	nls? ( sys-devel/gettext )"
+RDEPEND="${RDEPEND}
+	media-fonts/dejavu"
+
+src_prepare() {
+	default
+
+	sed -i -e 's/#top_builddir/top_builddir/' po/Makevars || die
+}
+
+src_configure() {
+	econf \
+		--docdir=/usr/share/doc/${PF} \
+		--localedir=/usr/share/locale \
+		--with-distributor="Gentoo ${PF}" \
+		--with-icondir=/usr/share/icons/hicolor/128x128/apps \
+		--with-applicationdir=/usr/share/applications \
+		$(use_enable debug debug relaxed) \
+		$(use_enable nls) \
+		--with-backend=$(usex qt4 "qt" "sdl")
+}
+
+src_compile() {
+	emake AR="$(tc-getAR)"
+}
+
+src_install() {
+	default
+	rm -f "${D}"/usr/share/doc/${PF}/COPYING*
+	if use videos ; then
+		insinto /usr/share/${PN}
+		newins "${DISTDIR}"/${VIDEOS_P} sequences.wz
+	fi
+	doman doc/warzone2100.6
+	dodoc doc/quickstartguide.pdf
+
+	elog "If you are using opensource drivers you should consider installing: "
+	elog "    media-libs/libtxc_dxtn"
+}
+
+pkg_preinst() {
+	gnome2_icon_savelist
+}
+
+pkg_postinst() {
+	gnome2_icon_cache_update
+}
+
+pkg_postrm() {
+	gnome2_icon_cache_update
+}